topic Re: Estimate & Contrast Commands in Statistical Procedures

Estimate & Contrast Commands

Heejeong — Sun, 08 May 2022 07:23:18 GMT

Hello,

I am running a simple proc glm with one continuous predictor. I wanted to calculate the estimates of Norepinephrine at 1 SD below the mean, mean, and 1 SD above the mean of the continuous predictor (centered value of stress reactivity).

proc glm data=JH.Final3 ;
model Norepinephrine= cPAreactpost;
estimate 'Centered Stress reactivity (1-SD)' intercept 1  cPAreactpost-0.0627096 ;
estimate 'Centered Stress reactivity (Mean)' intercept 1 cPAreactpost 0;
estimate 'Centered  Stress reactivity (1+SD)' intercept 1  cPAreactpost0.0627096;
run;

I have 2 quick questions:

1) Could you please confirm that the estimate syntax is correctly written for me to compare the predicted values of Norepinephrine at 1-SD, mean, and 1+SD of the predictor variables? I see the following output when I run this syntax.

2) If I wanted to see if these three parameters were significantly different from each other, I would I write the syntax? I have been using both estimate and contrast syntax for categorical variables but wasn't sure how I would write a "contrast" syntax when I have a continuous predictor.

Thank you so much in advance for all your help!

All the Best,

Joanna

Re: Estimate & Contrast Commands

PaigeMiller — Sun, 08 May 2022 11:08:44 GMT

Let me throw the question back to you. If the mean is 17.626 and 1 SD is 0.0627096, then what should the value of Mean – 1SD be? Does that equal the number in the output?

To get confidence intervals for the mean, you would use the MEANS statement in PROC GLM. Of course, confidence intervals do not use 1SD. If you really want 1SD, you should modify the ALPHA= option in the MEANS statement.

Re: Estimate & Contrast Commands

sbxkoenk — Sun, 08 May 2022 13:41:43 GMT

Hello @Heejeong ,

As stated by @PaigeMiller , you do not need ESTIMATE nor CONTRAST statements for this.

This is most easily done using the MEANS, LSMEANS ( , SLICE, and | or LSMESTIMATE statement ).

But for the sake of writing good ESTIMATE and CONTRAST statements, I put some references to blogs here that can serve as an inspiration for you and others :

Usage Note 67024: Using the ESTIMATE or CONTRAST statement or Margins macro to assess continuous variable effects in interactions and splines

67024 - Using the ESTIMATE or CONTRAST statement or Margins macro to assess continuous variable effects in interactions and splines (sas.com)

The magical ESTIMATE (and CONTRAST) statements

By Chris Daman on SAS Learning Post April 23, 2012

https://blogs.sas.com/content/sastraining/2012/04/23/the-magical-estimate-and-contrast-statements/

"Easy button" for ESTIMATE statements

By Chris Daman on SAS Learning Post April 25, 2012

https://blogs.sas.com/content/sastraining/2012/04/25/easy-button-for-estimate-statements/

ESTIMATE Statements - the final installment

By Chris Daman on SAS Learning Post May 2, 2012

https://blogs.sas.com/content/sastraining/2012/05/02/estimate-statements-the-final-installment/

How to write CONTRAST and ESTIMATE statements in SAS regression procedures?

By Rick Wicklin on The DO Loop June 6, 2016

https://blogs.sas.com/content/iml/2016/06/06/write-contrast-estimate-statements-sas-regression-procedures.html

Usage Note 24447: Examples of writing CONTRAST and ESTIMATE statements

https://support.sas.com/kb/24/447.html

BR,

Koen

Re: Estimate & Contrast Commands

Heejeong — Sun, 08 May 2022 14:15:46 GMT

Thank you so much for your fast response to my question @PaigeMiller!

And I apologize, but couldn't quite understand what you were trying to convey with your question back to me. The answer to your question (my train of thought is that I would calculate "17.626-0.0627096") is that the output does not equal this calculation?

And thank you so much for directing me to the Means Statement! My only concern is that my predictor is a "continuous variable" so when I tried to run the means statement, I received an error message ("ERROR: Only CLASS variables allowed in this effect") that a continuous variable is not allowed.

And thank you, @sbxkoenk for all your helpful links to writing ESTIMATE and CONTRAST statements, I am looking forward to reviewing them! I have the same problem as the above when trying to use "MEANS, LSMEANS (SLICE, and | or LSMESTIMATE statement)." Since my predictor is a continuous variable and I am unable to run use these helpful statements.

In another analysis, I did use the Proc Rank syntax to create quartiles of my predictor and ran a proc glm with a categorical predictor variable (the same variable as above), which I think is a more straightforward analysis. However, my result is not significant when my predictor is transformed into a categorical variable so I had to stick with my method of running the main analysis with a continuous predictor first then following up with additional analyses at different levels of the predictor variable.

Thank you both SO much for your help and support, I really appreciate it!

Re: Estimate & Contrast Commands

PaigeMiller — Sun, 08 May 2022 14:31:38 GMT

Sorry, I didn't notice your predictor is a continuous variable.

You can use these methods to get predicted value at any X value (including the mean of X, including mean(x) + 1SD and mean(X) – 1SD).

https://blogs.sas.com/content/iml/2014/02/17/the-missing-value-trick-for-scoring-a-regression-model.html

Re: Estimate & Contrast Commands

sbxkoenk — Sun, 08 May 2022 15:49:42 GMT

Sorry, @Heejeong , I hadn't read your original post thoroughly enough either.

In fact, you are doing a simple linear regression.

You can also do that with PROC REG.

And here are two examples on how to score new observations with PROC REG ( on top of the missing value trick, already suggested by @PaigeMiller ). PROC SCORE and PROC PLM :

The SCORE Procedure
https://go.documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/statug/statug_score_examples02.htm
4 reasons to use PROC PLM for linear regression models in SAS
By Rick Wicklin on The DO Loop February 11, 2019
https://blogs.sas.com/content/iml/2019/02/11/proc-plm-regression-models-sas.html
The PLM Procedure : Scoring with PROC PLM
https://go.documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/statug/statug_plm_examples01.htm

Also, instead of using PROC RANK to categorize / discretize your continuous predictor into equal-sized groups, there are methods that optimize the location of the boundaries between the groups such that the predictive-ness of the resulting discretized predictor is maximal.
Weights of Evidence (WOE) is such a method. You can also do it with a decision tree (allowing for one split and multiple branches).

Koen

Re: Estimate & Contrast Commands

StatDave — Sun, 08 May 2022 16:13:31 GMT

Do not categorize your predictor if that is not needed. Doing so only throws away information which is can be used in the model. Note that your model assumes that the effect of the predictor on the response mean is linear.

Similarly to what is shown in the first part of this note, this can be easily done in the Margins macro whether the predictor is centered or not.

    proc means data=JH.Final3;
      var cPAreactpost; 
      output out=out mean=mean std=sd;
      run;
    data mdat;
      set out;
      keep cPAreactpost;
      do cPAreactpost = mean-sd, mean, mean+sd;
        output;
      end;
      run;
    %Margins(data=JH.Final3, response=Norepinephrine, model=cPAreactpost,
             margins=cPAreactpost, margindata=mdat,
             options=diff reverse cl)

Alternatively, if the ESTIMATE statement is to be used, then as discussed in this note, you can write your hypotheses in terms of the model to determine the coefficients for the ESTIMATE or CONTRAST statement. Following that process, and assuming that the predictor mean and standard deviation are really zero and 0.0627, then that produces the coefficients as below. As detailed in the note, the coefficients for the difference are determined by subtracting the coefficient vectors for the two means to be compared.

proc glm data=JH.Final3;
model Norepinephrine=cPAreactpost;
estimate "mean" intercept 1 cPAreactpost 0;
estimate "mean-sd" intercept 1 cPAreactpost -0.0627;
estimate "mean+sd" intercept 1 cPAreactpost 0.0627;
estimate "1 sd change" cPAreactpost 0.0627;
estimate "2 sd change" cPAreactpost 0.1254;
run; quit;

Re: Estimate & Contrast Commands

Heejeong — Sun, 08 May 2022 18:31:18 GMT

Hello @StatDave, wow, thank you so much for your helpful response and for taking the time to write out the syntax for me!

Sometimes, I will understand the concept of things but can't get the syntax to run or don't feel 100% confident that I got it right, so I am really grateful for your time and help! I'm sorry for another set of questions but I promise that these will be the last ones. I am learning so much and so thankful for this opportunity, so thank you so much again! And if you need any clarification, please let me know!

I had a few follow-up questions:

1) When I run the Proc Means syntax that you wrote for me, below is the ouput I see. Although the mean reads as "1.3591194E-8," I wanted to confirm with you that it's safe to use "0" as the mean value for my Estimate statements.

2) I actually had a long list of covariates that I didn't show before to simplify my model. But now that I've found an answer to my original question, I just wanted to confirm with you that I can add my long list of covariates in both the MACRO and ESTIMATE models? Below is my syntax where I've added in my covariates to both the MACRO & ESTIMATE statements:

 proc means data=JH.Final3;
      var cPAreactpost; 
      output out=out mean=mean std=sd;
      run;
    data mdat;
      set out;
      keep cPAreactpost;
      do cPAreactpost = mean-sd, mean, mean+sd;
        output;
      end;
      run;
    %Margins(data=JH.Final3, response=Norepinephrine, model=cage ClinicSex marriedmidus work race_orig  cedu cHHtotalIncome EverSmokeReg Exercise20mins CNSmeds cBMI cCESD cNeuroticism  cChronCondNumb  cAnyStressWide_sum cpa_mlm2 cPAreactpost,
             margins=cPAreactpost, margindata=mdat,
             options=diff reverse cl)

proc glm data=JH.Final3;
model Norepinephrine=cage ClinicSex marriedmidus work race_orig cedu cHHtotalIncome EverSmokeReg Exercise20mins CNSmeds cBMI cCESD cNeuroticism cChronCondNumb cAnyStressWide_sum cpa_mlm2 cPAreactpost;
estimate "mean" intercept 1 cPAreactpost 0;
estimate "mean-sd" intercept 1 cPAreactpost -0.0627;
estimate "mean+sd" intercept 1 cPAreactpost 0.0627;
estimate "1 sd change" cPAreactpost 0.0627;
estimate "2 sd change" cPAreactpost 0.1254;
run; quit;

3) In the Margins syntax, there isn't a PROC GLM or a PROC REG, and I was wondering if I was supposed to run a PROC GLM first then run the Macro? Or does the below part of the MARGIN syntax replace the PROC GLM syntax?

response=Norepinephrine, model=cage ClinicSex marriedmidus work race_orig  cedu cHHtotalIncome EverSmokeReg Exercise20mins CNSmeds cBMI cCESD cNeuroticism  cChronCondNumb  cAnyStressWide_sum cpa_mlm2 cPAreactpost,

4) Below are my outputs for the MACRO and ESTIMATE commands. My initial understanding is that the Predictive Margins (from the MACRO) and Estimate Parameters (from the ESTIMATE) should generate the same values. But I got a bit confused because they are different. Could you please let me know why that might be and which numbers I should be using when I want to discuss how different levels of stress reactivity are differentially related to levels of Norepinephrine? I am currently using the below syntax for graphing my results, so I'm assuming that I should be using the results from the ESTIMATE command?

proc glm data=JH.Final3;
model Norepinephrine=cage ClinicSex marriedmidus work race_orig  cedu cHHtotalIncome EverSmokeReg Exercise20mins CNSmeds cBMI cCESD cNeuroticism  cChronCondNumb  cAnyStressWide_sum cpa_mlm2 cPAreactpost;
estimate "mean" intercept 1 cPAreactpost 0;
estimate "mean-sd" intercept 1 cPAreactpost -0.0627;
estimate "mean+sd" intercept 1 cPAreactpost 0.0627;
estimate "1 sd change" cPAreactpost 0.0627;
estimate "2 sd change" cPAreactpost 0.1254;
store graph5;run;
run; quit;
proc plm restore=graph5 noinfo;
			effectplot fit (x=cPAreactpost);
			run;

MACRO

ESTIMATE

5) Lastly, I just wanted to confirm that "1 sd change" estimate is testing the difference between "1-SD estimate value" and "mean." Also that "2 sd change" estimate command is comparing "1-SD estimate value" and "1+SD estimate value." So if I wanted to compare the estimates of "mean" and "1+SD estimate value," what syntax should I be using?

Re: Estimate & Contrast Commands

Heejeong — Sun, 08 May 2022 18:33:31 GMT

Hi @sbxkoenk,

Thank you for continuing to share so many helpful links with me! Also, I'm finding the Weights of Evidence (WOE) method to be extremely helpful too, so THANK YOU!

Re: Estimate & Contrast Commands

StatDave — Sun, 08 May 2022 19:11:34 GMT

Yes, that 1E-8 value is effectively zero. And yes, you can add covariates as you did in MODEL= in the Margins macro call as you did. As noted in the documentation of the macro, it fits the model (using PROC GENMOD) as well as estimates the margins, so you don't need to fit the model beforehand. The values from the macro and from the ESTIMATE statements differ because the ESTIMATE statements use zero values for all of your covariates (add the E option to display the values) while the macro uses the actual observed values in each observation in its computations. That is, the macro by default does not set each covariate at a fixed value. This is one advantage of using margins. The values from the first three ESTIMATE statements are estimated means at the mean, mean-sd, and mean+sd of the predictor when all of the covariates are fixed at zero. The values from the macro don't assume the covariates are fixed. And yes, the "1 (and 2) sd change" estimates are the changes from the mean... again with the covariates fixed at zero. The 1 sd change applies equally to a comparison of the mean to +1sd or the mean to -1sd since the predictor is assumed to have a linear effect.

Re: Estimate & Contrast Commands

Heejeong — Sun, 08 May 2022 20:38:17 GMT

Thank you so much for yet another extremely helpful response, @StatDave

I promise this is the last question. It's great to know that the MARGINS MACRO statement generates more accurate values with actual values of covariates (and not 0 values of covariates). I'm going to use the values from the MARGINS MACRO in the final manuscript but struggling to find a way to graph the predicted margins values.

I thoroughly read through the two documents that you shared with me and I only see a way to graph the estimates using the PROC PLM method. Would there be a way for me to graph the PREDICTED MARGINS from the MACRO MARGINS STATEMENT?

Thank you so much for your help!!

Re: Estimate & Contrast Commands

Heejeong — Sun, 08 May 2022 21:02:12 GMT

In case it might be helpful, below is the syntax I have been using to plot the model at SD-1, Mean, SD+1 of the continuous variable. Would this already be plotting the Predicted Margins?

proc glm data=JH.Final3 ;
model Norepinephrine= cage ClinicSex marriedmidus work race_orig  cedu cHHtotalIncome EverSmokeReg Exercise20mins CNSmeds cBMI cCESD cNeuroticism  cChronCondNumb  cAnyStressWide_sum cpa_mlm2 cPAreactpost;
run;
store graph4;run;
proc plm restore=graph4 noinfo;
effectplot fit (x=cPAreactpost)  /clm;
ods output fitplot=Logfit;
run;

proc sgplot data=Logfit noautolegend;
band upper=_uclm lower=_lclm x=_xcont1 / transparency=.3;
series y=_predicted x=_xcont1;
xaxis values=(-0.0627 0 0.0627) grid offsetmin=.05 offsetmax=.05
label="Positive Affective Responsivity";
yaxis values=(10 to 40  by 5) grid offsetmin=.05 offsetmax=.05 
label="Norepinephrine";
title "Effects of Positive Affective Responsivity on Norepinephrine";
run;

Thank you so much, @StatDave !!

Re: Estimate & Contrast Commands

StatDave — Sun, 08 May 2022 21:15:46 GMT

Yes. The Margins macro automatically creates the _MARGINS data set that contains the margin estimates and their confidence limits.in variables ESTIMATE, LOWER, and UPPER. So, you can use similar PROC SGPLOT code to produce the desired plot.

Note that the Margins macro does not produce "more accurate" estimates than the ESTIMATE statement - it just computes predictive margins rather than a particular linear combination of model parameters which is basically what the ESTIMATE statement does. So, they compute different things.

Re: Estimate & Contrast Commands

Heejeong — Sun, 08 May 2022 21:31:19 GMT

Thank you so much!

Would the below syntax be the correct way to write the code? When I run this code, I get a figure (which I've copy-pasted below), but I have a weird shape of the confidence interval between the MEAN and 1+SD of the predictor variable. Could this be something wrong with my laptop pixels or would it actually be something that's going on in the data that I would have to address?

 proc means data=JH.Final3;
      var cPAreactpost; 
      output out=out mean=mean std=sd;
      run;
    data mdat;
      set out;
      keep cPAreactpost;
      do cPAreactpost = mean-sd, mean, mean+sd;
        output;
      end;
      run;
    %Margins(data=JH.Final3, response=B4BNOCRE, model=cage ClinicSex marriedmidus work race_orig  cedu cHHtotalIncome EverSmokeReg Exercise20mins CNSmeds cBMI cCESD cNeuroticism  cChronCondNumb  cAnyStressWide_sum cpa_mlm2 cPAreactpost,
             margins=cPAreactpost, margindata=mdat,
             options=diff reverse cl)

proc sgplot data=_margins noautolegend;
band upper=UPPER lower=LOWER x=cPAreactpost ;
series y=ESTIMATE x=cPAreactpost;
xaxis values=(-0.0627 0 0.0627) grid offsetmin=.05 offsetmax=.05
label="Positive Affective Responsivity";
yaxis values=(10 to 40  by 5) grid offsetmin=.05 offsetmax=.05 
label="Norepinephrine";
title "Effects of Positive Affective Responsivity on Norepinephrine";
run;

Re: Estimate & Contrast Commands

StatDave — Sun, 08 May 2022 21:45:32 GMT

Remove the VALUES= option in the XAXIS statement. The actual values are computed values that will not be exactly equal to the rough values that you entered in that option.

Re: Estimate & Contrast Commands

StatDave — Sun, 08 May 2022 21:56:04 GMT

Actually, it is more likely that would result from the data not being in proper sorted order. Be sure that the values in the DATA= data set are sorted in increasing order of the X axis variable (cPAreactpost).

Re: Estimate & Contrast Commands

Heejeong — Sun, 08 May 2022 22:55:47 GMT

Thank you so much!

So I tried the code below to proc sort the data by the predictor but got the following error message:

I also tried deleting the values statement but it didn't change the figure shape. Thank you so much for troubleshooting this with me!

 proc means data=JH.Final3;
      var cPAreactpost; 
      output out=out mean=mean std=sd;
      run;
    data mdat;
      set out;
      keep cPAreactpost;
      do cPAreactpost = mean-sd, mean, mean+sd;
        output;
      end;
      run;
    %Margins(data=JH.Final3, response=B4BNOCRE, model=cage ClinicSex marriedmidus work race_orig  cedu cHHtotalIncome EverSmokeReg Exercise20mins CNSmeds cBMI cCESD cNeuroticism  cChronCondNumb  cAnyStressWide_sum cpa_mlm2 cPAreactpost,
             margins=cPAreactpost, margindata=mdat,
             options=diff reverse cl)

proc sort data=_margins; 
by cPAreactpost;
run;

proc sgplot data=_margins noautolegend;
band upper=UPPER lower=LOWER x=cPAreactpost ;*/ transparency=.3;
series y=ESTIMATE x=cPAreactpost;
xaxis values=(-0.0627 0 0.0627) grid offsetmin=.05 offsetmax=.05
label="Positive Affective Responsivity";
yaxis values=(10 to 40  by 5) grid offsetmin=.05 offsetmax=.05 
label="Norepinephrine";
title "Effects of Positive Affective Responsivity on Norepinephrine";
run;

Re: Estimate & Contrast Commands

StatDave — Mon, 09 May 2022 01:49:41 GMT

Perhaps you have the _MARGINS data set open in a ViewTable window. If not, try adding an OUT= option in your PROC SORT step (proc sort data=_margins out=mymargins; ...) and then using the MYMARGINS data in PROC SGPLOT. If none of that works, close and restart SAS and rerun all of it (with the OUT= in PROC SORT).

Re: Estimate & Contrast Commands

Heejeong — Mon, 09 May 2022 02:40:00 GMT

I closed everything and reran the syntax with the "with the OUT= in PROC SORT" and it worked! I can't be more thankful for all your help today! I learned so much and feel so much more confident with my analyses. Thank you so much, @StatDave , for your helpful and fast responses even at night time! I really appreciate it.