DATA Step, Macro, Functions and more

Character cells in proc report

Accepted Solution Solved
Reply
Respected Advisor
Posts: 4,925
Accepted Solution

Character cells in proc report

data have;
input (league team captain) ($);
datalines;
N A N1
N B N2
N C N3
S A N4
S B N5
S C N6
;

I would like to use PROC REPORT to generate the following report :

             team
           A   B   C
league
N         N1  N2  N3
S         N4  N5  N6

PG

Accepted Solutions
Solution
‎05-22-2013 09:21 AM
SAS Super FREQ
Posts: 8,866

Re: Character cells in proc report

Hi, the "trick" is that REPORT will not like to use a character value under an ACROSS variable unless you give it something to "summarize". Try out the attached code. #1 will not work because PROC REPORT "wants" a statistic associated with CAPTAIN, but #2 will do what you want. After you see that #2 is working, you can use NOPRINT on the DEFINE statement to hide it on the report.

cynthia

ods html file='c:\temp\makedummyvar.html';

proc report data=have nowd;

  title '1st try';

  column league team,captain;

  define league / group;

  define team / across;

  define captain / display;

run;

proc report data=have nowd;

  title1 '2nd try with dummyvar';

  column league team,captain dummyvar;

  define league / group;

  define team / across;

  define captain / display;

  define dummyvar / computed /* noprint */;

  compute dummyvar;

    dummyvar = 1;

  endcomp;

run;

ods html close;

View solution in original post


All Replies
Solution
‎05-22-2013 09:21 AM
SAS Super FREQ
Posts: 8,866

Re: Character cells in proc report

Hi, the "trick" is that REPORT will not like to use a character value under an ACROSS variable unless you give it something to "summarize". Try out the attached code. #1 will not work because PROC REPORT "wants" a statistic associated with CAPTAIN, but #2 will do what you want. After you see that #2 is working, you can use NOPRINT on the DEFINE statement to hide it on the report.

cynthia

ods html file='c:\temp\makedummyvar.html';

proc report data=have nowd;

  title '1st try';

  column league team,captain;

  define league / group;

  define team / across;

  define captain / display;

run;

proc report data=have nowd;

  title1 '2nd try with dummyvar';

  column league team,captain dummyvar;

  define league / group;

  define team / across;

  define captain / display;

  define dummyvar / computed /* noprint */;

  compute dummyvar;

    dummyvar = 1;

  endcomp;

run;

ods html close;

Respected Advisor
Posts: 4,925

Re: Character cells in proc report

Posted in reply to Cynthia_sas

Well I'll be... It works! Thanks Cynthia. That's far from intuitive, at least for me.

PG

PG
🔒 This topic is solved and locked.

Need further help from the community? Please ask a new question.

Discussion stats
  • 2 replies
  • 221 views
  • 0 likes
  • 2 in conversation