topic How retain a value from pre ious observation in Statistical Procedures

How retain a value from pre ious observation

r3570 — Thu, 16 Mar 2023 16:13:33 GMT

Hi all,
Please help me with below query
If I have a variable with a test value and corresponding result. I need to copy the same value to other blank observations as below:
Having:
Test Result
A 12.6
A
A
A
A
B 14.9
B
B
B
B
B

Need as below:
Test Result
A 12.6
A 12.6
A 12.6
A 12.6
A 12.6
B 14.9
B 14.9
B 14.9
B 14.9
B 14.9
B 14.9

Re: How retain a value from pre ious observation

Kurt_Bremser — Thu, 16 Mar 2023 16:18:11 GMT

Use a RETAINed variable which you discard later.

data want;
set have;
by test;
retain _result;
if first.test then _result = .;
if result ne .
then _result = result;
else result = _result;
drop _result;
run;

Re: How retain a value from pre ious observation

ballardw — Thu, 16 Mar 2023 16:21:55 GMT

Amazingly enough the function is RETAIN, but you want to use it with a new variable.

data have;
  input Test $ Result;
datalines;
A 12.6
A .
A .
A .
A .
B 14.9
B .
B .
B .
B .
B .
;


data want;
   set have;
   by test notsorted;
   retain tempresult;
   if first.test then tempresult=.;
   if not missing(result) then tempresult=result;
   if missing (result) then result=tempresult;
   drop tempresult;
run;

The data step creates a set similar to your description.

The BY statement in the Want data step assumes that your data is grouped by Test value if not actually sorted.

Retain creates a variable that will hold values. If the value is to be character you should define the length before the Retain statement.

The BY statement creates automatic variable that you can test to see if an observation is the first or last of a group. In this case it is used to reset the retained variable when the Test value changes to a new group.

Re: How retain a value from pre ious observation

Ksharp — Fri, 17 Mar 2023 11:45:06 GMT

data have;
  input Test $ Result;
datalines;
A 12.6
A .
A .
A .
A .
B 14.9
B .
B .
B .
B .
B .
;

data want;
update have(obs=0) have;
by Test;
output;
run;