DATA Step, Macro, Functions and more

Output dataset for multiple chi squared test for association

Accepted Solution Solved
Reply
New Contributor
Posts: 2
Accepted Solution

Output dataset for multiple chi squared test for association

Hi everybody,
I have a data set containing 35 categorical variable that I want to test with other 33 dichotomous variables using chi squred test. If I run
Proc freq data=mydata;
Table = c_: * d_: / chisq;
Run;
It works but i was struggling how to create a simple output data set with just three information: the two variables used in every test and the pchi.

Thanks everybody in advance

Accepted Solutions
Solution
‎01-19-2016 03:53 AM
Respected Advisor
Posts: 4,919

Re: Output dataset for multiple chi squared test for association

Use ODS OUTPUT to get the table :

 

ods listing select none;
proc freq data=sashelp.heart;
table (status sex) * (chol_status bp_status weight_status) / chisq;
ods output ChiSq=outChiSq;
run;
ods listing;

proc sql;
create table myChiSq as
select 
    scan(Table,2) as v1 length=32, 
    scan(Table,3) as v2 length=32, 
    df, 
    value, 
    prob
from outChiSq
where statistic="Chi-Square"
order by v1, v2;
select * from myChiSq;
quit;

Note : You need parentheses around the variable lists in the TABLES statement.

PG

View solution in original post


All Replies
Solution
‎01-19-2016 03:53 AM
Respected Advisor
Posts: 4,919

Re: Output dataset for multiple chi squared test for association

Use ODS OUTPUT to get the table :

 

ods listing select none;
proc freq data=sashelp.heart;
table (status sex) * (chol_status bp_status weight_status) / chisq;
ods output ChiSq=outChiSq;
run;
ods listing;

proc sql;
create table myChiSq as
select 
    scan(Table,2) as v1 length=32, 
    scan(Table,3) as v2 length=32, 
    df, 
    value, 
    prob
from outChiSq
where statistic="Chi-Square"
order by v1, v2;
select * from myChiSq;
quit;

Note : You need parentheses around the variable lists in the TABLES statement.

PG
New Contributor
Posts: 2

Re: Output dataset for multiple chi squared test for association

This is great! Thank you so much!

Respected Advisor
Posts: 4,919

Re: Output dataset for multiple chi squared test for association

You are welcome. Please mark answer as accepted solution.

PG
☑ This topic is solved.

Need further help from the community? Please ask a new question.

Discussion stats
  • 3 replies
  • 205 views
  • 1 like
  • 2 in conversation