DATA Step, Macro, Functions and more

rename all variables with last letter =1

Accepted Solution Solved
Reply
Contributor HG
Contributor
Posts: 23
Accepted Solution

rename all variables with last letter =1

Hi,

what is the best way to rename my variables?

data class;

  set sashelp.class;

newage1=age;

newweight1=weight;

newheight1=heigt;

run;

I have a lot of variables end with '1'. I want to take out '1'.

in my example, I need to rename newage1=newage and all other variables.

Thanks!


Accepted Solutions
Solution
‎08-15-2012 09:19 AM
Super Contributor
Posts: 1,636

Re: rename all variables with last letter =1

how about:

data class;
  set sashelp.class (obs=1);
  newage1=age;
  neww1=weight;
  newh1=height;
run;

proc sql;
  select catx('=',name,substr(name,1,length(name)-1)) into : list separated by ' '
   from dictionary.columns
     where libname='WORK' and memname='CLASS' and substr(name,length(name))='1';
quit;

data newclass;
   set class;
   rename &list;
run;
proc print;run;

View solution in original post


All Replies
Solution
‎08-15-2012 09:19 AM
Super Contributor
Posts: 1,636

Re: rename all variables with last letter =1

how about:

data class;
  set sashelp.class (obs=1);
  newage1=age;
  neww1=weight;
  newh1=height;
run;

proc sql;
  select catx('=',name,substr(name,1,length(name)-1)) into : list separated by ' '
   from dictionary.columns
     where libname='WORK' and memname='CLASS' and substr(name,length(name))='1';
quit;

data newclass;
   set class;
   rename &list;
run;
proc print;run;

Respected Advisor
Posts: 4,173

Re: rename all variables with last letter =1

Pretty close to what Linlin suggest but using a RegEx to match more precisely the variables you want renamed - and using Proc Datasets instead of a Data Step to do the renaming (and so avoiding a full pass through the data).

data class;
  set sashelp.class;
  newage1=age;
  newweight1=weight;
  newheight1=height;
run;


proc sql noprint;
  select cats(name,'=',prxchange('s/(.+)(1\b)/$1/o',1,name)) into : list separated by ' '
   from dictionary.columns
     where libname='WORK' and memname='CLASS' and prxmatch('/.+1\b/',name)
  ;
quit;

proc datasets lib=work nolist;
  modify class;
    rename &list;
  ;
quit;

🔒 This topic is solved and locked.

Need further help from the community? Please ask a new question.

Discussion stats
  • 2 replies
  • 232 views
  • 4 likes
  • 3 in conversation