topic Re: How to color or label ewmachart by different periods? in Statistical Procedures

How to color or label ewmachart by different periods?

Giovani — Wed, 20 Mar 2024 02:03:33 GMT

Using the procedure listed here, I am looking to add different visual information, either using color or a label for the time variable in the EWMA chart output. Any help is welcome.

data Sample;
input Sample Diameter Time $;
datalines;
1 24.05 Morning
2 23.99 Morning
3 23.95 Morning
4 23.93 Morning
5 23.97 Morning
6 24.02 Morning
7 24.06 Morning
8 24.10 Morning
9 23.98 Morning
10 24.03 Afternoon
11 23.91 Afternoon
12 24.06 Afternoon
13 24.06 Afternoon
14 23.96 Afternoon
15 23.98 Afternoon
16 24.06 Afternoon
17 24.01 Afternoon
18 24.00 Afternoon
19 23.93 Afternoon
20 23.92 Afternoon
21 24.09 Morning
22 24.11 Morning
23 24.05 Morning
24 23.98 Morning
25 23.98 Morning
26 24.06 Morning
27 24.02 Morning
28 24.06 Morning
29 23.97 Morning
30 23.96 Morning
;

proc MACONTROL data=work.Sample ;
ewmachart Diameter * Sample /
weight = 0.4
sigmas = 3.0
outlimits = c;
label Diameter = "Diameter";
label Sample = "Sample";
run;

Re: How to color or label ewmachart by different periods?

sbxkoenk — Wed, 20 Mar 2024 19:54:20 GMT

You need to provide an ANNOTATE dataset.
Can you do that?

ANNOTATE=SAS-data-set
ANNO=SAS-data-set
specifies an input data set that contains appropriate annotate variables, as described in SAS/GRAPH: Reference. The ANNOTATE= option enables you to add features to the moving average chart (for example, labels that explain out-of-control points). The ANNOTATE= data set is used only when the chart is created as traditional graphics; it is ignored if ODS Graphics is enabled or if you specify the LINEPRINTER option.
The data set specified with the ANNOTATE= option in the PROC MACONTROL statement is a "global" annotate data set in the sense that the information in this data set is displayed on every chart produced in the current run of the MACONTROL procedure.
ANNOTATE2=SAS-data-set
ANNO2=SAS-data-set
specifies an input data set that contains appropriate annotate variables that add features to the trend chart (secondary chart) produced with the TRENDVAR= option in the EWMACHART or MACHART statement. This option is ignored if ODS Graphics is enabled or if you specify the LINEPRINTER option.

Use this blog as an example :
How to show recessions (or other ranges) on a time series plot?
By Robert Allison on SAS Learning Post August 22, 2014
https://blogs.sas.com/content/sastraining/2014/08/22/how-to-show-recessions-or-other-ranges-on-a-time-series-plot/

Koen

Re: How to color or label ewmachart by different periods?

sbxkoenk — Wed, 20 Mar 2024 19:55:54 GMT

If you want to see all ANNOTATE posts in the SAS blogs , go here :

https://blogs.sas.com/content/tag/annotate/

Koen

Re: How to color or label ewmachart by different periods?

Giovani — Thu, 21 Mar 2024 13:21:27 GMT

Is there a fully reproducible code for the chart mentioned in the post?

Re: How to color or label ewmachart by different periods?

yabwon — Thu, 21 Mar 2024 14:06:22 GMT

SGPLOT?

data Sample;
input Sample Diameter Time $;
datalines;
1 24.05 Morning
2 23.99 Morning
3 23.95 Morning
4 23.93 Morning
5 23.97 Morning
6 24.02 Morning
7 24.06 Morning
8 24.10 Morning
9 23.98 Morning
10 24.03 Afternoon
11 23.91 Afternoon
12 24.06 Afternoon
13 24.06 Afternoon
14 23.96 Afternoon
15 23.98 Afternoon
16 24.06 Afternoon
17 24.01 Afternoon
18 24.00 Afternoon
19 23.93 Afternoon
20 23.92 Afternoon
21 24.09 Morning
22 24.11 Morning
23 24.05 Morning
24 23.98 Morning
25 23.98 Morning
26 24.06 Morning
27 24.02 Morning
28 24.06 Morning
29 23.97 Morning
30 23.96 Morning
;

proc MACONTROL data=work.Sample ;
ewmachart Diameter * Sample /
weight = 0.4
sigmas = 3.0
outlimits = c
OUTTABLE=OT
;
label Diameter = "Diameter";
label Sample = "Sample";
run;

data forPlot;
  set OT end=_E_;
  l=0;
  if 10<=Sample<=22 then u=25;
  else u=0;
  output;
run;

proc sgplot data=forPlot noautolegend;
band x=sample lower=_LCLE_ upper=_UCLE_ / transparency=0 modelname="myname";
band x=sample lower=l upper=u / fillattrs=(color=gold transparency=.2);
step x=sample y=_LCLE_ / name="myname" lineattrs=(color=grey thickness=2);
step x=sample y=_UCLE_ / lineattrs=(color=grey thickness=2);
series x=sample y=_MEAN_ / lineattrs=(color=black thickness=2);
series x=sample y=_EWMA_ / lineattrs=(color=blue thickness=3);
yaxis min=23.90 max=24.10;
run;

result:

Bart

Re: How to color or label ewmachart by different periods?

Giovani — Thu, 21 Mar 2024 14:12:52 GMT

Thanks, @yabwon