converting numeric to character by put statement: how to avoid "." for missing values

[fengyuwuzu]

when I use put statement to convert a numeric variable to character one, using the following code will make missings to '.', not blank. 

VSSTRESC=strip(put(VSRESPORRES,best.));

Then I need to use the following code to avoid '.' 

if VSRESPORRES ne . then  VSSTRESC=strip(put(VSRESPORRES,best.));
				else VSSTRESC='';

I have many such variables to convert. I wonder if there is an easier way to avoid it? 

[Shmuel]

add options missing=' '; before your step

[fengyuwuzu]

Thank you. Will this option statement affect the missing values of numeric varaibles in the same data step? 

[Shmuel]

the option options missing=' '; affects only how it is displayed.

[Patrick]

As an alternative to the missing option which affects how missings are printed for all numerical variables, you can also define your own format as demontrated in the code below.

Also: To get your result left aligned you could use syntax <format name>.-L 

proc format;
  value MyBest(default=16)
  low-high=[best.]
  other=' ';
run;

data sample;
  VSRESPORRES=1;
  VSSTRESC=put(VSRESPORRES,MyBest.-L);
  output;
  VSRESPORRES=.;
  VSSTRESC=put(VSRESPORRES,MyBest.-L);
  output;
run;

[Reeza · Accepted solution]

If you're lazy, you can use CATT, it does an automatic conversion, with no message in the log.

option missing='';

data class;
	set sashelp.class;

	if age=13 then
		weight=.;
run;

data check;
	set class;
	test1=catt(weight);
	test2=put(weight, best.);
run;

title 'Missing with space';

proc print data=check (obs=5);
run;

option missing=.;
title 'Missing with period';

proc print data=check(obs=5);
run;