GraphGuy Tracker

Re: Proc gmap questions

GraphGuy — Mon, 20 Apr 2026 15:18:41 GMT

Typically, you would not want to merge your data with the map dataset.

I would recommend merging it with mapsgfk.world_attr (which contains 1 observation per country) instead.

Re: gmap version of maps.counties that uses Connecticut planning regions instead of counties

GraphGuy — Mon, 20 Apr 2026 15:08:26 GMT

When using the new CT imported from the shapefile, it is already projected, there you will not need to run the "proc gproject" on it (unless you want some other projection, in which case you can use Jeff's suggestion to deproject and get the lat/long values, so you can re-project it using any projection you want).

Here is a simple example of importing the shapefile, and plotting the already-projected map:

proc mapimport datafile="/home/u59782200/data/CT_Planning_Regions/CT_Planning_Regions.shp" out=raw_ct;
run;

proc gmap data=raw_ct map=raw_ct;
id ObjectID;
choro planningRE;

Also, I notice that your title mentions maps.counties. Note that the 'maps' library is the old/legacy SAS maps (perhaps from 1996 vintage), and you'll probably want to use the latest 'mapsgfk' library instead (for your maps other than CT). Specifically mapsgfk.us_counties (the dataset label indicates this map is based on 2021 map data in the version of SAS I'm using).

Re: GPLOT: Graphing Title, label text not visible after WPS version upgrade

GraphGuy — Mon, 20 Apr 2026 13:47:29 GMT

The goptions ctitle and ctext "should" be controlling your title and text, but I'm suspecting it is somehow coming out white on a white background instead.

Perhaps try specifying the color on the title statement itself, and see if that makes a difference, such as ...

TITLE1 color=red "test title";

Re: proc gplot-2 vars

GraphGuy — Mon, 29 Sep 2025 13:30:24 GMT

data have;
length yymm $4;
input YYMM Y :percent8.2;
format y percent8.2;
datalines;
2201 0.18%
2202 0.19%
2203 0.22%
2204 0.04%
2205 0.23%
2206 0.27%
2207 0.26%
2208 0.04%
2209 0.06%
2210 0.09%
2211 0.03%
2212 0.04%
2301 0.03%
2302 5.3%
;

data want; set have;
length date_string $8;
date_string='20'||trim(left(yymm))||'15';
format  sasdate yymmn4.;
sasdate = input(date_string,yymmdd8.);

proc print data=want; 
format sasdate date9.;

axis1 label=none minor=none offset=(0,0) order=(0 to .1 by .01);
axis2 label=('YYMM') offset=(2pct,2pct)
 order=('15jan2022'd to '15feb2023'd by month);

symbol1 value=circle height=2pct color=blue;

title1 h=5pct "Values, by Month";

proc gplot data=want;
format y percentn7.0;
plot y*sasdate/
 autovref lvref=33 cvref=gray33
 vaxis=axis1
 haxis=axis2
;

Re: Cleaning up a 3D chart

GraphGuy — Mon, 29 Sep 2025 13:06:15 GMT

 data have;
input ID Greetings;
datalines;
1 1
2 1 
3 1 
4 1
5 1
6 1
7 1
8 1
9 1
10 1
11 1
12 2
13 2
14 2
15 3
16 3
17 3
18 3
19 3
20 3
21 3
22 .
23 .
24 .
25 2
;
 
Proc format;
Value Gre
1 = 'Hello'
2 = 'Hi'
3 = 'Dear'
;

axis1 label=none minor=none order=(0 to 60 by 20) offset=(0,0);

axis2 label=('Type of Greeting') offset=(9,9);

pattern1 color=cyan;

title1 h=6pct font='albany amt/bold'  "Customized 3d Chart";

proc Gchart Data=have;
Format Greetings Gre. ;
vbar3d Greetings / 
 discrete space=7pct width=5pct
 raxis=axis1 autoref cref=gray33 lref=33 
 maxis=axis2
 type=percent
 outside=percent statfmt=comma5.0
 ;

Re: SAS color names: Why is "Blue Green" not the same as "Green Blue"?

GraphGuy — Thu, 05 Dec 2024 00:59:56 GMT

If you care about your colors, and want them to look consistent no matter what type of output you're creating (png, svg, java, activex, javaimg, actximg, pdf, etc) ... I suggest always using the hex rgb color codes.

Re: Fun With SAS ODS Graphics: How Many States Does It Take to Win a U.S. Presidential Election?

GraphGuy — Thu, 14 Nov 2024 21:04:48 GMT

Is there a way to get the lines to start at zero?

Re: Converting Latitude and Longitude for Use With Specific MAPSGFK Maps

GraphGuy — Wed, 07 Aug 2024 00:02:50 GMT

As Jeff says, Alaska & Hawaii have been moved/projected/scaled differently from the rest of the US, in this particular map (mapsgfk.us). Therefore, there is no one/simple command that will move/project/scale arbitrary lat/long coordinates and have them line up with the map.

But ... mapsgfk.uscity has applied the same move/project/scale to all the mapsgfk.uscity locations, so they line up with mapsgfk.us ... and therefore if you find the closest city to each of your lat/long locations, you could look up the x/y from mapsgfk.uscity, and plot those locations on the map. Here's a small example showing all the mapsgfk.uscity locations overlaid on mapsgfk.us:

title "mapsgfk.us with mapsgfk.uscity locations overlaid";
proc sgmap mapdata=mapsgfk.us noautolegend plotdata=mapsgfk.uscity;
choromap / mapid=statecode;
scatter x=x y=y / markerattrs=(size=1px color=red symbol=circlefilled) transparency=0;
run;

Re: Discrete Axis - Ticks at both ends when using inbetween

GraphGuy — Fri, 12 Jul 2024 13:11:56 GMT

Why would you want any ticks on that axis at all?

What purpose do they serve?

Re: Fun With SAS ODS Graphics: Stars and Popsicle Stick Stripes Forever

GraphGuy — Sat, 06 Jul 2024 19:21:30 GMT

@tc never disappoints!

Re: Difficulties getting Proc Gmap to produce annotated graph with Proc Geocode and county level map

GraphGuy — Fri, 21 Jun 2024 14:44:38 GMT

Here's how to do it without combining/projecting/separating the map & data, by using the somewhat new feature of saving the projection parameters for the map and then applying them to the annotate dataset:

data zips;
input c zip;
cards;
1 65203
2 65211
3 65201
;

proc geocode data=zips out=geocodedzips (rename=(x=long y=lat));
run;

data mocounties; set mapsgfk.us_counties (where=(statecode='MO'));
run;

proc gproject data=mocounties out=mocounties 
latlong eastlong degrees parmout=projparm;
id county;
run;

proc gproject data=geocodedzips out=geocodedzips
latlong eastlong degrees parmin=projparm parmentry=mocounties;
id;
run;

data anno_locations; set geocodedzips;
if c=1 then color="red";
if c=2 then color="bib";
if c=3 then color="viyg";
if c=4 then color="bippk";
xsys='2'; ysys='2'; hsys='3'; when='a';
function='pie'; rotate=360; size=.5;
style='psolid'; 
output;
length html $300;
html='title='||quote(trim(left(c))||'0d'x||trim(left(put(zip,z5.))));
style='pempty'; color='deb'; 
output;
run;

pattern1 v=e;

proc gmap map=mocounties data=mocounties anno=anno_locations;
id county;
choro segment / coutline=black levels=1 nolegend
coutline=gray99;

Re: Editing slice labels in a donut chart so that they don't overlap

GraphGuy — Fri, 21 Jun 2024 14:09:56 GMT

Could you provide the code you used to produce your gchart pie chart?

Re: PROC GMAP

GraphGuy — Fri, 21 Jun 2024 13:47:43 GMT

Hypothetically, you could draw bars on a 2d map using annotate (where the bar starts at the center of each state, and the height of the bars is scaled based on the data). I'm not sure it would be a great way to present data, and not sure it would be worth the work.

Re: SAS Plotter Update "Sankey diagram"

GraphGuy — Fri, 14 Jun 2024 02:50:44 GMT

Examples are a *lot* more useful, when they include the sample data!

Re: Fun With SAS ODS Graphics: Mr. Sun, Mr. Moon (Best Cities for Eclipse Viewing)

GraphGuy — Thu, 11 Apr 2024 01:56:26 GMT

The maps in the blog post show numeric (lat/long) axes - I've never seen Proc SGMAP do that. Are you 100% certain they were created with SGMAP?

Re: Fun With SAS ODS Graphics: Mr. Sun, Mr. Moon (Best Cities for Eclipse Viewing)

GraphGuy — Wed, 10 Apr 2024 01:43:15 GMT

Yep - interesting blog post. ... But it doesn't appear they used SAS to create any of the maps in the blog post(?)

Re: Need to map Lat and Long to street level

GraphGuy — Mon, 08 Apr 2024 20:50:34 GMT

Someone mentioned SAS/GIS - that would probably be the best SAS solution for this type of thing ... but it was never finished, and the current version of the software has been 'frozen' (no new decelopment) for many years, and it would be difficult to find expertise/advice/examples to help you with that.

You could plot lat/long crime data on streetmaps using SAS/Graph Proc Gmap, but it's a bit cumbersome (you have to download all the map tiles, and stitch them together, and then get a bit tricky to annotate your data onto the map tile images).

SAS Proc SGmap makes overlaying lat/long data onto streetmaps very simple - that's what I would recommend. I put an example in a blog that might get you started (sample code at bottom of the blog): https://blogs.sas.com/content/graphicallyspeaking/2021/08/17/cary-nc-data-fire-incidents/

Re: How to plot a set of unique coordinates on a map

GraphGuy — Wed, 06 Mar 2024 15:46:43 GMT

You could use the value of the 'present' variable to control the color of the dots, such as ...

data coordinates; set coordinates;

length color $12;
xsys='2'; ysys='2'; hsys='3'; when='a';
function='pie'; rotate=360; size=1.0;

if present=0 then color='red';

else if present=1 then color='green';
run;

Re: What release of SAS is used with SAS On Demand for Academics?

GraphGuy — Sat, 17 Feb 2024 17:09:46 GMT

Not sure exactly when it was upgraded, but looks like it's at 9.4m7 now (Feb 2024) ...

%put &=SYSVLONG;

SYSVLONG=9.04.01M7P080620

So a bunch of the last features added to sgmap should work now:

https://blogs.sas.com/content/graphicallyspeaking/2020/09/25/new-sgmap-features-in-sas-9-4m7/

Re: How to plot a set of unique coordinates on a map

GraphGuy — Sat, 17 Feb 2024 15:31:18 GMT

I have a couple of similar examples on this page, that might interest you. (they're on the last row of thumbnails - bottom/left):

https://robslink.com/SAS/democd_mpg/aaaindex.htm