topic Re: MI ANALYZE by group(regions) in Statistical Procedures

MI ANALYZE by group(regions)

Gilles-Protais — Sun, 25 Jun 2023 10:55:33 GMT

Greetings community,

am trying to do multiple imputation and I which to have pooled estimates through the function MIANALYZE by region, but I don't how to include that in my code

proc mi nimpute=2 data=Work.query seed=45 out=want_imp1;
class age7 sgp region province ghq12 sex;
fcs regression (lnbmi) logistic (sgp) discrim (province) ;
var id hh wfin  age7 lnbmi    ghq12  province region sgp sex;
run ;
 

proc mixed data= want_imp1;
title 'PROC MIXED weighted + clustered GP after MI';
by _imputation_ regionch;
weight wfin;
class hh age7 sex sgp ;
model lnbmi = GHQ12 sgp sex*age7 / solution covb;
random intercept / subject=hh;
ods output SolutionF = mixed_GP_parms covb = mixed_GP_cov;
run;


proc mianalyze parms=mixed_gp_parms ;
title 'MIANALYZE of MIXED with GP as covariate';
class sgp sex age7 ;
modeleffects intercept sgp  age7*sex;
by region
run;

Thanks very much.

Re: MI ANALYZE by group(regions)

SAS_Rob — Mon, 26 Jun 2023 13:48:12 GMT

That code should work, assuming you have a typo in the MIXED code on the BY statement with the variable regionch instead of region. Can you post the LOG so we can see exactly what is going wrong?

Re: MI ANALYZE by group(regions)

Gilles-Protais — Tue, 27 Jun 2023 20:28:20 GMT

Re: MI ANALYZE by group(regions)

SAS_Rob — Wed, 28 Jun 2023 13:07:00 GMT

It looks like the data is not properly sorted. Try sorting it first and see if that takes care of the issue.

proc sort data=mixed_gp_parms;
by region _imputation_;
run;

proc mianalyze parms=mixed_gp_parms ; 
title 'MIANALYZE of MIXED with GP as covariate'; 
class sgp sex age7 ; 
modeleffects intercept sgp age7*sex;
by region;
run;

Re: MI ANALYZE by group(regions)

Gilles-Protais — Wed, 28 Jun 2023 17:05:13 GMT

Thanks very much. It worked for me.