topic Re: Obtaining the odds ratio and 95% confidence interval from mixed effect logistic regression in sa in Statistical Procedures

Obtaining the odds ratio and 95% confidence interval from mixed effect logistic regression in sas

mrahouma — Thu, 22 Sep 2022 23:29:40 GMT

How can I get the odds ratio and 95% confidence interval from mixed effect logistic regression in sas?

I am aware that odds ration could be derived by exponentiating the obtained estimate.

A sample dataset and code (derived from a prior post)

data herd;
call streaminit(1);
do herd = 1 to 10;
   do testyear = 2005, 2015;
      do Time = 1 to 6;
         eta = -1 + 0.1*herd + 0.5*Time - 2*(testyear=2015);
         mu = logistic(eta);
         mpd = rand("Bernoulli", mu);
         output;
      end;
   end;
end;

proc GLIMMIX data = herd;
   class testyear TIME;
   model MPD = TESTYEAR TIME / s dist=binary;
   RANDOM HERD;
RUN;

Appreciate any advice.

Re: Obtaining the odds ratio and 95% confidence interval from mixed effect logistic regression in sa

Ksharp — Fri, 23 Sep 2022 11:52:52 GMT

/*
You could get CI of estimated parameter,
and EXP() this CI to get CI of ODDS Rario. 
*/

data herd;
call streaminit(1);
do herd = 1 to 10;
   do testyear = 2005, 2015;
      do Time = 1 to 6;
         eta = -1 + 0.1*herd + 0.5*Time - 2*(testyear=2015);
         mu = logistic(eta);
         mpd = rand("Bernoulli", mu);
         output;
      end;
   end;
end;
run;

ods output ParameterEstimates=ParameterEstimates SolutionR=SolutionR;
proc GLIMMIX data = herd;
   class HERD testyear TIME;
   model MPD = TESTYEAR TIME / s dist=binary cl ODDSRATIO;
   RANDOM intercept /cl subject=HERD;
RUN;


data fixed;
 set ParameterEstimates;
 odds_ratio=exp(Estimate);
 lower_odds_ratio=exp(Lower);
 upper_odds_ratio=exp(Upper);
run;
proc print label;run;


data mixed;
 set SolutionR;
 odds_ratio=exp(Estimate);
 lower_odds_ratio=exp(Lower);
 upper_odds_ratio=exp(Upper);
run;
proc print label;run;

Re: Obtaining the odds ratio and 95% confidence interval from mixed effect logistic regression in sa

mrahouma — Fri, 23 Sep 2022 15:55:05 GMT

Thanks a lot. Upvoted and accepted as answer. Would it be possible to explain difference between RANDOM intercept /cl subject=HERD; vs RANDOM HERD; only that I wrote? Appreciate your help and time

Re: Obtaining the odds ratio and 95% confidence interval from mixed effect logistic regression in sa

Ksharp — Sat, 24 Sep 2022 09:24:34 GMT

If you need MIXED effect ,you need a variable named SUBJECT . I look at your dataset and think HERD is the SUBJECT. So I wrote:
RANDOM intercept /cl subject=HERD;
and @SteveDenham @lvm @StatDave could give you the exact right syntax as long as you pointed out what you are looking for .

Re: Obtaining the odds ratio and 95% confidence interval from mixed effect logistic regression in sa

SteveDenham — Mon, 26 Sep 2022 13:26:33 GMT

The two syntax's should give you the same results. However, for complex designs, the use of the intercept/subject= syntax improves convergence. See this paper:

https://support.sas.com/resources/papers/proceedings15/SAS1919-2015.pdf

SteveDenham

Re: Obtaining the odds ratio and 95% confidence interval from mixed effect logistic regression in sa

mrahouma — Mon, 26 Sep 2022 16:06:16 GMT

Thx a lot. Greatly appreciated.