How do I obtain pairwise differences in proc mianalyze?

chepchep — Mon, 14 Jul 2025 14:38:12 GMT

Hello,

I am trying to analyze an imputed dataset. Everything runs okay except for proc mianalyze where I run into some problems. I am tyring to get pairwise differences of my class variable which has 3 categories.

Here is the code that I am using:

proc genmod data=mi_out;
by _imputation_;
/* Process each imputed dataset */
class matchid rand2;
/* 'matchid' identifies matched pairs,
'treatment' is the variable of interest */
model DIFF = rand2 / dist=normal;
/* 'outcome' is the continuous outcome */
repeated subject=matchid / type=cs;
/* Matched pairs, compound symmetry */

/* Define pairwise comparisons using ESTIMATE statements */
estimate 'rand2_1_vs_rand2_2' rand2 1 -1 0;
estimate 'rand2_1_vs_rand2_3' rand2 1 0 -1;
ods output estimates=pairwise_estimates; /* Save estimates */
run;

proc mianalyze parms=pairwise_estimates;
modeleffects rand2_1_vs_rand2_2 rand2_1_vs_rand2_3 ;
run;

When I run the proc mianalyze, I get the following error:

ERROR: Variable PARAMETER, EFFECT, VARIABLE, PARM, or ROWNAME must be in the PARMS= data set.

can someone please help me understand why I am getting this error, or how I can obtain the pairwise differences?

Re: How do I obtain pairwise differences in proc mianalyze?

SAS_Rob — Mon, 14 Jul 2025 15:12:00 GMT

You need to sort the Estimates data set by the label and then MIANALYZE BY LABEL to combine the results. You should also use the DATA= input data set since it is not a data set of parameter estimates.

Add the following just after the GENMOD step

proc sort data=pairwise_estimates;;
by label _imputation_;
run;

proc mianalyze data=pairwise_estimates;;
by label;
modeleffects LBetaEstimate;
stderr stderr;
run;

topic Re: How do I obtain pairwise differences in proc mianalyze? in Statistical Procedures

How do I obtain pairwise differences in proc mianalyze?

Re: How do I obtain pairwise differences in proc mianalyze?