DATA Step, Macro, Functions and more

Year wise claim count and sum of payments

Reply
Contributor
Posts: 68

Year wise claim count and sum of payments

HI ,

I have a data set like below

Year Claim  Loss_paid  Loss_Incured
2008 100         500              100
2008 200        1000             200
2009 300         2000           300
2009 400        3000           400

I need to get an output like

Year Claim_Count Loss_PAid Loss_incured
2008       2                  1500          300
2009      2                   5000          700

 

Year wise claims counts and sum value of Loss_paid and Loss_Incured

PROC Star
Posts: 1,400

Re: Year wise claim count and sum of payments

Posted in reply to ambadi007

like this?

 

data have;
input Year Claim  Loss_paid  Loss_Incured;
datalines;
2008 100         500              100
2008 200        1000             200
2009 300         2000           300
2009 400        3000           400
;

proc sql;
	create table want as
	select year
	      ,count(Claim) as Claim_Count
		  ,sum(Loss_paid) as Loss_paid
		  ,sum(Loss_Incured) as Loss_Incured
	from have
	group by year;
quit;
Valued Guide
Posts: 624

Re: Year wise claim count and sum of payments

Posted in reply to ambadi007

Not clear what you need: dataset or report. If you need a report, try

proc report data=have;
   define Year / group;
   define Claim / n;
   define Loss_Paid / sum;
   define Loss_Incured / sum;
run;
Super User
Posts: 13,876

Re: Year wise claim count and sum of payments

Posted in reply to ambadi007

and another way to create a data set:

 

proc summary data=have nway;
  class year;
  var loss_paid loss_incured;
  output out=want (drop=_type_ rename=(_freq_=claim_count)) 
      sum=;
run;
Ask a Question
Discussion stats
  • 3 replies
  • 121 views
  • 0 likes
  • 4 in conversation