topic Re: estimates in proc logistic when predictor is a continuous var in Statistical Procedures

estimates in proc logistic when predictor is a continuous var

palolix — Sat, 16 Nov 2024 02:10:01 GMT

Dear SAS community,

Since the lsmeans/ilink option is not supported in proc logistic when the predictor var is continuous, I tried the following estimates:

My outcome var is ordinal (1,2,3,4,5,6,7,8,9) and my predictor DM continuous. I would like to know the predicted prob for hedonic=5 and 6 at DM=22.8.

proc logistic data=one desc;
model hedonic= DM/link=clogit;
estimate "Pr prob hedonic=5 at DM=22.8" intercept 1 DM 22.8/ilink category='5';
estimate "Pr prob hedonic=6 at DM=22.8" intercept 1 DM 22.8/ilink category='6';
run;

I would greatly appreciate if you could let me know if this looks ok to you.

Thanks a lot!

Re: estimates in proc logistic when predictor is a continuous var

StatDave — Sat, 16 Nov 2024 03:32:21 GMT

Since you want predicted probabilities for individual levels of your response from this ordinal model, the clearest way to get them is to create a one observation data set to be scored with DM at the desired level and then use the OUTPUT statement with the PREDPROBS=INDIVIDUAL option. This option produces the predicted probabilities of the individual response levels. To illustrate, use the DocVisit data set in the example titled "Partial Proportional Odds Model" in the PROC LOGISTIC documentation. To simplify the example, the following statements combine all the higher response levels into level 3, so that the new response variable, DV, has levels 0, 1, 2, or 3.

data dv; set docvisit; 
  dv=dvisits; if dvisits>2 then dv=3; 
  run;

and then create a one observation data set with the predictor, INCOME, set to the desired level (let's use 0.25) and the response set to missing and add it to the original data so that this observation does not get used when fitting the model. The SCORE variable is created so that this observation can be singled out for saving by the WHERE clause in the PROC LOGISTIC OUTPUT statement.

data score; income=0.25; dv=.; score=1; run;
data dv2; set score dv; run;

Now, fit the ordinal model using INCOME as the predictor. The EFFECTPLOT gives you a visual image of how the individual response level probabilities change with INCOME. The OUTPUT statement produces the individual response level probabilities and the probabilities cumulated over the lower response levels (0, up to 1, up to 2, and up to 3). The ESTIMATE statement with the ILINK option can only produce the cumulative probabilities. The CATEGORY=JOINT option gives each of the cumulative probabilities in a single table.

proc logistic data=dv2; 
model dv=income; 
effectplot / individual;
output out=out(where=(score=1)) predprobs=(cumulative individual); 
estimate 'P(dv=1 @ .25)' intercept 1 income .25 / ilink category=joint;
run;

These statements print the one observation at INCOME=0.25 and its cumulative (beginning with CP_) and individual level (beginning with IP_) predicted probabilities.

proc print data=out;
id income; var ip: cp:; 
run;

Notice that the cumulative predicted probabilities are the same as those from the ESTIMATE statement. The differences between successive cumulative predicted probabilities are the individual predicted probabilities.

Re: estimates in proc logistic when predictor is a continuous var

palolix — Sat, 16 Nov 2024 22:07:23 GMT

Great, I got the same results using this approach, thank you so much StatDave!

Question: when using proc logistic with a categorical outcome variable with more than two levels, do I have to include it in the class statement and specify a baseline category using (ref=)?

Thanks!

Re: estimates in proc logistic when predictor is a continuous var

StatDave — Sat, 16 Nov 2024 22:15:34 GMT

No. When modeling a categorical response (binary, ordinal, or nominal) in any procedure (LOGISTIC, GENMOD, HPGENSELECT, etc.), it is best to not include it in the CLASS statement. If you want to set a reference level (for a binary or nominal responses) or to change the direction of an ordinal response, use the options following the response in the MODEL. For example: model y(ref='1') = .... / link=glogit;

Re: estimates in proc logistic when predictor is a continuous var

palolix — Sat, 16 Nov 2024 22:30:52 GMT

Ok, good to know. Thank you very much StatDave!

Re: estimates in proc logistic when predictor is a continuous var

SteveDenham — Tue, 19 Nov 2024 17:37:25 GMT

Note that "etc." in @StatDave 's response does not, so far as I can tell, include GLIMMIX. For some reason, a multinomial response variable must be included in the CLASS statement for things to not error out.

SteveDenham

Re: estimates in proc logistic when predictor is a continuous var

palolix — Tue, 19 Nov 2024 19:05:14 GMT

Thank you for letting me know Steve, that's good to know, I hope I can remember that when using Glimmix.

I have a question regarding regression analysis. I know that the higher the r-square value the better, but is there a minimum r-square value in order to make meaningful predictions?

Thank you Steve!

Re: estimates in proc logistic when predictor is a continuous var

Ksharp — Wed, 20 Nov 2024 02:23:03 GMT

r-square value of model is just a square of pearson correlation coefficient between Y variable and Predicted Y variable.

In other words, r in r-square is a pearson correlation coefficient between Y variable and Predicted Y variable.

proc glm data=sashelp.class;
model weight=height age;
output out=want p=pred;
quit;

You can use PROC CORR to do correlation coefficient significant test .

proc corr data=want;
var weight pred;
run;

Here 0.87915*0.87915= 0.7729 (the same as r-square of model)

You can check the p-value (marked as yellow) to see if r-square is significant.

Re: estimates in proc logistic when predictor is a continuous var

sajjad1122 — Wed, 20 Nov 2024 08:03:00 GMT

Your approach is mostly correct, but a couple of things to adjust:

Intercept: You may need to reference specific threshold values for hedonic = 5 and 6 instead of using a generic intercept 1.
Category Option: The category option isn't supported in proc logistic. Use proc plm to compute predicted probabilities or adjust your estimates using the model thresholds.
This should help you get the correct predicted probabilities.

Re: estimates in proc logistic when predictor is a continuous var

StatDave — Wed, 20 Nov 2024 20:25:37 GMT

The CATEGORY= option is indeed supported in PROC LOGISTIC. Perhaps you are using a much older release. If you add the E option in the ESTIMATE statement in my example below, the resulting table shows that each estimate it produces uses, in turn, one of the intercepts so that each estimate in the resulting set appropriately gives the predicted probability for one particular response level. Also, if you change LOGISTIC to GLIMMIX in the code, and run it with just the MODEL statement and add the DIST=MULT option, it runs fine without having the response in the CLASS statement.

Re: estimates in proc logistic when predictor is a continuous var

palolix — Thu, 21 Nov 2024 00:16:16 GMT

Thank you so much for your suggestion Ksharp. To use Pearson corr between two variables, neither of the variables can be the response or outcome var?

Re: estimates in proc logistic when predictor is a continuous var

palolix — Thu, 21 Nov 2024 00:17:49 GMT

Thanks for your clarification StatDave!

Re: estimates in proc logistic when predictor is a continuous var

Ksharp — Thu, 21 Nov 2024 00:41:37 GMT

What do you mean by that ?
these two variable: one is original response variable Y,another is Y hat(the predicted value of Y).

Re: estimates in proc logistic when predictor is a continuous var

palolix — Thu, 21 Nov 2024 04:05:44 GMT

Ok I will try that with y and pred y, but this applies only to continuous variables right?

Re: estimates in proc logistic when predictor is a continuous var

Ksharp — Thu, 21 Nov 2024 06:19:49 GMT

Nope. Also could apply to LOGISTIC Model:

data have;
 set sashelp.heart;
 y=ifn(status='Dead',0,1);
run;

proc logistic data=have;
model y=height weight/rsquare;
output out=want p=pred;
run;
proc corr data=want;
var y pred;
run;

Here 0.14804*0.14804=0.0219 (same as proc logistic)

Re: estimates in proc logistic when predictor is a continuous var

SteveDenham — Fri, 22 Nov 2024 14:43:46 GMT

With regard to GLIMMIX, I was incomplete in my assertion about including a categorical response in the CLASS statement for multinomial distributions. That only seems to be the case for a generalized logit (LINK=GLOGIT), but not for the default link for DIST=MULT, where the default is a cumulative logit.

SteveDenham

(Apologies to @StatDave )

Re: estimates in proc logistic when predictor is a continuous var

palolix — Fri, 22 Nov 2024 22:03:32 GMT

That's great, thank you very much Ksharp!

I tried this code (omitting the first part) when my outcome var is binary and I got pretty similar values for r-square. However, when I tried it for an ordinal outcome var I got pretty different r-square results (0.07172*0.07172=0.0051 vs 0.1022). Am I doing something wrong or does this only work for binary outcome variables?

This is the code I'm using :

proc logistic data=one desc;
model hedonic=DM/link=clogit rsquare;
output out=want3 p=pred;
run;
proc corr data=want3;
var hedonic pred;
run;

These are the results I get:

Response Profile
Ordered Value	hedonic	Total Frequency
1	9	17
2	8	93
3	7	99
4	6	103
5	5	86
6	4	100
7	3	50
8	2	31
9	1	4

Probabilities modeled are cumulated over the lower Ordered Values.

R-Square	0.1022	Max-rescaled R-Square	0.1042

Testing Global Null Hypothesis: BETA=0
Test	Chi-Square	DF	Pr > ChiSq
Likelihood Ratio	62.8777	1	<.0001
Score	60.9165	1	<.0001
Wald	60.5840	1	<.0001

The CORR Procedure

hedonic

1.00000

4680

0.07172

<.0001

4664

pred
Estimated Probability

0.07172

<.0001

4664

1.00000

4664

Re: estimates in proc logistic when predictor is a continuous var

palolix — Fri, 22 Nov 2024 22:06:00 GMT

Thanks for your clarification Steve!

Re: estimates in proc logistic when predictor is a continuous var

StatDave — Fri, 22 Nov 2024 22:34:16 GMT

No worries, but actually GLIMMIX also runs fine with GLOGIT:

proc glimmix data=dv2; 
model dv=income/dist=mult link=glogit s; 
run;

Re: estimates in proc logistic when predictor is a continuous var

Ksharp — Sat, 23 Nov 2024 06:14:09 GMT

If your Y variable is ordinal with multiple values like : 1,2,3,4
the PROC LOGISTIC would lead you to THREE models:
1 v.s 2,3,4
1,2 v.s 3,4
1,2,3 v.s 4

Therefore, my idea is NOT suited for this scenario I think.