topic Re: conditional cell formating in Statistical Procedures

conditional cell formating

emin_ch — Tue, 20 Jan 2015 16:03:10 GMT

hi,

i got a table like this one:

Treatment	Infection1	Infection2	p_value
A	3.45	4.64	0.683
B	4.32	9.17	0.04
C	2.99	1.04	0.02

and i would like to apply the backgroundcolor=green for the p_value if infection2 is lower then infection1 AND backgroundcolor=red if infection2 is higher than infection1. do somebody know a simple way to change the cell style based on these two conditions?

kind regards

emin

Re: conditional cell formating

emin_ch — Tue, 20 Jan 2015 16:13:43 GMT

i forgot to say that i use proc print. but if it is complicated for proc print procedure i can use proc report too.

thanks,

emin

Re: conditional cell formating

RW9 — Tue, 20 Jan 2015 16:14:47 GMT

Hi,

There are a few papers on changing cell style using proc report and compute blocks. Here is one for starters:

http://support.sas.com/resources/papers/proceedings09/273-2009.pdf

Re: conditional cell formating

emin_ch — Tue, 20 Jan 2015 16:28:48 GMT

thanks RW9!

i have to say that all examples which i read until now changes the cell format based on the value of the cell itself, and my problem is that the formatting of the cell (p_value) should be based on two conditions: infection2>infection1 and p_value<0.05. can i implement two conditions in the same time in proc template, in proc report or elsewhere?

Re: conditional cell formating

RW9 — Tue, 20 Jan 2015 18:03:59 GMT

Yes, you should be able to do that with if statements in the compute, I am not work to test, but something along the lines of:

compute p_value;

if infectiom2 > infection and p_value < 0.05 then call define('p_value','style','style=[background=green]');

endcomp;

Worst comes to worst, do the logic in a datastep, have a noprint variable with binary 1 or 0 and use that in your if statement.

You can reference specific columns/rows/cells also:

http://www2.sas.com/proceedings/forum2008/224-2008.pdf

Some other papers:

http://support.sas.com/rnd/papers/sgf07/sgf2007-report.pdf

Re: conditional cell formating

Ksharp — Wed, 21 Jan 2015 07:12:36 GMT

This would be better for proc report.

and next time , post such questions at ODS and Base Reporting could get a good answer.

data have;
input Treatment     $ Infection1     Infection2     p_value     ;
cards;
A     3.45     4.64     0.683
B     4.32     9.17     0.04
C     2.99     1.04     0.02
;
run;
ods listing close;
ods html file='c:\temp\x.html' style=sasweb;
proc report data=have nowd;
columns Treatment  Infection1 Infection2 p_value;
define Treatment/display;
define Infection1/display;
define Infection2/display;
compute p_value;
 if Infection1 gt Infection2 then call define(_col_,'style','style={background=green}');
  else  call define(_col_,'style','style={background=red}');
endcomp;
run;
ods html close;
ods listing;

XIa Keshan

Re: conditional cell formating

emin_ch — Mon, 26 Jan 2015 14:57:47 GMT

Thank you guys!! Everything works as desired.