DATA Step, Macro, Functions and more

creating new rows for long periods

Accepted Solution Solved
Reply
Frequent Contributor
Posts: 110
Accepted Solution

creating new rows for long periods

id rx start_date   days_supply
1 a    1/1/2005     90 
2  b   2/2/2004      60 


Hi all, I have the above dataset, I want to divide the periods that the patient can take drug were days supply represent the days the patients taked the drug. For simplicity, if the patient have 90 days means patient takes the drug for 3 months. 60 for two months and so on. Here is the output I am looking for 

id rx start_date   days_supply
1  a   1/1/2005     30
1  a   2/1/2005     30 
1  a   3/1/2005    30
2  b   2/2/2004   30
2  b   3/2/2004   30 

Accepted Solutions
Solution
‎10-27-2016 08:17 AM
Super User
Posts: 9,681

Re: creating new rows for long periods

data have;
       infile datalines;
       input id rx $ start_date mmddyy10. days_supply;
       format start_date mmddyy10.;
 datalines;
1 a 01/01/2005 90
2 b 02/02/2004 60
; run;
 
data want;
  set have;
       months = int(days_supply/30); 
	   supply=30;
       do i=1 to months;
          date = intnx('month',start_date,i-1,'s');
           output;
       end;
       KEEP ID RX supply date;
       format date mmddyy10.;
run;

View solution in original post


All Replies
Trusted Advisor
Posts: 1,378

Re: creating new rows for long periods

data have;

       infile datalines;

       input id rx start_date mmddyy10. days_supply;

       format start_date mmddyy10.;

 datalines;

1 a 01/01/2005 90

2 b 02/02/2004 60

; run;

 

data want;

  set have;

       months = days_supply / 30;   /* or ceil(days_supply/30)  */

       start_date_in = start_date;

       do i=1 to months;

           start_date = intnx('MONth', start_date_in, i-1) + day(start_date_in) -1;

           days_supply = 30;

           output;

       end;

run;

 

Solution
‎10-27-2016 08:17 AM
Super User
Posts: 9,681

Re: creating new rows for long periods

data have;
       infile datalines;
       input id rx $ start_date mmddyy10. days_supply;
       format start_date mmddyy10.;
 datalines;
1 a 01/01/2005 90
2 b 02/02/2004 60
; run;
 
data want;
  set have;
       months = int(days_supply/30); 
	   supply=30;
       do i=1 to months;
          date = intnx('month',start_date,i-1,'s');
           output;
       end;
       KEEP ID RX supply date;
       format date mmddyy10.;
run;
Frequent Contributor
Posts: 110

Re: creating new rows for long periods

Thank you! 

☑ This topic is SOLVED.

Need further help from the community? Please ask a new question.

Discussion stats
  • 3 replies
  • 211 views
  • 2 likes
  • 3 in conversation