DATA Step, Macro, Functions and more

How to round values in stat procedures

Accepted Solution Solved
Reply
Occasional Contributor
Posts: 5
Accepted Solution

How to round values in stat procedures

I treied to make all my statistical outputs to round 2 decimals. For example, here is code:

 

ods rtf file='c:\SAS\MeanOutput.rtf';
proc means data = sashelp.class nmiss N min max mean std;
var _numeric_ ;
format _numeric_ comma10.2;
run;
ods rtf close;

 

where the format statement doen't work. Any help or suggestion would be appreciated. Thank you.

 

Louis


Accepted Solutions
Solution
‎04-08-2017 12:34 PM
PROC Star
Posts: 552

Re: How to round values in stat procedures

Use the maxdec option like this Smiley Happy

 

proc means data = sashelp.class nmiss N min max mean std maxdec = 2;
var _numeric_ ;
run;

View solution in original post


All Replies
Solution
‎04-08-2017 12:34 PM
PROC Star
Posts: 552

Re: How to round values in stat procedures

Use the maxdec option like this Smiley Happy

 

proc means data = sashelp.class nmiss N min max mean std maxdec = 2;
var _numeric_ ;
run;
Occasional Contributor
Posts: 5

Re: How to round values in stat procedures

It worked like a charm. Thank you so much!
PROC Star
Posts: 7,363

Re: How to round values in stat procedures

You already got a satisfactory answer, but that only changed the decimal places. It didn't apply the format you wanted (i.e. comma12.2).

 

If you need to change the formats for proc means, you can do that using proc template. e.g.:

 

ods path(prepend) work.templat(update);
proc template;
 edit base.summary;
  edit mean;
   format=comma12.2;
  end;
  edit sum;
   format=comma12.2;
  end;
  edit min;
   format=comma12.2;
  end;
  edit max;
   format=comma12.2;
  end;
  edit stddev;
   format=comma12.2;
  end;
 end;
run;

ods rtf file='/folders/myfolders/MeanOutput.rtf';
proc means data = sashelp.class nmiss N min max mean std;
  var _numeric_ ;
run;
ods rtf close;

proc template;
 delete base.summary;
run;

Art, CEO, AnalystFinder.com

 

Occasional Contributor
Posts: 5

Re: How to round values in stat procedures

Correct, I'm more interested in the change of the display. But thank you so much for showing me alternative way doing the format.
☑ This topic is SOLVED.

Need further help from the community? Please ask a new question.

Discussion stats
  • 4 replies
  • 166 views
  • 0 likes
  • 3 in conversation