Hallo Holger,
der EG kann nicht direkt auf die Kataloge zugreifen, der SAS-Server schon. Wenn die Library allokiert ist, reicht folgendes Programm aus, um das als Source-Entry gespeicherte Programm auszuführen:
Filename in Catalog "pgms.test";
%Include in(test.source) / source2;
Das Filenamestatement referenziert den Katalog und mit %Include wir der Source-Entry angegeben, der ausgeführt werden soll.
Programme ändern und wieder als Katalog-Entry speichern geht über den EG erst mal nicht, deshalb bin ich, wie die anderen Kollegen, auch der Meinung dass es vernünftiger ist, die Entries zu exportieren und im Filesystem zu speichern, auch hier ein Beispiel, wie das gehen könnte:
Options mcompilenote = all;
* GP Catalog Entries im Dateisystem speichern *;
%* Cat2File
exportiert einen Source-Entry in eine Datei
fref Fileref auf den Katalog
entry Name des Entries [name.source]
file Zieldatei ["dir/file.sas"]
*;
%Macro Cat2File(fref,entry,file);
Data _Null_;
Infile &fref(&entry);
File &file;
Input;
Put _infile_;
Run;
%Mend;
%* ExportSources
steuert den Export fuer einen Katalog
cat Name des Kataloges (lib muss allokiert sein)
dir Zielverzeichnis in dem die Dateien angelegt werden
*;
%Macro ExportSources(cat,dir);
%Local fref listEntries i curEntry;
%Let cat = pgms.test;
%Let fref = in;
Ods exclude all;
Ods Output catalog_random=Work.TestContents;
Proc Catalog c=&cat;
Contents;
Run;
Quit;
Proc Sql noprint;
Select objname Into :listEntries Separated By " "
From Work.TestContents
Where type = "SOURCE"
;
Drop Table Work.TestContents;
Quit;
Filename &fref Catalog "&cat";
%Do i=1 %To %Sysfunc(countw(&listEntries));
%Let curEntry = %Scan(&listEntries,&i);
%Cat2File(&fref,&curEntry..source,"&dir./&curEntry..sas");
%End;
%Mend;
%ExportSources(pgms,f:/temp/test);
Makro %Cat2File exportiert den Code eines Entries in eine Datei, %ExportSources enthält die Steuerung: Der Inhalt des Kataloges wird ausgelesen und die SOURCE-Entries in eine Tabelle gespeichert. Daraus wird eine Liste gebildet und in einer Makrovariable gespeichert. Die anschließende Schleife ruft den Export für jeden Entry auf. Das Zielverzeichnis muss natürlich im Filesystem des SAS-Servers liegen, damit er dorthin schreiben kann.
Hoffe das hilft weiter, viele Grüße,
Grischa
Edit 11.11.2016
Da waren noch zwei Fehler im Programm, Beim Drop hat das TABLE gefehlt und beim Namen der Datei der zweite Punkt in &curEntry..sas Außerdem habe ich noch ein Ods Exclude all; ergänzt, damit die Ausgabe von Proc Contents nicht im Output-Fenster ausgegeben wrid.
