topic Re: Compare two medians in Statistical Procedures

Compare two medians

PaigeMiller — Tue, 27 Nov 2012 16:21:11 GMT

Is there a test in SAS that compares two medians? I am looking for the equivalent of PROC TTEST, but with medians instead of means.

Thanks.

Re: Compare two medians

PGStats — Tue, 27 Nov 2012 17:15:24 GMT

Look at the MEDIAN test available in NPAR1WAY.

Re: Compare two medians

art297 — Tue, 27 Nov 2012 17:18:11 GMT

You can also use proc freq. Take a look at http://support.sas.com/documentation/cdl/en/statug/63033/HTML/default/viewer.htm#statug_intronpar_sect006.htm

Re: Compare two medians

PaigeMiller — Tue, 27 Nov 2012 18:45:09 GMT

It was always my understanding that the median test in PROC NPAR1WAY was a non-parametric test of means, not of medians.

Re: Compare two medians

PaigeMiller — Tue, 27 Nov 2012 18:46:57 GMT

Arthur Tabachneck wrote:

You can also use proc freq. Take a look at http://support.sas.com/documentation/cdl/en/statug/63033/HTML/default/viewer.htm#statug_intronpar_sect006.htm

I don't see the word "median" anywhere in the PROC FREQ documentation.

Re: Compare two medians

art297 — Tue, 27 Nov 2012 19:02:00 GMT

: I'll have to leave it to , or another statistician to provide the correct answer but, the following is in the documentation:

SAS/STAT software provides the following nonparametric tests for comparing the locations of two related

samples:

Wilcoxon signed rank test

sign test

McNemar’s test

The first two tests are available in the UNIVARIATE procedure, and the last test is available in the FREQ

procedure. When you perform these tests, your data should consist of pairs of measurements for a random

sample from a single population. For example, suppose your data consist of SAT scores for students before

Tests for k Samples F 281

and after attending a course on how to prepare for the SAT. The pairs of measurements are the scores before

and after the course, and the students should be a random sample of students who attended the course. Your

goal in analysis is to decide whether the median change in scores is significantly different from zero.

Re: Compare two medians

PGStats — Tue, 27 Nov 2012 19:04:55 GMT

The mean is never mentioned in the definition of the test. My experience is that this test isn't very powerful which might explain why it is so rarely used. - PG

Re: Compare two medians

PaigeMiller — Tue, 27 Nov 2012 19:23:10 GMT

Arthur Tabachneck wrote:

"When you perform these tests, your data should consist of pairs of measurements for a random

sample from a single population."

Okay, that does not describe my situation.

Re: Compare two medians

SteveDenham — Tue, 27 Nov 2012 20:13:10 GMT

Then PG's answer at #1 is what you need--the median test in PROC NPAR1WAY.

Steve Denham

Re: Compare two medians

Rick_SAS — Tue, 27 Nov 2012 20:23:29 GMT

I'm not an expert, but I believe that the Mann-Whitney (aka, Wilcoxon-Mann-Whitney or just Wilcoxon) test is generally used as an alternative to a t test when the data are not normally distributed. The Mann-Whitney test is commonly regarded as a test of population medians, but this is technically only true if the two populations have the same shape and one is a "translation" (or shift) of the other. If the populations have different scales and shape, the M-W test will detect that as well, which tends to muddy the results.

You might want to create box plots of the two groups. If the boxes are approximately the same size and shape, but one is offset from the other, then an M-W test would be a way to test whether the medians are different.

For an introduction to nonparametric tests, including how to perform a M-W test by using PROC NPAR1WAY, see http://analytics.ncsu.edu/sesug/2004/TU04-Pappas.pdf

Re: Compare two medians

AllenMcDowell — Thu, 29 Nov 2012 16:42:34 GMT

You can use PROC QUANTREG. Suppose you have two variables, y1 and y2, that potentially have different medians. Create a new variable y that is just y1 stacked on top of y2, and create a dummy variable x that has a value of 0 if an observation is from y1 and a value of 1 if an observation is from y2. Now you can use QUANTREG to estimate the median conditional on the value of x. The TEST statement performs a WALD test of whether the effect of x is significantly different from 0.

Here is a sample program that demonstrates:

data one;

call streaminit(736283);

do i = 1 to 100;

if i<51 then y=rand('NORMAL',0,1);

if i<51 then x=0;

if i>=51 then y=rand('NORMAL',1,1);

if i>=51 then x=1;

output;

end;

run;

proc quantreg data=one;

class x;

model y=x;

test x;

run;

The resulting Wald test statistic is 13.2403, the p-value is 0.0003.

Re: Compare two medians

PaigeMiller — Thu, 29 Nov 2012 16:59:35 GMT

Thanks, Allen. That looks like a reasonable approach. Do you have any references on the Wald test? I don't really find much in SAS docs for PROC QUANTREG about the Wald test.

Re: Compare two medians

AllenMcDowell — Thu, 29 Nov 2012 18:34:19 GMT

The mathematical details of the Wald test are provided at:

http://support.sas.com/documentation/cdl/en/statug/65328/HTML/default/viewer.htm#statug_qreg_syntax11.htm

You can also perform a likelihood ratio test by specifying the LR option in the TEST statement; the mathematical details are provided on this same page.

Re: Compare two medians

Rick_SAS — Thu, 29 Nov 2012 19:50:59 GMT

It's an intriguing idea, but if it were me I'd use the simpler NPAR1WAY procedure. To me, the simpler procedure has the advantage of more explicit assumtions and (often) more power than the general test. (And it's easier for me to understand what is being tested.) By way of an analogy, if I'm testing for the difference of means, I wouldn't use PROC GLM and the ESTIMATE statement when I could use PROC TTEST.

For example, rerun @AllenMcDowell's DATA step where the second mean is 0.5:

if i>=51 then y=rand('NORMAL',0.5,1);

Now compare the QUANTREG and NPAR1WAY results. In this case the Wilcoxon two-sample test has a p-value of 0.0174,the MEDIAN test has a p-value of 0.047, and the QUANTREG Wald test has a p-value of 0.09:

proc npar1way data=one median wilcoxon;

class x;

var y;

run;

Re: Compare two medians

PaigeMiller — Thu, 29 Nov 2012 20:01:09 GMT

AllenMcDowell wrote:

The mathematical details of the Wald test are provided at:

http://support.sas.com/documentation/cdl/en/statug/65328/HTML/default/viewer.htm#statug_qreg_syntax11.htm

You can also perform a likelihood ratio test by specifying the LR option in the TEST statement; the mathematical details are provided on this same page.

With all due respect, there are no mathematical details of the Wald test at this link.

Re: Compare two medians

PaigeMiller — Thu, 29 Nov 2012 20:03:22 GMT

Rick Wicklin wrote:

I'm not sure that the stated criterion of "(often) more power" is a useful one. Especially when "(often)" is demonstrated by a single example. Do you have references regarding power?

What "explicit assumtions (sic)" are present in NPAR1WAY that are not present for QUANTREG's test?

Re: Compare two medians

AllenMcDowell — Thu, 29 Nov 2012 20:07:59 GMT

Sorry, wrong link. try this one:

http://support.sas.com/documentation/cdl/en/statug/65328/HTML/default/viewer.htm#statug_qreg_details13.htm

or look at the Details section and select the "Linear Test" entry.

Re: Compare two medians

Rick_SAS — Thu, 29 Nov 2012 20:33:41 GMT

Yes, this is a single example. You are welcome to run a simulation study to see how well it holds in general.

I do not know what assumptions are behind the QUANTREG test, which is why I would not use it myself.

The assumptions and power behind the "median test" and the Wilcoxon test are discussed in "Should the Median Test be retired from general use?", (Freidlan and Gastwirth, 2000, TAS). That article provides evidence and gives references that show that the median test has less power in small samples, for unbalanced designs, and for asymmetric distributions than many other tests, including the Wilcoxon test. The same article also provides power analysis for various distributional assumptions.

Re: Compare two medians

peterinboston — Fri, 04 Jan 2013 15:54:00 GMT

I am new to Proc QuantReg. Comparing medians is appealing since it would be more robust to outliers than comparing means.

The appeal of Quantreg, for me, is that it can compare medians while including other factors in the model. So you get what I'd call 'an adjusted test of medians' with QuantReg, instead of the usual unadjusted comparison of medians with Proc npar1way Wilcoxon.

The first step is to get QuantReg to duplicate the Wilcoxon result. Then I’d use Proc Quantreg to improve on a Wilcoxon test by adjusting for other factors. I’ve come as close as I can using the

test x / rankscore (wilcoxon);

syntax below.

Note that the Wald test p=.0899 given in the first Proc QuantReg below must not be right, since the 95%CI (-1.0039,-0.0535) for the X parameter estimate does not include 0.

I don’t understand why we don’t see a SE and a p-value in the Parameter Estimates table output of Proc Quantreg.

data one;

call streaminit(736283);

do i = 1 to 100;

if i<51 then y=rand('NORMAL',0,1);

if i<51 then x=0;

if i>=51 then y=rand('NORMAL',.5,1); *<<<note .5 difference in means;

if i>=51 then x=1;

output;

end;

run;

proc npar1way data=one WILCOXON;

class x;

var y ;

run;

Wilcoxon Two-Sample Test

Statistic 2180.0000

Normal Approximation

Z -2.3749

One-Sided Pr < Z 0.0088

Two-Sided Pr > |Z| 0.0176

proc quantreg data=one;

class x;

model y=x;

test x;

run;

Parameter Estimates

95% Confidence

Parameter DF Estimate Limits

Intercept 1 0.4081 -0.0237 0.8264

x 0 1 -0.4365 -1.0039 -0.0535

x 1 0 0.0000 0.0000 0.0000

Test Results

Test Chi-

Test Statistic DF Square Pr > ChiSq

Wald 2.8766 1 2.88 0.0899

The following syntax comes closer to the Wilcoxon p-value (Wilcoxon p=.0176; quantreq p=.0168), but why are they different??

proc quantreg data=one alpha=0.05 ;

class x;

model y=x;

test x / rankscore (wilcoxon);

run;

Parameter Estimates

95% Confidence

Parameter DF Estimate Limits

Intercept 1 0.4081 -0.0237 0.8264

x 0 1 -0.4365 -1.0039 -0.0535

x 1 0 0.0000 0.0000 0.0000

Test Results

Test Chi-

Test Statistic DF Square Pr > ChiSq

Rank_Wilcoxon 5.7132 1 5.71 0.0168

Re: Compare two medians

peterinboston — Thu, 28 Feb 2013 17:00:25 GMT

I asked SAS about why the results of Npar1way and Quantreg were not more similar. Below I give their response and an example they provided where the two procedures give very similar results. Apparently expecting the results to match identically was naive, since the procedures are quite different. What follows is their response.....

Summary
=========
(1) The traditional nonparametric two-sample tests are given by PROC NPAR1WAY
but this procedure is not designed to fit a model and is essentially doing
something different than PROC QUANTREG which is optimizing an objective function,
i.e. - determining the coefficient/parameter estimates that optimize the objective function.
(2) When there are ties in the response data there are different ways to compute
the rank scores in NPAR1WAY but QAUNTREG does not do any adjustment for ties.
The QUANREG developer said this is the main difference between NPAR1WAY and QUANTREG.
(3) If you have other covariates you wish to include in the analysis then you are
better served by using PROC QUANTREG which can incorporate other factors into the model.

Test program
=============
You will notice in the test program and data set simulated by the QUANTREG developer
that the NPAR1WAY results agree rather closely with QUANTREG:
(1) Regarding the "Wilcoxon Two-Sample Test" (WilcoxonTest ODS table) from NPAR1WAY
versus the Rank_Wilcoxon Test (Test 1 ODS Table) from QUANTREG:
(a) If you square the "Normal Approximation" Z value you will get something
very close to the Rank_Wilcoxon Test "Chi-Square" value from QUANTREG.
(b) The two-sided Z pvalue (Two Sided Pr > |Z|) from NPAR1WAY is very similar
the to Chi-square p-value (Pr > ChiSq) from QUANTREG.
(2) Regarding the "Median Two-Sample Test" (MedanTest ODS table) from NPAR1WAY
versus the Rank_Sign Test (Test 2 ODS table) from QUANTREG:
(a) If you square the Z value you will get something very close to the
Rank_Sign "Chi-Square" value from QUANTREG.
(b) The two-sided Z pvalue (Two Sided Pr > |Z|) from NPAR1WAY is very
similar the to Chi-square p-value (Pr > ChiSq) from QUANTREG.

%let n=100;

data Trial(drop=i);
     do i=1 to &n;
        if (i <= &n/2) then do;
           y = rannorm(1);
           treatment = 1;
        end;
        else do;
           y = 0.75 + rannorm(1);
           treatment = 0;
        end;
        output;
     end;
     run;

ods trace on / listing;
ods select WilcoxonTest MedianTest; * MedianAnalysis;
proc npar1way data=Trial Wilcoxon Median;
     class Treatment;
     var y;
     title1 "NPAR1WAY - two sample tets";
     run;

ods select ModelInfo ObjFunction ParameterEstimates Tests;
proc quantreg data=Trial alpha=0.05;
     class treatment;
     model y = treatment / quantile=.5;
     test treatment / rankscore(Wilcoxon);
     test treatment / rankscore (median);
     title1 "QUANTREG - rankscore tests of two treatments";
     run;
ods trace off;