topic Re: PROC MEANS in Statistical Procedures

PROC MEANS

Thalitacosta — Fri, 11 Mar 2022 18:41:07 GMT

How to put the following statistics in output data:

proc means data=&bib..&base. n sum min p1 p5 p10 p25 p50 p75 p90 p95 p99 max mean missing;

var &vari.;

run;

Re: PROC MEANS

Reeza — Fri, 11 Mar 2022 18:51:09 GMT

https://documentation.sas.com/doc/en/pgmsascdc/9.4_3.5/proc/p17h6q7ygvkl1sn13qzf947dundi.htm#p17h6q7ygvkl1sn13qzf947dundi

For your code I would use ODS OUTPUT.

proc means data=&bib..&base. n sum min p1 p5 p10 p25 p50 p75 p90 p95 p99 max mean missing stackodsoutput;
var &vari.;
ods output summary=want;
run;

proc print data=want;run;

@Thalitacosta wrote:

How to put the following statistics in output data:

proc means data=&bib..&base. n sum min p1 p5 p10 p25 p50 p75 p90 p95 p99 max mean missing;

var &vari.;

run;

Re: PROC MEANS

PaigeMiller — Fri, 11 Mar 2022 18:50:07 GMT

proc summary data=sashelp.class;
var height weight age;
output out=stats  n= sum= min= p1= p5= p10= p25= p50= p75= p90= p95= p99= max= mean= nmiss=/autoname;
run;

Re: PROC MEANS

Rick_SAS — Sat, 12 Mar 2022 12:18:59 GMT

For an example and discussion, see the article, "Save descriptive statistics for multiple variables in a SAS data set."

The article shows two solutions:

1. Use PROC MEANS. If you do this, be sure to use the STACKODSOUTPUT option

proc means data=&bib..&base.
           N sum min p1 p5 p10 p25 p50 p75 p90 p95 p99 max mean missing
           STACKODSOUTPUT;        /* preserve table form of output */
ods output Summary=MeansSummary;  /* write statistics to data set */
run;

proc print data=MeansSummary; run;

2. Use PROC UNIVARIATE and the OUTTABLE= option. See the article for the syntax and example.