DATA Step, Macro, Functions and more

Flag Maximum Encounter Date(s)

Accepted Solution Solved
Reply
Regular Contributor
Posts: 151
Accepted Solution

Flag Maximum Encounter Date(s)

[ Edited ]

Hello Everybody!

 

I've got a data set and I'm trying to create a variable that will flag the last Encounter_Date for each patient for each fiscal month/fiscal year. They may have multiple encounters on the last Encounter_Date. I'm trying to replicate the results of this code:

 

proc sql;

create table bbb as select * from aaa

group by fy, fm, ppid

 having encounter_date = max(encounter_date);

quit;

 

with something like this (I want to keep all records in aaa and flag the max(encounter_date)):

 

proc sort data = aaa;

by FY FM ppid encounter_date;

run;

 

data bbb;

 

set aaa;

by FY FM ppid;

if last.ppid then Max_Enc_Date = 1 ;

else Max_Enc_Date =0 ;

run;

 

Thanks,

Brian


Accepted Solutions
Solution
‎04-20-2018 12:56 PM
Super User
Posts: 6,935

Re: Flag Maximum Encounter Date(s)

To keep several observations, all with the same maximum date, sort in descending order:

 

proc sort data=aaa;

by fy fm ppid descending encounter_date;

run;

 

Then it is easy to select all those having the maximum:

 

data want;

set have;

by fy fm ppid;

if first.ppid then max_date = encounter_date;

retain max_date;

Max_Enc_Date = (encounter_date = max_date);

drop max_date;

run;

View solution in original post


All Replies
Solution
‎04-20-2018 12:56 PM
Super User
Posts: 6,935

Re: Flag Maximum Encounter Date(s)

To keep several observations, all with the same maximum date, sort in descending order:

 

proc sort data=aaa;

by fy fm ppid descending encounter_date;

run;

 

Then it is easy to select all those having the maximum:

 

data want;

set have;

by fy fm ppid;

if first.ppid then max_date = encounter_date;

retain max_date;

Max_Enc_Date = (encounter_date = max_date);

drop max_date;

run;

Regular Contributor
Posts: 151

Re: Flag Maximum Encounter Date(s)

[ Edited ]
Posted in reply to Astounding

That's Astounding!

 

Thank you!

☑ This topic is solved.

Need further help from the community? Please ask a new question.

Discussion stats
  • 2 replies
  • 135 views
  • 0 likes
  • 2 in conversation