Astounding:
For a stored process, all the macro variables that will come from the prompting framework should be declared in a %GLOBAL statement. So, Ashley's "internal" and local macro variables will not need to be in a
%GLOBAL statement, but the macro variables that will come from stored process PROMPTS should be declared.
Ashley:
Anytime you have a macro compile error, such as this one (from one of your earlier posts):
ERROR: There is no matching %IF statement for the %ELSE. A dummy macro will be compiled.
You have to fix that first. I think that part of what's wrong with the code you originally posted is a misplaced
%LET statement
15 +%if %length(&DISTRICT) >= 0 %then %do;
16 +
17 +%if %length(&where_clause) > 0 %then %let where_clause = &where_clause and;
18 +
19 +%let where_clause = &where_clause (DISTRICT = "&DISTRICT");
ERROR: There is no matching %IF statement for the %ELSE. A dummy macro will be compiled.
20 +
21 +
22 +%else %let where_clause = &where_clause and;
23 +
24 +%let where_clause = &where_clause;
25 +
26 +
27 +%end;
where you have %let where_clause ... between the %IF and the %ELSE
In fact, I can replicate this error message by doing something similar in a test:
** problem with %let statement between the %if and the %else;
%macro testwrong();
%if %length(&test) > 0 %then %do;
%if &test = y %then %put this is if 1;
%let macvar=xxx;
%else %if &test2 = y %then %put this is else if 1;
%end;
%mend testwrong;
options mprint mlogic symbolgen;
%let test=y;
%let test2=;
%testwrong()
which results in the same error message in the SAS log. The logic of where the %LET statement doesn't make sense to me, anyway, but I usually always code my %IF and %ELSE with %DO/%END, to make it very, very clear what is being executed and under what condition.
My "wrong" code shows the same message in the SAS log:
382 ** problem with %let statement between the %if and the %else;
383 %macro testwrong();
384 %if %length(&test) > 0 %then %do;
385 %if &test = y %then %put this is if 1;
386 %let macvar=xxx;
387 %else %if &test2 = y %then %put this is else if 1;
ERROR: There is no matching %IF statement for the %ELSE.
ERROR: A dummy macro will be compiled.
388 %end;
389 %mend testwrong;
390
391 options mprint mlogic symbolgen;
392 %let test=y;
393 %let test2=;
394 %testwrong()
-
180
WARNING: Apparent invocation of macro TESTWRONG not resolved.
ERROR 180-322: Statement is not valid or it is used out of proper order.
So, until you fix any macro compile errors, you will not be generating anything useful with your macro invocation and you can't trust what happens when you execute the macro. In fact, with the "a dummy macro will be compiled message" that should be your indicator that your macro code is "broken". That's why I suggested that you step back and try just 1 %IF statement and build 1 correct WHERE Statement before you jumped into building multiple or additive WHERE statements. Only syntactically correct macro code is compiled and until your macro program compiles successfully, there's not going to be anything to "call" when you invoke the macro by name.
Several version of the above macro program (with the %LET inside a %IF/%DO) would be these. Since I don't know where your %LET should logically go, I just created 2 different versions. Both of these macro programs compile correctly. Of course, the results for MACVAR would be logically different for both of these invocations.
** coded %IF statement using %do/%end;
%macro testright();
%if %length(&test) > 0 %then %do;
%if &test = y %then %do;
%put this is if 1;
%let macvar=xxx;
%put macvar is &macvar;
%end;
%else %if &test2 = y %then %do;
%put this is else if 1;
%end;
%end;
%mend testright;
options mprint mlogic symbolgen;
%let test=y;
%let test2=;
%testright()
%macro testalt();
%if %length(&test) > 0 %then %do;
%let macvar=xxx;
%put macvar is &macvar;
%if &test = y %then %do;
%put this is if 1;
%end;
%else %if &test2 = y %then %do;
%put this is else if 1;
%end;
%end;
%mend testalt;
options mprint mlogic symbolgen;
%let test=y;
%let test2=;
%testalt()
I still think you need to take a step back and understand how macro programs and macro %IF statements work and define the code that you expect to generate. You seem to want to generate "additive" WHERE statements joined by the AND operator. This is only ONE way to generate WHERE statements. The WHERE ALSO is another way to augment or modify a WHERE statement condition. For example, try this:
ods listing;
proc print data=sashelp.class;
where sex = 'F';
where also age gt 14;
run;
The type of code you need to generate might be easier to do in a macro program if you considered using WHERE ALSO because then you could create WHOLE statements in discrete %IF/%DO/%END sections.
cynthia
Click image to register for webinar
