topic Help with fixing this for finding the 95% CI for the mean. in Statistical Procedures

Help with fixing this for finding the 95% CI for the mean.

KB131619 — Tue, 04 Mar 2025 17:14:26 GMT

Options NoNumber NoDate;
Data assignment4number6;
xbar = 53.87;
alpha = 0.05;
n=50;
s2 = 97.8121;
Proc Means NoPrint;
Output Out=Stat mean=xbar Var=s2 n=n;

Data assignment4number6;
t = tinv(1-alpha/2, (n-1));
sep = Sqrt(s2/n);
L1 = xbar - t*sep;
L2 = xbar + t*sep;
run;
Proc Print; Var t alpha sep L1 L2;
RUN;

I am trying to modify a program to get what I have here by hand. Any help is appreciated.

Re: Help with fixing this for finding the 95% CI for the mean.

sbxkoenk — Tue, 04 Mar 2025 18:51:08 GMT

Options NoNumber NoDate;
Data assignment4number6;
xbar = 53.87;
alpha = 0.05;
n = 50;
s2 = 97.8121;
t = tinv(1-alpha/2, (n-1));
*t = 2.010;
sep = sqrt(s2/n);
L1 = xbar - t*sep;
L2 = xbar + t*sep;
format t alpha sep L1 L2 14.7;
run;
Proc Print data=assignment4number6; 
 Var t alpha sep L1 L2;
run;
/* end of program */

Koen

Re: Help with fixing this for finding the 95% CI for the mean.

Ksharp — Wed, 05 Mar 2025 01:34:04 GMT

Options NoNumber NoDate;
Data assignment4number6;
xbar = 53.87;
alpha = 0.05;
var = 97.8121;

n = 50;
t = quantile('t',1-alpha/2, (n-1));
/*putlog t=;*/
stderr = sqrt(var/n);
L1 = xbar - t*stderr;
L2 = xbar + t*stderr;
output;


n = 100;
t = quantile('t',1-alpha/2, (n-1));
/*putlog t=;*/
stderr = sqrt(var/n);
L1 = xbar - t*stderr;
L2 = xbar + t*stderr;
output;

format t alpha stderr L1 L2 14.7;
run;
Proc Print data=assignment4number6; 
 Var n t alpha stderr L1 L2;
run;

Re: Help with fixing this for finding the 95% CI for the mean.

sbxkoenk — Wed, 05 Mar 2025 12:41:45 GMT

The TINV function returns the p-th quantile from the Student's t distribution with degrees of freedom df and a noncentrality parameter nc. The probability that an observation from a t distribution is less than or equal to the returned quantile is p.
TINV accepts a noninteger degree of freedom parameter df. If the optional parameter nc is not specified or is 0, the quantile from the central t distribution is returned.
The QUANTILE function returns the quantile from a distribution that you specify. The QUANTILE function is the inverse of the CDF function.
You must also specify a degree of freedom parameter df and optional noncentrality parameter nc.

I think the quantile feature is more recent and obviously more general (since you can put "all" distributions in it).

BR, Koen

Re: Help with fixing this for finding the 95% CI for the mean.

Ksharp — Thu, 06 Mar 2025 01:33:05 GMT

Yeah. TINV function is obsoleted , now should use QUANTILE function .