topic Re: Plots in Statistical Procedures

Plots

josecorrente — Wed, 28 May 2025 12:05:34 GMT

Hi all good morning

I would like to ask you how I can change symbols in SGPLOT procedure for different groups using scatter and series.

Thanks in advance

José Eduardo

Re: Plots

PaigeMiller — Wed, 28 May 2025 13:08:02 GMT

If you have multiple groups on a plot, you can use the STYLEATTRS command in PROC SGPLOT to designate symbols for each group, and specify the desired symbols in the DATASYMBOLS= option.

Example:

proc sgplot data=sashelp.class;
    styleattrs datasymbols=(diamond circle) datacontrastcolors=(red green);
    scatter x=height y=weight / group=sex;
run;

Re: Plots

josecorrente — Fri, 30 May 2025 11:24:38 GMT

Hi pagemiller
Thank you for your reply. The problem is I am using scatter and series at the same plot (overlaid) and I am not get different symbols for grous. Using styleattrs it considers only the last symbol. The colors are ok. Do you have any suggestions to use different symbols? Thanks in advance.

Re: Plots

PaigeMiller — Fri, 30 May 2025 11:31:48 GMT

Show us the code you are using. Paste your code into the code box (it pops up when you click on the "little running man" icon)

Re: Plots

josecorrente — Fri, 30 May 2025 14:01:18 GMT

Hi pagemiller
The code is:

proc sgplot data=Out11;
styleattrs datasymbols=(diamond circle ) datacontrastcolors=(black grey )
datalinepatterns=(solid dot );
scatter y=mean x=time /group=zygosity markerattrs=( size=6 );;
series y=pred x=time /group=zygosity markerattrs=( size=6 );
run;

The scatter plot is for the observations and the series is for a b-spline fit for these data.

Thanks in advance

Re: Plots

PaigeMiller — Fri, 30 May 2025 14:34:02 GMT

Repeating the instructions I gave earlier:

Paste your code into the code box (it pops up when you click on the "little running man" icon)

Re: Plots

Rick_SAS — Fri, 30 May 2025 19:40:33 GMT

> I am not getting different symbols for groups.

First, you might want to read an article that describes the interaction between ATTRPRIORITY, CYCLEATTRS, and STYLEATTRS in ODS graphics. It might be that what you are seeing (or what you want to see) requires that you understand how these options interact.
It sounds like you might want to use ATTRPRIORITY=NONE, which enables the symbol to automatically change for different groups.

Since we don't have your data, let's use data that we all have. The following creates some data for this example that (hopefully!) is similar to yours:

data Out;
set sashelp.stocks(keep=Stock Date Open where=(Date<'01JAN1991'd));
rename date=Time Open=mean;
run;
proc sort data=Out;
  by Time Stock;
run;
/* write spline predictor to OUT2 data set in the PRED variable */
proc glmselect data=Out;
  effect spl = spline(Time / basis=bspline knotmethod=equal(9));
  class Stock;
  model mean = spl | stock / selection=none;
  output out=out2 pred=pred;
run;

Now let's graph the data. The following sets ATTRPRIORITY=NONE and lets the symbols, colors, and line styles change according to the ODS style.

ods graphics / AttrPriority=NONE;
proc sgplot data=Out2;
   scatter y=mean x=time /group=Stock;
   series y=pred x=time / group=Stock;
run;

The output is below. Note that the colors, symbols, and line patterns are different for all groups.

If you want to override the default colors or symbols or patterns, you can use the STYLEATTRS statement, as Paige suggested. You can override 1, 2, or all three attributes. In the following, I set all line patterns to SOLID, but specify colors and patterns for the markers and lines:

ods graphics / AttrPriority=NONE;
proc sgplot data=Out2;
   styleattrs datalinepatterns=(solid)
              datacontrastcolors=(SteelBlue DarkGreen DarkRed)
              datasymbols=(CircleFilled TriangleFilled X);
   scatter y=mean x=time /group=Stock markerattrs=( size=6 );
   series y=pred x=time / group=Stock;
run;

Please read the article and study the examples. Hope this helps!

Re: Plots

Season — Sat, 31 May 2025 07:08:15 GMT

I used to create plots where different groups are displayed in different color and line patterns and therefore encountered the AttrPriority option in ODS GRAPHICS. I read the relevant introduction to that option given in SAS Help, but I was still rather confused on its utility. Could you please briefly explain it? Thank you!

Re: Plots

Rick_SAS — Sat, 31 May 2025 10:08:34 GMT

Yes, happy to. Please see Attrs, attrs, everywhere: The interaction between ATTRPRIORITY, CYCLEATTRS, and STYLEATTRS in ODS graphics - The DO Loop

and the links therein.

Re: Plots

Season — Sat, 31 May 2025 14:04:24 GMT

Thank you so much for a response well more informative than I originally anticipated! Have a nice weekend!

Re: Plots

josecorrente — Wed, 04 Jun 2025 19:14:44 GMT

Thank you very much for you reply. I will read the article and try in my data. Sincerely
Jose Eduardo