topic Re: What Statistical Analysis in SAS is Appropriate? in Statistical Procedures

What Statistical Analysis in SAS is Appropriate?

Liz123 — Tue, 28 Nov 2023 19:46:16 GMT

Hello everyone. I would like to trend the amount of substance used over a period of time for individuals using a particular service to see whether there is an increase in substance use over time or not. Also I would like to know whether these changes are associated with a cardiac problem or not. The amount of substance (y axis) is in ranges, hence it is not continuous, while the Y axis is time. Each subject has measures at several points and these timepoints are not consistent for all the participants. No comparison group.. The cardiac event is a dichotomous variable (Yes/No).

My questions are:

1) What type of statistical analysis would be appropriate to trend the amount of substance used by individuals over the period of study, considering that the amount of substance use will be in ranges, not a continuous variable.

2) What analysis can I do for the 2nd part to test whether there is an association with cardiac problem?

I have been looking for research papers that may have done analysis of this type but I have not found yet. If anyone has a resource material or research paper link that could help, that would be helpful in addition to the responses that I get from this forum.

Thanks.

What Statistical Analysis in SAS is Appropriate?

Liz123 — Tue, 28 Nov 2023 20:46:00 GMT

My questions are:

2) What analysis can I do for the 2nd part to test whether there is an association with cardiac problem?

I have been looking for research papers that may have done analysis of this type but I have not found yet. Any advice? If anyone has a resource link or research paper link that could help, that would be helpful in addition to the responses that I get from this forum. Thanks.

Re: What Statistical Analysis in SAS is Appropriate?

StatDave — Tue, 28 Nov 2023 22:23:03 GMT

There could be several approaches or models to address your questions and the choice of the most appropriate one for your data and goals has to be yours. That said, one approach is to fit a suitable Generalized Estimating Equations (GEE) model to accommodate the repeated measurements on each subject. I assume that the two cardiac groups consist of two independent sets of subjects. If you assume that your ordinal response is at least roughly normally distributed in each group at each time and that any trend over time is approximately linear, then the model could simply allow for an intercept and a slope for each of the two cardiac groups. The slopes measure the trend in each group.

The basic idea is similar to what is discussed in this note on intervention analysis, but doesn't involve an intervention. The situation described above is like the right-hand (post intervention) side of the data plot in the "Treated and Control Groups, Continuous Response" section of the note. The following generates the same example data but keeps only the observations for the two independent groups over months 4-6.

     data a; 
        sd=3;
        keep id exposed month iv expiv y;
        do exposed=1,0;
        do month=1 to 6;
           iv=(month>3);
           expiv=cats(exposed,'_',iv);
           input mean @;
           do ID=1 to 10;
              Y=rannor(23425)*sd+mean;
              if iv then output;
           end; 
        end; end;
        datalines;
      26 30 32   45 52 63
      27 31 33   29 32 36
      ;

The PROC GEE step fits and plots a model that allows for separate intercepts (EXPOSED) and slopes or trends (EXPOSED*MONTH) for the two exposure groups (like your cardiac groups). Because the model contains a single, common slope estimate (MONTH), the test for the MONTH*EXPOSED interaction is a test of whether the slopes for the two exposed groups are the same. The highly significant test for the interaction indicates that the group trends differ. Whether the subjects are all observed at that same set of time points doesn't affect this particular analysis.

     proc gee data=a; 
        class id exposed;
        model y = exposed month exposed*month;
        repeated subject=id;
        effectplot slicefit(x=month sliceby=exposed) / extend=data clm;
        run;

You could then fit a form of the model that directly shows the estimated intercepts (EXPOSED) and slopes (EXPOSED*MONTH) for the two groups.

     proc gee data=a; 
        class id exposed;
        model y = exposed exposed*month / noint;
        repeated subject=id;
        effectplot slicefit(x=month sliceby=exposed) / extend=data clm;
        run;

Re: What Statistical Analysis in SAS is Appropriate?

sbxkoenk — Tue, 28 Nov 2023 22:56:31 GMT

I think this is a duplicate of "another" topic:

https://communities.sas.com/t5/Statistical-Procedures/What-Statistical-Analysis-in-SAS-is-Appropriate/td-p/904958

Please don't post your question multiple times in several boards simultaneously.

If another board is better suited to receive your question, the topic will be moved by a user with "super-powers".

Thanks,

Koen

Re: What Statistical Analysis in SAS is Appropriate?

Kurt_Bremser — Tue, 28 Nov 2023 23:15:50 GMT

I merged the posts.

Re: What Statistical Analysis in SAS is Appropriate?

Liz123 — Tue, 28 Nov 2023 23:39:50 GMT

Hello. Thanks so much for your response. Highly appreciated. I would like to see the trend of amount of substance use over time for individuals and not groups. No comparison of trends between the groups either. The unit of the substance amount is in ranges i.e. categorical. Is it possible to conduct analysis without comparing groups in this case? Can you please clarify whether the type of analysis that you suggested would work for that? Thanks.

Re: What Statistical Analysis in SAS is Appropriate?

Liz123 — Tue, 28 Nov 2023 23:51:50 GMT

Hello. So sorry about that. I am new on this platform. I was not sure whether my question was posted, so I posted again. Thanks for letting me know.

Re: What Statistical Analysis in SAS is Appropriate?

Ksharp — Wed, 29 Nov 2023 02:30:00 GMT

For your first question, if "amount of substance use will be in ranges, " a.k.a it is a category variable,
You could try PROC FREQ 's trend analysis:
https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.3/statug/statug_freq_examples08.htm

For your second question, maybe you could try PROC CATMOD.
https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.3/statug/statug_catmod_syntax.htm
But I don't know how to code it.