Macro doesn't read the conditional

[fri0]

Hi! I'm trying to use this macro, but I have a problem with the first "If" conditional, it's like SAS doesn't read the if, and jump all the marked part in the code. Could anyone please tell me what is wrong in the code? (The line 96 has the category Ingreso for the clase column)

Thanks in advance!

%macro recorre;
proc sql noprint;
	SELECT count(*) INTO :total FROM WORK.DATA_DIA;
quit;
%Do I = 96 %to 96;
	proc sql noprint;
		SELECT tipo, clase, horanum INTO :n_tipo, :n_clase, :n_hora FROM WORK.DATA_DIA where n = &I;
	quit;
	%put &n_clase;
*Begin error;
	%if &n_clase = 'Ingreso' %then %do;
		%put 'ing';
		%if &n_tipo = 'Demanda' %then %do;
			%put 'dem';
		%end;
		%else %do;
			%put 'ofe';
		%end;
*End error;
 %end; %put Fin; %End; %mend recorre; %recorre;

[novinosrin · Accepted solution]

quick look tells me you don't need quotes around values in a macro statement

%macro recorre;
proc sql noprint;
	SELECT count(*) INTO :total FROM WORK.DATA_DIA;
quit;
%Do I = 96 %to 96;
	proc sql noprint;
		SELECT tipo, clase, horanum INTO :n_tipo, :n_clase, :n_hora FROM WORK.DATA_DIA where n = &I;
	quit;
	%put &n_clase;
	%if &n_clase = Ingreso %then %do;
		%put 'ing';
		%if &n_tipo = Demanda %then %do;
			%put 'dem';
		%end;
		%else %do;
			%put 'ofe';
		%end;
	%end;
	%put Fin;
%End;
%mend recorre;

%recorre;

[fri0]

Hi! if you said it for the words 'ing', 'dem' and 'ofe', it's just to probe the code. But I couldn't get those prints.

[novinosrin]

I meant for 

	%if &n_clase = 'Ingreso' %then %do;
		
		%if &n_tipo = 'Demanda' %then %do;

[fri0]

It totally works! Thanks you very much!

[Satish_Parida]

This is a very common mistake,
We confuse the string comparison in data step if and macro %if.
As mentioned above, the string do not need to be in quote for comparison. Also you do not need to have quotes around strings to %put.
Everything in macro is already character.

[Reeza]

Add the debugging options, run the macro again and review the log. If you still can’t get it working post the revised code and log. 

Options mprint symbolgen mlogic;