DATA Step, Macro, Functions and more

Calculating duration from a Panel Structure

Reply
N/A
Posts: 1

Calculating duration from a Panel Structure

Hi All,

New SAS user here.  I have a panel data structure, from which I am trying to calculate the duration between observations.  My test data looks like this:

ID     Enter Date     Exit Date     Sex     Age

1        1/1/2000       1/1/2002       m       24

1        5/5/2006        5/5/2009      m       30

1        8/8/2011        8/8/2013      m       35

2        2/2/2002        2/2/2005       f        42

2        6/6/2006        6/6/2010       f        46

3        3/3/2003        3/3/2004      m       19

3        4/4/2008        4/4/2012      m       24

I want to create a variable that subtracts the exit date from the next enter date, so that last observation for each ID group is missing.  Any efficient ways to do this without running loop?

Thanks in Advance.

Respected Advisor
Posts: 4,646

Re: Calculating duration from a Panel Structure

Don't know what you mean by "without running loop", but this is efficient :

data test;
informat enterDate exitDate mmddyy9.;
format enterDate exitDate mmddyy10.;
input ID     EnterDate     ExitDate     Sex $    Age;
datalines;
1        1/1/2000       1/1/2002       m       24
1        5/5/2006        5/5/2009      m       30
1        8/8/2011        8/8/2013      m       35
2        2/2/2002        2/2/2005       f        42
2        6/6/2006        6/6/2010       f        46
3        3/3/2003        3/3/2004      m       19
3        4/4/2008        4/4/2012      m       24
;

data want;
set test end=end;
if not end then do;
      set test (firstobs=2 keep=id enterDate rename=(enterDate=nextDate id=nextId));
      if id=nextId then duration = intck("DAY", exitDate, nextDate);
      end;
run;


proc print; run;

PG

PG
Super Contributor
Posts: 1,636

Re: Calculating duration from a Panel Structure

data want;

  merge test(in=a) test(firstobs=2 keep=id enterdate rename=(id=_id enterdate=_enterdate));

   duration=ifn(id=_id,intck("DAY",exitdate, _enterdate),.);

   if a;

   drop _:;

  proc print;run;

Respected Advisor
Posts: 3,124

Re: Calculating duration from a Panel Structure

Here is an obnoxious SQL approach with the undocumented feature:

data have;

input ID     (Enter_Date     Exit_Date) (:mmddyy10.)   Sex$     Age;

format     Enter_Date     Exit_Date mmddyy10.;

cards;

1        1/1/2000       1/1/2002       m       24

1        5/5/2006        5/5/2009      m       30

1        8/8/2011        8/8/2013      m       35

2        2/2/2002        2/2/2005       f        42

2        6/6/2006        6/6/2010       f        46

3        3/3/2003        3/3/2004      m       19

3        4/4/2008        4/4/2012      m       24

;

proc sql;

select a.*,b.enter_date-a.exit_date as new_date from

(select *, monotonic() as obs from have) a

left join

(select *, monotonic() as obs from have) b

on a.id=b.id and

b.obs-a.obs=1

order by id, enter_date;

quit;

Haikuo

Ask a Question
Discussion stats
  • 3 replies
  • 250 views
  • 0 likes
  • 4 in conversation