Extracting words from string

[SASSLICK001]

Hello All

What is the effective way to extract two words from the following string!? ( I need to extract Day 1)

I can use substr(string,5,5), but sometimes it can be Day 100 or W1 Day 25 (Study 2) in which i need to extract Day 25

I can also use scan function and extract 2 and  3 words and concatenate ! Is there any function which is more robustic?

W10 Day 1 (Study 1)

W1 Day 100 (Study x)

W Day 25

Thanks for all your insights!

J

[sbb]

SCAN works well, either supplying a positive-value argument (from start-location) or negative-value (from end-location) -- will depend on the result/requirement, however there are likely multiple SAS functions that can accomplish the task.  Similarly, various SAS concatenation functions as well will apply, such as CATX, or using TRIM, possibly even COMPRESS, depending on the rqmt.

Scott Barry
SBBWorks, Inc.

[Ksharp]

data have;
input x $40.;
cards;
W10 Day 1 (Study 1)
W1 Day 100 (Study x)
W Day 25
;
run;
data want;
 set have;
if prxmatch('/\s+Day\s+\d+\s+/i',x) then 
want=prxchange('s/.*\s+(Day\s+\d+)\s+.*/$1/i',-1,x);
run;

Xia Keshan

[Ksharp]

data want;

set have;

retain pid;

if _n_ eq 1 then pid=prxparse('/\s+Day\s+\d+\s+/i');

call prxsubstr(pid, x, position, length);

if position ne 0 then want = substr(x, position, length);

drop pid position length;

run;

[SASSLICK001]

Thanks Keshan for your reply,

whan about if we have W1 Screening

[Ksharp]

It will return a missing value .