DATA Step, Macro, Functions and more

Using cntlin in proc format when one of the values is 'LOW'

Accepted Solution Solved
Reply
PROC Star
Posts: 7,363
Accepted Solution

Using cntlin in proc format when one of the values is 'LOW'

Ran into an interesting problem last night when using the cntlin option with proc format. The following code produces an error:

data for_format;
  input sym_root $;
  cards;
AAA
BBB
LOW
ZZZ
;
run;

data for_format;
  set for_format (rename=(sym_root=start));
  retain fmtname "$labelfmt" type "C";
  label=_n_;
run;

proc format cntlin = for_format;
run ;

Anyone know how one can include the value 'LOW' in such a case? My work around was to recode 'LOW' to be 'LOWW', but I'd rather no have to change the variable's value.

 

Art, CEO, AnalystFinder.com

 


Accepted Solutions
Solution
‎05-27-2017 12:46 PM
Super User
Super User
Posts: 6,500

Re: Using cntlin in proc format when one of the values is 'LOW'

You need to add the HLO variable to your control dataset to prevent SAS from trying to detect the LOW HIGH keywords from the text of the START/END values.

data for_format;
  set have (rename=(sym_root=start));
  retain fmtname "$labelfmt" type "C" hlo '   ';
  label=_n_;
run;
proc format cntlin = for_format;
run ;

One way to test is to make the format using code and output the control dataset.

Then try keeping different subsets of the variables in that control dataset to pass back into PROC FORMAT to figure out the minimum set of variables that are needed.

proc format cntlout=want;
  value $labelfmt
  'AAA'='1'
  'BBB'='2'
  'LOW'='3'
  'ZZZ'='4'
  ;
run;

proc format cntlin=want(keep=fmtname type start label hlo); 
run;

View solution in original post


All Replies
Solution
‎05-27-2017 12:46 PM
Super User
Super User
Posts: 6,500

Re: Using cntlin in proc format when one of the values is 'LOW'

You need to add the HLO variable to your control dataset to prevent SAS from trying to detect the LOW HIGH keywords from the text of the START/END values.

data for_format;
  set have (rename=(sym_root=start));
  retain fmtname "$labelfmt" type "C" hlo '   ';
  label=_n_;
run;
proc format cntlin = for_format;
run ;

One way to test is to make the format using code and output the control dataset.

Then try keeping different subsets of the variables in that control dataset to pass back into PROC FORMAT to figure out the minimum set of variables that are needed.

proc format cntlout=want;
  value $labelfmt
  'AAA'='1'
  'BBB'='2'
  'LOW'='3'
  'ZZZ'='4'
  ;
run;

proc format cntlin=want(keep=fmtname type start label hlo); 
run;
PROC Star
Posts: 7,363

Re: Using cntlin in proc format when one of the values is 'LOW'

@Tom: Worked like a charm!

 

Thanks,

Art

 

☑ This topic is SOLVED.

Need further help from the community? Please ask a new question.

Discussion stats
  • 2 replies
  • 143 views
  • 2 likes
  • 2 in conversation