ArtC Tracker

Re: How Far Are You Willing To Go To Get To SAS Global Forum 2018

ArtC — Fri, 06 Apr 2018 18:07:18 GMT

At just over 2300 miles from Anchorage, those of us coming from AK will probably be the furthest within US travelers. But that distance is nothing compared to those coming from down under. In CA distance is measured in units of time. It seems to me that same principle should apply when flying - hours in coach (half credit if flying business class).

Re: Dress Code

ArtC — Tue, 03 Apr 2018 18:32:45 GMT

Most attendees wear business casual, although often presenters will step it up just a bit. Remember that convention center presentation rooms tend to be on the COLD side.

Re: Merge cell vertically in proc report, with missing cells, keep the order of file

ArtC — Thu, 01 Mar 2018 18:32:09 GMT

One way would be to change the value of the missings to different non printable characters. This version of the CONTROL data set will insert nonprintable values into cells with missing values. because they are different they will not group but will still be blank. You would need to adjust the code if there are more than 30 or so missing values.

data have;
input variable $ @10 group $1. @13 num;
datalines;
name        1
drugA       2
drugB    D  3
d_drug01 B  4
d_drug02 B  5
d_drug03 B  6
d_drug04 B  7
d_drug05 B  8
d_drug06 B  9
d_drug07 B  10
DrugF    C  11
DrugX    F  12
Drugy       13
Drugz       14
Drugq       15
Drugr       16
run;
data control(keep=fmtname start label);
   retain fmtname 'numord';
   set have(rename=(num=start));
   if group=' ' then do;
      cnt+1;
      label=byte(4+put(cnt,3.));
   end;
   else label=group;
   run;

proc format cntlin=control;
   run;

proc report data=have spanrows;
   column num variable;
   define num / order f=numord1. order=internal
                style(column)={vjust=c just=c};
   define variable / display;
   run;

The BYTE function creates a hex code. Hex codes from 0 - 31 are not printable so will appear as blanks (some nonprintable characters actually print in some fonts).

This seems like a hack to me so i am hoping someone else will come up with something more robust.

Re: Merge cell vertically in proc report, with missing cells, keep the order of file

ArtC — Tue, 27 Feb 2018 18:27:34 GMT

The SPANROWS option will get you closer, however the missing cells will also merge.

proc report data=have spanrows;
   column num variable;
   define num / group f=numord. style(column)={vjust=c just=c};
   define variable / display;
   run;

Re: Proc REport

ArtC — Tue, 27 Feb 2018 18:06:13 GMT

You may want to try using a multilabel format. Note the (multilabel) option on the VALUE statement and the MLF option on the DEFINE statement. Unless you are writing to the LISTING destination, you can also eliminate a number of REPORT options e.g. HEADLINE, HEADSKIP, SKIP, OL

Data TBl;
INPUT grade $ Model $ Obligo;
Cards;
a.0        a   10
a.0        b   20
b.1-6      a   30
c.7-10     a   40
d.11       a   50
d.11       b   60
e.12       a   70
e.12       b   80
;
Run;
proc format;
 value $grade (multilabel)
   'a.0'     = 'Primary'   
   'b.1-6'   = 'Primary'
   'c.7-10'  = 'Primary'
   'd.11'    = 'Primary'
   'a.0'     = 'Secondary'   
   'b.1-6'   = 'Secondary'
   'c.7-10'  = 'Secondary'
   'd.11'    = 'Secondary'
   'e.12'    = 'Secondary';
   run;


/*libname proclib 'SAS-library';*/
/*options nodate pageno=1 linesize=64 pagesize=60*/
/*fmtsearch=(proclib);*/
proc report data=TBl;
column grade=ggroup grade Model Obligo ;
define ggroup / group 'Grade Group' f=$grade. mlf;
define grade / group 'Grade';

define Model / group 'Model';
define Obligo / analysis sum
                format=comma10.
                'Ob';
/*total after each groupkCat*/
break after grade / 
/*   ol*/
   summarize
   suppress
/*skip*/
;
/*global total*/
/*rbreak after / summarize;*/
/*compute after;*/
/*type = 'Total';*/
/*endcomp;*/
run;

Re: Proc REport

ArtC — Tue, 27 Feb 2018 07:03:00 GMT

Do you want e.12 to appear in the report? I assume so otherwise you could eliminate it with a WHERE.

Re: Merge cell vertically in proc report, with missing cells, keep the order of file

ArtC — Tue, 27 Feb 2018 06:57:34 GMT

I am not sure exactly what you mean by 'merged cells'. That term has a specific meaning that to me is not implied by your question., So let me take a guess and see if it gets us closer. Do you mean that you do not want the GROUP variable to not repeat? If so then we can control order and the display of the GROUP variable through the use of a format. The following creates a format that can then be used as a grouping variable without the complicating NUM variable on the COLUMN statement.

data have;
input variable $ @10 group $1. @13 num;
datalines;
name        1
drugA       2
drugB    D  3
d_drug01 B  4
d_drug02 B  5
d_drug03 B  6
d_drug04 B  7
d_drug05 B  8
d_drug06 B  9
d_drug07 B  10
DrugF    C  11
DrugX    F  12
run;
data control(keep=fmtname start label);
   retain fmtname 'numord';
   set have(rename=(num=start group=label));
   run;

proc format cntlin=control;
   run;
proc report data=have;
   column num variable;
   define num / group f=numord.;
   define variable / display;
   run;

Re: Building Intelligent Macros: Driving a Variable Parameter System with Metadata

ArtC — Mon, 26 Feb 2018 17:23:26 GMT

Thank you @Tom for touching on the use of the %NRSTR quoting function with CALL EXECUTE - nice explanation. I have found that whether to use the PUT / %INCLUDE vs CALL EXECUTE to build the call to mostly be a personal preference. Some find it easier and others find it more confusing. I would recommend that the reader have a good understanding of both techniques and use the one that seems easiest for them. This paper does not deal with the specifics of CALL EXECUTE and as @Tom indicates there can be some 'subtle' gotchas with its use. If his comment on %NRSTR was not just a reminder, you may want to read http://www2.sas.com/proceedings/sugi22/CODERS/PAPER70.PDF .as a starter for CALL EXECUTE.

Building Intelligent Macros: Driving a Variable Parameter System with Metadata

ArtC — Fri, 23 Feb 2018 19:54:28 GMT

Abstract and online materials for this paper prepared for WUSS 2017.

Abstract

When faced with generating a series of reports, graphs, and charts; we will often use the macro language to simplify the process. Commonly we will write a series of generalized macros, each with the capability of creating a variety of outputs that depend the macro parameter inputs. For large projects, potentially with hundreds of outputs, controlling the macro calls can itself become difficult.

The use of control files (metadata) to organize and process when a single macro is to be executed multiple times was discussed by Rosenbloom and Carpenter (2015). But those techniques only partially help us when multiple macros each with its own set of parameters are to be called. This paper discusses a technique that allows you to control the order of macro calls along with each macro's parameter set using a metadata control file.

Excerpt from an example in the paper

Online Materials

View the PDF version of the complete paper here.

Sample code and control files are attached as a ZIP file

A SAS Macro Language Preview in Three Parts

ArtC — Fri, 23 Feb 2018 17:52:53 GMT

Using the macro language adds a layer of complexity to SAS programming that many programmers are reluctant to tackle. The macro language is not intuitive, and some of its syntax and logic runs counter to similar operations in the DATA step. This makes the transfer of DATA step and PROC step knowledge difficult when first learning the macro language. So why should one make the effort to learn a complex counterintuitive language?

Re: question about array coding

ArtC — Wed, 24 Jan 2018 20:43:55 GMT

As you finalize your code, be sure to make the name of the array consistent.

Re: Need Help with Proc format application.

ArtC — Tue, 16 Jan 2018 19:31:04 GMT

Although not immediately obvious (and a continuing source of confusion) there is a difference between INFORMATs (used by the INPUT statement and the INPUT function) and FORMATs (used by the PUT statement and the PUT function). The INVALUE statement in PROC FORMAT creates INFORMATs and you will notice from the previous post by @Kurt_Bremser that the type of the INFORMAT depends on the result (numeric INFORMATS yield a numeric result). FORMATS created by the VALUE statement are numeric if the incoming value is numeric.

Re: Removing a variable conditionally

ArtC — Sun, 14 Jan 2018 22:37:58 GMT

@stat_sasNice use of the ODS OUTPUT statement. If more than one variable needs to be dropped a SEPARATED BY phrase could be added to the SQL step which creates &DROP_VARS:

select Variable into :drop_vars separated by ' ' from stats

Also this will eliminate any variable with constant value, other than all missing, not just all 1's.

Re: How can I improve a proc fcmp?

ArtC — Fri, 12 Jan 2018 18:19:49 GMT

I am not sure that i understand your question, but i can see in your DATA step that you call your FCMP function. That function calls your macro and that macro (M_SeleccionaCalle), which in turn executes a number of data reads (potentially lots of I/O). All of this I/O will happen for every observation in the original incoming data set (PT_V_NEW_SALES_LOTE_ORDER_TEMP1). Without understanding your intent/objective/logic, my first thought is to try to minimize all of this I/O. Can you restructure so that the macro (M_SeleccionaCalle) is called only once instead of N times?

Re: Macro for dynamically assigning new values based on random numbers

ArtC — Thu, 11 Jan 2018 19:03:07 GMT

@Ksharp cool code, but would the following be a simpler approach?

  data want2;
   set data_1;
   random_no=1+floor(id_no*rand('uniform'));
   run;

Do we need to be sure that the random identifiers are unique?

Re: add vars to data sets with macro and call execute. What's wrong with my codes

ArtC — Thu, 11 Jan 2018 18:13:07 GMT

Your CALL EXECUTE is incorrectly specified. You have:

data _null_;

	set datanames;	

	call execute(cats('%nrstr(%addvar)(',state,sic1,')'));

run

you need to include a comma between the resolved values of state and sic1. In part:

,state , ',' , sic1, without the comma state and sic1 are being appended and passed to the first parameter which is state.

Re: add vars to data sets with macro and call execute. What's wrong with my codes

ArtC — Mon, 08 Jan 2018 19:05:42 GMT

Notice that &state contains both the state and sic codes and that &SIC is null. take a look at your code that reads the control file and builds these two variables. make sure that both are correct at that step. Try %PUT &=STATE &=SIC1;

Re: What to do in Denver?

ArtC — Sat, 23 Dec 2017 07:31:49 GMT

Although it is a bit different than in the movies, you can also tour the home of Molly Brown (the "unsinkable" one of Titanic fame).

Re: What to do in Denver?

ArtC — Tue, 19 Dec 2017 19:11:39 GMT

Just outside of Denver in the small town of Golden you can visit the Colorado School of Mines(my grad school). They also have a small brewery in Golden (Coors).

Re: Transposing multiple variables from multiple time points.

ArtC — Sat, 06 May 2017 23:57:28 GMT

SAS variable names cannot contain a dot (.) but we could use an underscore. The following transposes for 5 visits using the DATA step. This could be cleaned up and made more flexible, but it should do what you requested.

data have;
input SUBJ VISIT SITE1 SITE2 SITE3;
datalines;
1        1        3.5     4.5      2.5 
1        2        3.6     4.6      2.2
2        1        3.4     3.2      2.1
2        2        4.5     5.2      4.4
run;
data want(keep=subj site1_: site2_: site3_:);
   set have;
   by subj;
   array st1 {5} site1_1 - site1_5;
   array st2 {5} site2_1 - site2_5;
   array st3 {5} site3_1 - site3_5;
   retain site1: site2: site3: .;

   if first.subj then call missing(of st1{*} st2{*} st3{*});

   st1{visit} = site1;
   st2{visit} = site2;
   st3{visit} = site3;

   if last.subj then output want;
   run;