topic Re: Model Fit for Proc Gee in Statistical Procedures

Model Fit for Proc Gee

twix17 — Mon, 27 Feb 2023 05:43:40 GMT

Hello Community,

I am trying to calculate model fit for the two Proc GEE models below. I know I can calculate using QIC number and find for the lower number.

ods output GEEFitCriteria=fitcrit;
proc gee data=data;
	class subjectID var1 var2;
	model isBlockAcuteGap(event="1")= var1 var2/ dist=bin link=logit type3  ;
	repeated subject=subjectID ;
run;

ods output GEEFitCriteria=fitcrit2;
proc gee data=data;
	class subjectID var1 var2 var3;
	model isBlockAcuteGap(event="1")= var1 var2 var3 / dist=bin link=logit type3 wald;
	repeated subject=subjectID ;
run;

Is there a way to statistically look for the difference between these two models instead of just looking at the lower Qic number?

I don't know how to find a loglikelihood ratio for the model above.

Thanks

Re: Model Fit for Proc Gee

StatDave — Mon, 27 Feb 2023 03:41:01 GMT

Goodness of fit is always a matter of how you want to define it. See the "Assessing fit in Generalized Estimating Equations (GEE) models" section of this note which mentions an R-square measure, the QIC measure, and observation- and cluster-level ways of assessing fit. Additionally, in your case, the two models differ only by the addition of one predictor. So, the question might amount to whether that added predictor is important. In that case, the significance of that predictor is a comparison of fit.

Regarding the likelihood ratio test - this is not possible since the GEE method is not likelihood-based.

As a separate note, you should never include variables in the CLASS statement that aren't also used in the MODEL, REPEATED, or other statements involved in fitting the model. Doing so can cause observations to be omitted that don't have to be.

Re: Model Fit for Proc Gee

twix17 — Mon, 27 Feb 2023 05:45:24 GMT

Thanks for your response. I have updated the sas code. Thanks

Re: Model Fit for Proc Gee

Ksharp — Mon, 27 Feb 2023 11:46:03 GMT


/*
You could compare two model's RUC statistic to see
if they are different statistically.
But you could run into over-fit problem if you have many X variables.
*/
data data;
 set sashelp.heart;
 if not missing(Smoking_Status);
run;
proc gee data=data;
 class Smoking_Status;
 model Status(event="Dead")= weight height/ dist=bin link=logit type3  ;
 repeated subject=Smoking_Status ;
 output out=want1(keep=status p1) predicted=p1;
run;
proc gee data=data;
 class Smoking_Status;
 model Status(event="Dead")= weight height Diastolic Systolic MRW/  dist=bin link=logit type3 wald;
 repeated subject=Smoking_Status ;
 output out=want2(keep=status p2) predicted=p2;
run;


data want;
 merge want1 want2;
run;
proc logistic data=want ;
model Status(event="Dead")=p1 p2/nofit;
roc 'p1' pred=p1;
roc 'p2' pred=p2;
roccontrast reference('p2') / estimate e;
run;

Re: Model Fit for Proc Gee

twix17 — Mon, 27 Feb 2023 19:11:47 GMT

Thanks @Ksharp

Re: Model Fit for Proc Gee

Ksharp — Fri, 12 Apr 2024 02:03:27 GMT

https://blogs.sas.com/content/iml/2024/03/27/likelihood-ratio-test.html