How to group by calculated variable?

[afiqcjohari]

rsubmit;
 data mytrans; 
 length TrYear 5
		  numMonth 3; 
 set db2dw.acarddet;
    TrYear = year(dTran);
		numMonth = month(dTran);
 run;
endrsubmit;
rsubmit;
proc sql;
 create table mnth_trans as
 select TrYear, numMonth, count(*) as tottxn from mytrans
 group by TrYear, numMonth;
;quit;
proc transreg data=mnth_trans;
   model identity(tottxn) = pbspline(TrYear); /* AICC criterion */
run;
endrsubmit;

What I'd like to do is combine the data step and proc sql in one procedure. 

What's the best way to do so?

Or better yet, combine all data step proc sql and proc transgreg in 1 procedure...

[Reeza · Accepted solution]

---

@afiqcjohari wrote:

rsubmit;
 data mytrans; 
 length TrYear 5
		  numMonth 3; 
 set db2dw.acarddet;
    TrYear = year(dTran);
		numMonth = month(dTran);
 run;
endrsubmit;
rsubmit;
proc sql;
 create table mnth_trans as
 select TrYear, numMonth, count(*) as tottxn from mytrans
 group by TrYear, numMonth;
;quit;
proc transreg data=mnth_trans;
   model identity(tottxn) = pbspline(TrYear); /* AICC criterion */
run;
endrsubmit;

What I'd like to do is combine the data step and proc sql in one procedure. 

What's the best way to do so?

Or better yet, combine all data step proc sql and proc transgreg in 1 procedure...

---

Add the word CALCULATED before you use it in the GROUP (ie group by calculated trtYear, calculated trtMonth)

Or use the calculation in the GROUP statement (ie group by year(date), month(date) )

Or use a single PROC FREQ and format the date in the procedure.

proc sql;
create table test as
select year(date) as Dyear, month(date) as DMonth, count(*) as Totalcount
from sashelp.stocks
group by calculated Dyear, calculated Dmonth;
quit;

proc sql;
create table test as
select year(date) as Dyear, month(date) as DMonth, count(*) as TotalCount
from sashelp.stocks
group by year(date), month(date);
quit;

proc freq data=sashelp.stocks noprint;
table date/out=want;
format date monyy7.;
run;

[afiqcjohari]

The last solution is very interesting. Where can I learn more about using format in that way?

[Rick_SAS]

You can read the article "Use formats to bin numerical variables."

[Tom]

You can use the position in the column list in your GROUP BY phrase.

proc sql;
 create table mnth_trans as
  select  year(dTran) as TrYear
       ,  month(dTran) as numMonth
       , count(*) as tottxn
   from mytrans
  group by 1,2
 ;
quit;

[afiqcjohari]

This is terrific.