Hi, in this example, row 1 and 4 are duplicates because if you swiched col1 and col2 for one of the rows, that row will be a duplicated row of the other based on col1 and col2. I only want to keep one of them. Thank you! Z
data have;
input col1 $ col2 $ col3;
datalines;
A B 1
C F 3
D H 5
B A 1
G H 6
;
run;
data want;
input col1 $ col2 col3;
datalines;
A B 1
C F 3
D H 5
G H 6
;
run;
Ok, I figured it out, thank you anyway:
data temp;
set have;
new1=col1;
new2=col2;
call sortc(new1,new2);
run;
proc print data=temp;
run;
proc sort data=temp out=want2 nodupkey;
by new1 new2;
run;
proc print data=want2;
run;
If the dataset is big, then this may offer some efficiencies. It passes through the data only once:
data need/ view=need;
set have;
new1=col1;new2=col2;
call sortc(new1,new2);
run;
proc sort data=need out=want nodupkey;
by new1 new2;
run;
It takes advantage of the fact that data set need is a data set VIEW, not a data set FILE. This means it is actualized only when called later (by the proc sort) its data is passed directly to proc sort without being written to disk.
Result, one pass of the data, producing sorted results with all duplicate combinations (not just duplicate permutations) of col1/col2 removed.
Don't miss out on SAS Innovate - Register now for the FREE Livestream!
Can't make it to Vegas? No problem! Watch our general sessions LIVE or on-demand starting April 17th. Hear from SAS execs, best-selling author Adam Grant, Hot Ones host Sean Evans, top tech journalist Kara Swisher, AI expert Cassie Kozyrkov, and the mind-blowing dance crew iLuminate! Plus, get access to over 20 breakout sessions.
Learn how use the CAT functions in SAS to join values from multiple variables into a single value.
Find more tutorials on the SAS Users YouTube channel.