topic factorial split-plot (how to combine 2 years?) in Statistical Procedures

factorial split-plot (how to combine 2 years?)

alex2200 — Thu, 10 Apr 2014 07:33:53 GMT

I am elementary user of sas, my experiment was 2 years agricultural experiment.

The experiment was laid out in the factorial split-plot arrangement based on a randomized complete block (RCB).

I can analysis of this experiment in one year by sas.

I know the script ( code) of it in sas:

data;
input a b c block y1;
cards;
;

proc anova;
classes block a b c;
model y1=block a b a*b block(a b) c a*c b*c a*b*c;
test h=a e=block(a b);
test h=b e=block(a b);
test h=a*b e=block(a b);
means a/duncan alpha=0.01 e=block(a b);
means b/duncan alpha=0.01 e=block(a b);
means c/duncan alpha=0.01;
means a*b a*c b*c a*b*c;
run;quit;

But my problem is the combine of 2 years.

does any body know the script ( code ) of it? can any body help me?

Re: factorial split-plot combined experiment

alex2200 — Thu, 10 Apr 2014 10:49:42 GMT

please help me ! it is so important for me. I googled it in internet . also I have been read all of my statistics books. but I could not find appropriate answer.

please help me

Re: factorial split-plot combined experiment

SteveDenham — Thu, 10 Apr 2014 12:05:23 GMT

Hi Alex,

Let me ask some questions first. When you say two years--are the treatments (a b c) applied to the same plots in both years? If so, then it could be addressed as a repeated measures design. If not, then you will need to decide whether to consider year as a fixed effect or a random effect. With only two years worth of data, it is probably more appropriate to consider it as a fixed effect, giving rise to a split-split plot design. One thing of great importance is that PROC ANOVA and PROC GLM do not correctly calculate standard errors of factors in a split-plot design (see SAS System for Mixed Models by Littell et al., either edition). This reference has an entire chapter on fitting models to split-plot designs.

With an answer to the question above about design, we can adapt your code to PROC MIXED and obtain a more appropriate analysis.

Steve Denham

Re: factorial split-plot combined experiment

alex2200 — Thu, 10 Apr 2014 13:11:39 GMT

thank you very much indeed for your answer SteveDenham.

yes the treatments was applied to the same plots in both year , so I think, it can addressed as a repeated measures design.

I heard about proc anova and proc glm which they do not work correctly in split plot design, but in some references and Class notes anova and proc glm was used for analysis split plot design for one year expriment. the question is that: does that not work correctly for one year analysis? or it doses not work correctly for 2 years combine just?

thank you again

Re: factorial split-plot combined experiment

lvm — Thu, 10 Apr 2014 16:02:29 GMT

GLM and ANOVA procs are always wrong for split-plots.

Re: factorial split-plot combined experiment

alex2200 — Thu, 10 Apr 2014 16:37:28 GMT

ok! I accept that

so could any body help me about PROC MIXED code of one year and combine of 2 years?

Re: factorial split-plot combined experiment

lvm — Thu, 10 Apr 2014 17:33:08 GMT

You need to better explain your design. Do you have a, b, and c, plus year, or is year one of the letters in your code? A split plot would normally have two fixed effect factors, not three. It looks like you have two factors crossed at the higher level (a and b), and then c is the sub-plot (within the axb combination). Is this right?

Re: factorial split-plot combined experiment

alex2200 — Thu, 10 Apr 2014 19:05:45 GMT

thank you for answer lvm

ok I explain my design:

The experiment was laid out in the factorial split-plot arrangement based on a randomized complete block (RCB).

we had 3 factor

A , B and C

factor A had 3 treatments

factor B had 2 treatments

factor c had 2 treatments

factor a and b were in main plot ( factorial)

and factor c was in sub plot ( split plot)

( so I think you say right lVm)

we had 4 replication

the year is not one of the letter in code. and all of the factors (A and B and c) is agricultural factor.

I want the:

1. code of analyses of one year

2. the cod of analysis of combined experiments ( 2 year)

in PROC MIXED( please).

It would be appreciated if you could help me

Re: factorial split-plot combined experiment

lvm — Thu, 10 Apr 2014 19:48:21 GMT

Here is the mixed code for one year (split plot with two whole plots).

proc mixed;

classes block a b c;

model y1= a|b|c ;

random block block(a b);

lsmeans a|b|c / alpha=0.01 diff adjust=simulate ;

run;

Random effects are only listed in a random statement. All the tests are conducted correctly and automatically (no TEST statements, etc.). See how easy it is. Duncan adjustments are not available, and are not recommended. I put in simulation adjustment, which is now considered a good choice.

I actually think you should use a Kenward-Roger df adjustment also. Change model statement to:

model y1= a|b|c / ddfm=kr ;

Now, we can consider year to be a repeated measure within the block*a*b*c experimental units (you said the same plot is observed for each year). I consider year to be a fixed effect. With only two years, the covariance structure has limited structure, so we can consider compound symmetry. This is the same then as a split-split plot with blocks. I doubt if you want all the interactions with year (you will never be able to interpret all the 2x,3x, and the 4x interaction). But I will write the model (one possibility) with the four way interaction:

proc mixed;

classes block a b c year;

model y1= a|b|c|year / ddfm=kr ;

random block block(a b) block(a b c);

lsmeans a|b|c / alpha=0.01 diff adjust=simulate ;

*you can add more LSMEANS statements here, say for specific year interactions;

run;

The above assumes that the data are stacked, with a year variable added and a separate record for each year.

If you had more than two times, you must consider more complex covariance structures. A more general approach for any number of times for the repeated measure is to use:

proc mixed;

classes block a b c year;

model y1= a|b|c|year / ddfm=kr ;

random block block(a b) ;

repeated year / subject=block*a*b*c type=ar(1) ; *there are many choices for type;

lsmeans a|b|c / alpha=0.01 diff adjust=simulate;

*you can add more LSMEANS statements here, say for specific year interactions;

run;

proc mixed;

classes block a b c year;

model y1= a|b|c|year / ddfm=kr ;

random block block(a b) random block(a b c) ;

repeated year / subject=block*a*b*c type=ar(1) ;

lsmeans a|b|c / alpha=0.01 diff adjust=simulate;

*you can add more LSMEANS statements here, say for specific year interactions;

run;

I expect that some variance components will be 0. One approach is to then remove them.

Re: factorial split-plot combined experiment

Herwibawa — Tue, 11 Aug 2015 15:51:29 GMT

Hi,

I'm elementary user of sas and was working on split plot design and it will then be followed by Duncan Multiple Range Test. Please kindly help me to correct my sintax :

data Yield;

input A $ B $ Block Yield;

treatment = K||X;

cards;

K1 X1 2 7

;

proc anova data=Yield;

class Block A B;

model Yield=A B A(Block) B A*B;

means A B A*B / duncan e=A(Block);

run;

proc anova data=Yield;

class treatment Block;

model Yield=treatment Block;

means treatment/duncan;

run;

Re: factorial split-plot combined experiment

SteveDenham — Tue, 11 Aug 2015 18:39:43 GMT

Use the code that was provided by @lvm, with minor changes as needed. Note that PROC ANOVA and PROC GLM do NOT correctly analyze split-plot designs.

Also, seriously consider ad different adjustment method than Duncan's New Multiple Range Test. It is neither new nor truly a multiple range adjustment. There is extensive literature in this area, and better options are outlined in the LSMEANS documentation.

Steve Denham

Re: factorial split-plot combined experiment

lvm — Tue, 11 Aug 2015 18:50:45 GMT

Never, ever, use PROC ANOVA or PROC GLM for split plots, Standard errors will be wrong. Use MIXED or GLIMMIX. The later are much easier anyway: by specifying random effects, the procedure knows how to do each appropriate test. Here is code assuming that A is the whole plot and B is the subplot.

proc glimmix data = ;

class block A B;

model yield = A|B;

random block A*block

lsmeans A B A*B / diff adjust=simulate;

run;

Duncan multiple range is definitely out of favor, and can't be done with MIXED or GLIMMIX. I personally recommend adjust=simulate (fewer unrealistic assumptions).

Re: factorial split-plot combined experiment

Herwibawa — Wed, 12 Aug 2015 02:35:05 GMT

A very big thank you both @SteveDenham and @lvm for your advices. I have just revised my codes, and could then you want to help to correct my codes below. However, how to compare each treatment to others ? meanwhile I can't use Duncan in Proc Mixed, can you ? If so, I propose to use "adjust = DUNNET" to compare with control, am I wrong ? but I didn't understand how to interpret it in my paper with a,b,c, notation, it's looked very different results of "means A B A*B / DUNCAN e=A(Block)" in Proc Anova. Please help me...

data sp;

input A $ B $ Block Y;

datalines;

A1 B1 1 72

A1 B1 2 63

A1 B2 1 45

A1 B2 2 30

A1 B3 1 4

A1 B3 2 7

A2 B1 1 23

A2 B1 2 27

A2 B2 1 85

A2 B2 2 65

A2 B3 1 55

A2 B3 2 58

A3 B1 1 5

A3 B1 2 8

A3 B2 1 23

A3 B2 2 21

A3 B3 1 15

A3 B3 2 19

A4 B1 1 30

A4 B1 2 39

A4 B2 1 42

A4 B2 2 44

A4 B3 1 12

A4 B3 2 18

;

proc mixed;

class A B Block;

model Y = A B A*B;

random Block A*Block;

lsmeans A|B / adjust=DUNNETT;

run;

Re: factorial split-plot combined experiment

lvm — Wed, 12 Aug 2015 14:22:45 GMT

Remember, don't try comparing your results to the ANOVA output. The latter will be wrong for several parts of the mean comparisons! I am not sure what you are asking; it is fine to use the dunnett method, but be careful, SAS is deciding on the level of the factors to use as the control (the default is the first level of A and the first level of B). This can be altered with diff= option. Not sure what you mean about letters. I am guessing you want to see a table of means followed by mean separation letters. This is only done when all combinations of means are compared, not just with the control. You can do this with GLIMMIX, not MIXED, using the LINES option on the LSMEANS statement (as long as you use an adjustment that gives all mean comparisons). The code below does this. Note that you have a significant interaction, and the multiple comparison table is for theinteractions. However, most would argue that you would want to restrict comparisons to all levels of A at each level of B, or all levels of B at each level of A (the so-called simple effects). To get this, add the line:

slice A*B / sliceby=B adjust=simulate lines;

to get the simple effects for each level of B (as an example).

proc glimmix;

class A B Block;

model Y = A B A*B;

random Block A*Block;

lsmeans A|B / adjust=simulate lines;

run;

Re: factorial split-plot combined experiment

Herwibawa — Thu, 13 Aug 2015 04:59:52 GMT

Thank you very much @lvm for your advices, I had tried to add the line :

proc glimmix;

class A B Block;

model Y = A B A*B;

random Block A*Block;

lsmeans A|B / adjust=simulate lines;

run;

But, It didn't work on my SAS software, since I was using SAS 9.1. So, I revised the line :

proc mixed;

class A B Block;

model Y = A B A*B;

random Block A*Block;

lsmeans A B A*B / adjust=simulate;

run;

The result of "lsmeans A B A*B / adjust=simulate;" is attached below :

http://s24.postimg.org/jkl2xcdxh/image.jpg

(be sorry I fell to insert an image)

However, I haven't understood yet how to interpret or read the result of "Lsmeans" on the image above ? so I can get a similar explain of "Interaction A*B", while it should be more easy to read when I analyzed using Duncan to get A B C notation some like on the image below.

http://s12.postimg.org/gvn43353h/image.jpg

Please help me it is so important for me...

Re: factorial split-plot combined experiment

SteveDenham — Thu, 13 Aug 2015 11:59:11 GMT

I am going to argue against the use of the Dunnett adjustment in the face of a model that has an interaction, as it is designed for comparison to a single control (see for example Chapters 3, 4 and 9 in Multiple Comparisons and Multiple Tests Using SAS by Westfall et al.). They make a very strong case for the use of the adjust=simulate option for higher order ANOVAs and mixed models.

Steve Denham

Re: factorial split-plot combined experiment

lvm — Thu, 13 Aug 2015 20:04:36 GMT

Too bad you don't have a newer version of SAS, because the LINES option and SLICE statement in GLIMMIX do exactly what you want! If you are in education or noncommercial activity, you can always install SAS University Edition (it is free),. and it is always the newest version. But that would take a while for you to learn about. With only 9.1, the table of mean differences you showed would have to be translated by you, by hand, into the letter (lines) display. You sort the means from high to low (or low to high), and then figure out which ones are different (different letters) and which ones are the same using the difference table. This can be tedious and take a while.

You have an alternative that I think (?) should work in 9.1 (not absolutely sure). You can use the macro written by Hans-Peter Piepho. See the article here.

You would need to download the macro and run it first (every time you launch SAS for the mean separation analysis). Then you follow the directions in the article to get the letter display. Note that you have to use the ODS output statement to save LSMEANS and mean differences from a MIXED run. With the interaction, you do slices of one factor at fixed values of the other. Good luck.(By the way, the macro can also do things not possible with the LINES option in current versions of SAS, but that is not relevant for your application).

http://agrobiol.sggw.waw.pl/~cbcs/articles/CBCS_7_1_2.pdf

You do need PROC IML for the macro to work. Message was edited by: Larry Madden

Re: factorial split-plot combined experiment

Herwibawa — Wed, 19 Aug 2015 01:34:44 GMT

A very big thank you @Larry Madden, I have installed SAS University Edition.

anyway I'm facing a new problem, in which several plants had died, even of plants in one of the treatment combination. So, what should I do ?

Ok, I'll explain my data;

A1 B1 1 died

A1 B1 2 20

A1 B1 3 died

A1 B1 4 died

A1 B1 5 died

A1 B2 1 died

A1 B2 2 13

A1 B2 3 died

A1 B2 4 12

A1 B2 5 10

A1 B3 1 died

A1 B3 2 died

A1 B3 3 died

A1 B3 4 15

A1 B3 5 17

A2 B1 1 died

A2 B1 2 died

A2 B1 3 died

A2 B1 4 died

A2 B1 5 died

A2 B2 1 died

A2 B2 2 28

A2 B2 3 died

A2 B2 4 died

A2 B2 5 30

A2 B3 1 17

A2 B3 2 15

A2 B3 3 16

A2 B3 4 died

A2 B3 5 18

A3 B1 1 5

A3 B1 2 died

A3 B1 3 10

A3 B1 4 died

A3 B1 5 died

A3 B2 1 died

A3 B2 2 10

A3 B2 3 8

A3 B2 4 9

A3 B2 5 died

A3 B3 1 died

A3 B3 2 5

A3 B3 3 died

A3 B3 4 10

A3 B3 5 6

It would be appreciated if you could help me

Re: factorial split-plot combined experiment

SteveDenham — Wed, 19 Aug 2015 11:53:34 GMT

All that I have to offer comes from digging through the documentation. This looks like a mixture of distributions: one is a binomial as to whether a plant lived or died, the other is a normal that describes the response. It may be possible to use something like PROC FMM to do this, but it does not handle random effects, so all of the old tricks used in GLM would have to be applied to get reasonable estimates.

The easiest answer is to assume that plants died at random, so that the data are what is called missing at random. In that case, recode 'died' as missing values ( . ), and analyze as previously outlined.

Steve Denham

Re: factorial split-plot combined experiment

Herwibawa — Fri, 11 Sep 2015 10:52:37 GMT

My experiment arranged in Split Plot design. How to make a Charts/ Boxplots for Proportions of a Binary Variable ?

data Survival;

input A $ B $ Block Y; if Y=1 then 1='Survive'; else 0='Died';

datalines;

A1 B1 1 0

A1 B1 2 1

A1 B1 3 0

A1 B1 4 0

A1 B1 5 0

A1 B2 1 1

A1 B2 2 1

A1 B2 3 1

A1 B2 4 1

A1 B2 5 0

A1 B3 1 1

A1 B3 2 0

A1 B3 3 0

A1 B3 4 1

A1 B3 5 1

A2 B1 1 0

A2 B1 2 0

A2 B1 3 0

A2 B1 4 0

A2 B1 5 0

A2 B2 1 1

A2 B2 2 0

A2 B2 3 0

A2 B2 4 1

A2 B2 5 0

A2 B3 1 1

A2 B3 2 1

A2 B3 3 1

A2 B3 4 0

A2 B3 5 1

A3 B1 1 1

A3 B1 2 0

A3 B1 3 1

A3 B1 4 0

A3 B1 5 0

A3 B2 1 0

A3 B2 2 1

A3 B2 3 1

A3 B2 4 1

A3 B2 5 0

A3 B3 1 0

A3 B3 2 1

A3 B3 3 0

A3 B3 4 1

A3 B3 5 1

;

Is it true when it displayed in as shown below ? how to write the codes ?

Please help me it is so important for me...