topic Re: PROC MIANALYZE freezes SAS in Statistical Procedures

PROC MIANALYZE freezes SAS

psh23 — Sun, 30 Apr 2017 05:10:22 GMT

I am trying to run a MI with logistic regression. The proc MI and proc logistic run fine, but when I try to run the proc MIanalyze, it just runs forever until the computer freezes.

proc mi data=smokingr seed=550 out=p.outmi nimpute=10 minmaxiter=50;
class sex race smoking partnered ses smoke_d vitstat;
var sex race age2 yeardx_new smoke_d vitstat count ses partnered smoking;
fcs logistic(smoking ses/ link=glogit) logistic(partnered);
run;

proc logistic data=p.outmi;
class sex race(ref="NH White") smoking(ref="Yes") partnered(ref="Not partnered") ses(ref="Low") / param=ref;
model vitstat = sex race age2 ses partnered smoke_d smoking yeardx_new count;
by _imputation_;
ods output ParameterEstimates=parms;
run;

proc print data=parms; run;

proc mianalyze parms(classvar=classval)=parms;
title "pooled estimates SAS MI";
class sex race smoking partnered ses smoke_d;
modeleffects intercept sex race age2 ses partnered smoke_d smoking yeardx_new count;
ods output parameterestimates=MIestimates;
run;

Re: PROC MIANALYZE freezes SAS

Reeza — Sun, 30 Apr 2017 05:47:50 GMT

1. How big is your data? Number of rows or GB?

2. Does it work with sample data, try an example from the documentation?

http://documentation.sas.com/?docsetId=statug&docsetVersion=14.2&docsetTarget=statug_mianalyze_examples07.htm&locale=en

3. What version of SAS and SAS/STAT are you running?

Re: PROC MIANALYZE freezes SAS

psh23 — Sun, 30 Apr 2017 22:35:50 GMT

The example code runs perfectly. My data is small, about 2500 observations and its SAS 9.4

Re: PROC MIANALYZE freezes SAS

amcr729 — Mon, 15 Nov 2021 20:18:15 GMT

having the same problem. did you figure it out?

Re: PROC MIANALYZE freezes SAS

SAS_Rob — Tue, 16 Nov 2021 20:46:15 GMT

Post your code and we can see if there is anything unusual about it.

Re: PROC MIANALYZE freezes SAS

amcr729 — Tue, 16 Nov 2021 21:01:38 GMT

Thanks, here is the code for the imputation process overall. It is when I run the code under /*3. pooling phase*/, highlighted in blue, that sas gets hung up, i.e. keeps running and never completes the procedure:

/*1. imputation phase*/
proc mi data=siya nimpute=20 out=mi_fcs;
class share give receive agyw drugs depression
ss worksite mobility pimp homeless money unsafe
disclose vs ed civil alcohol violrec viol;
fcs plots=trace(mean std);
var share give receive agyw drugs depression
ss worksite mobility pimp homeless money unsafe
disclose estigmasw estigmahiv astigmasw
astigmahiv pills303 pillsreceive303
pillsgive303 vs ed civil alcohol violrec viol ;
fcs discrim(share give receive agyw drugs depression
ss worksite mobility pimp homeless money unsafe
disclose vs ed civil alcohol violrec viol / classeffects=include) nbiter=100;
run;

/*2. analysis and pooling*/
proc genmod data=mi_fcs;
class pid civil (ref="0") depression (ref="0")
alcohol (ref="0") ed (ref="0") mobility (ref="0") unsafe (ref="0") money (ref="0") worksite (ref="0") /param=ref;
model vs=
pills303
agyw
ed
civil
alcohol
drugs
depression
mobility
worksite
pimp
violrec
homeless
money
unsafe
estigmasw
estigmahiv
astigmasw
astigmahiv disclose/Dist=poisson Link=log;
Repeated subject = pid / type=Ind PRINTMLE;
estimate 'pills303' pills303 1;
by _imputation_;
ods output ParameterEstimates=gm_fcs;
title 'VS on pills given and/or received with MI';
run;

/*3. pooling phase*/
TITLE " MULTIPLE IMPUTATION Linear REGRESSION - FCS";
PROC MIANALYZE parms(classvar=level)=gm_fcs;
class share give receive agyw drugs depression
ss worksite mobility pimp homeless money unsafe
disclose vs ed civil alcohol violrec viol;
MODELEFFECTS INTERCEPT share give receive agyw drugs depression
ss worksite mobility pimp homeless money unsafe
disclose estigmasw estigmahiv astigmasw
astigmahiv pills303 pillsreceive303
pillsgive303 vs ed civil alcohol violrec viol;/*all variables from all models*/
RUN;

Re: PROC MIANALYZE freezes SAS

SAS_Rob — Tue, 16 Nov 2021 21:38:24 GMT

You have a bunch of extra variables on the CLASS statement in MIANALYZE. You should only be using variables involved in the model from GENMOD.

PROC MIANALYZE parms(classvar=level)=gm_fcs;
class civil depression alcohol ed mobility unsafe money worksite ;
MODELEFFECTS INTERCEPT pills303
agyw
ed
civil
alcohol
drugs
depression
mobility
worksite
pimp
violrec
homeless
money
unsafe
estigmasw
estigmahiv
astigmasw
astigmahiv disclose;

run;

Also, since you are using a REPEATED statement in GENMOD you need to make sure that you are feeding the empirical estimates into MIANALYZE and not the MLEs. In other words, your ODS OUTPUT statement is incorrect. Use this one instead.

ods output GEEEmpPest=gm_fcs;

Re: PROC MIANALYZE freezes SAS

amcr729 — Wed, 17 Nov 2021 02:43:53 GMT

Thank you so much, that worked! But I am not getting the contrast estimate results I need when I run that PROC MIANALYZE code. do I include the estimate statement in it? Please advise, many thanks again.

Re: PROC MIANALYZE freezes SAS

SAS_Rob — Wed, 17 Nov 2021 12:32:49 GMT

Combining ESTIMATE statement results can be done following this example.

data test;

do a=1 to 3;

do rep=1 to 10;

x=ranuni(123)*10;

if ranuni(234)>.55 then y=.;

else y=.46+.88*a+x+rannor(123);

output;

end;

proc mi data=test out=outmi;

var a x y;

run;

ods trace on;

proc genmod data=outmi;

by _imputation_;

class a;

model y=a x;

estimate 'A1_v_A2' a 1 -1 0;*do not use spaces in the labels;

estimate 'A1_v_A3' a 1 0 -1;

ods output estimates=estimate_ds;

run;

proc sort data=estimate_ds;

by label _imputation_;

run;

proc mianalyze data=estimate_ds;

by label;

modeleffects LBetaEstimate;

stderr stderr;

run;

Re: PROC MIANALYZE freezes SAS

amcr729 — Thu, 02 Dec 2021 18:16:05 GMT

Thank you very much. I tried that code (below) and got the following error messages:

ERROR: Invalid reference value for ed.
ERROR: No valid observations due to invalid or missing values in the response, explanatory, offset,
frequency, or weight variable.
NOTE: The above message was for the following BY group:
pills303=0 Imputation Number=1
ERROR: Data set WORK.MI_FCS is not sorted in ascending sequence. The current BY group has pills303 =
3.3333333333 and the next BY group has pills303 = 0.
NOTE: The SAS System stopped processing this step because of errors.
WARNING: Output 'estimates' was not created. Make sure that the output object name, label, or path
is spelled correctly. Also, verify that the appropriate procedure options are used to
produce the requested output object. For example, verify that the NOPRINT option is not
used.

I do not know what could be wrong with "ed" -- it has four categories, 0-3.

"Pills303" is a continuous various (mean=0.63, range: 0-11.3)

Here is the code I ran per your guidance:

proc genmod data=mi_fcs;
class pid civil (ref="0") depression (ref="0")
alcohol (ref="0") ed (ref="0") mobility (ref="0") unsafe (ref="0") money (ref="0") worksite (ref="0") /param=ref;
model vs=
pills303
agyw
ed
civil
alcohol
drugs
depression
mobility
worksite
pimp
violrec
homeless
money
unsafe
estigmasw
estigmahiv
astigmasw
astigmahiv disclose/Dist=poisson Link=log;
Repeated subject = pid / type=Ind ;
estimate 'pills303' pills303 1 -1 0;
by pills303 _imputation_;
ods output estimates=estimate_ds;
title 'VS on pills given and/or received with MI';
run;

Your help sorting this out would be greatly appreciated.

Re: PROC MIANALYZE freezes SAS

Reeza — Thu, 02 Dec 2021 18:37:36 GMT

ERROR: Data set WORK.MI_FCS is not sorted in ascending sequence. The current BY group has pills303 =
3.3333333333 and the next BY group has pills303 = 0.

That's the first issue to sort out, Once you fix that which errors are remaining?

Re: PROC MIANALYZE freezes SAS

SAS_Rob — Thu, 02 Dec 2021 19:57:10 GMT

Why are you adding Pills303 to the BY statement? To have the same variable on both the BY statement and in the MODEL statement is going to cause singularity issues since for each value of Pills303 it will fit a different model (and the values are constant).

Likewise, the ESTIMATE statement does not make sense since there is only a single coefficient for Pills303 and it looks like you are trying to compare two separate levels..

Re: PROC MIANALYZE freezes SAS

amcr729 — Thu, 02 Dec 2021 21:06:44 GMT

thank you for pointing out the mistakes. I fixed those and it ran fine. But: the proc mianalyze results still don't give me the contrast estimate (prevalence ratio) that I need. I just get the beta (lbetaestimate). Is there a way to get that?

Re: PROC MIANALYZE freezes SAS

amcr729 — Mon, 06 Dec 2021 18:00:18 GMT

Hi - any thoughts on how to get the pooled contrast estimates from proc mianalyze? thanks so much in advance, hopefully this is the last question!

Re: PROC MIANALYZE freezes SAS

SAS_Rob — Tue, 07 Dec 2021 16:12:23 GMT

You would need to add the EXP option to the ESTIMATE statement and then combine those estimates specifically. Something like the example below would work.

data test;
seed=2534565;
do _imputation_=1 to 25;
do i=1 to 250;
do ind1=0 to 1;
do ind2=0 to 1;
logit=-1 + .05*ind1-.67*ind2;
p=exp(-logit)/(1+exp(-logit));
if ranuni(seed)>p then y=1; else y=0;
output;
end;
end;
end;
end;
run;
ods trace on;
proc genmod data=test;
model y=ind1 ind2 /dist=bin link=log;
by _Imputation_;
estimate 'Ind1 relative risk' ind1 1/exp;
estimate 'Ind2 relative risk' ind2 1/exp;
ods output Estimates=est_ds(where=(index(label,'Exp')=1));*Keeps the EXP values and their standard errors;
run;

proc sort data=est_ds;
by label _imputation_;
run;

proc mianalyze data=est_ds;
by label;
modeleffects LBetaEstimate;
stderr stderr;
run;

Re: PROC MIANALYZE freezes SAS

amcr729 — Tue, 07 Dec 2021 18:23:39 GMT

thank you. is the 'data test' code necessary in all cases, or can I just use proc genmod on? I don't understand what is happening with the 'data test' code.

Re: PROC MIANALYZE freezes SAS

SAS_Rob — Wed, 08 Dec 2021 12:31:56 GMT

No, the first step is not necessary in your case. It simply generated a sample data set to use. You should use the GENMOD step on.

Re: PROC MIANALYZE freezes SAS

amcr729 — Wed, 08 Dec 2021 15:28:16 GMT

got it, thanks. I ran it, but the results don't seem right to me unless I am reading them wrong. I am assuming that the estimate under "lbetaestimate" is not the beta but the pooled prevalence ratio (contrast estimate). That estimate and CI seem fine but the p-value (<.0001) seems off-- see page 31 of attachment. For all 5 imputations, the p-value is around .2 (see pages 16-30). any thoughts on what could be going wrong here? Many thanks.

Re: PROC MIANALYZE freezes SAS

SAS_Rob — Thu, 09 Dec 2021 15:58:21 GMT

The default test is whether or not it is equal to 0. You would want to modify that to test if it is equal to 1. This can be done by specifying the THETA0=1 option on the MIANALYZE statement.

SAS Help Center: PROC MIANALYZE Statement

Re: PROC MIANALYZE freezes SAS

amcr729 — Thu, 09 Dec 2021 18:53:05 GMT

Got it, that worked! thanks. I am now trying to get multiply imputed results for a different genmod model (same imputation model, dataset etc) where I am producing contrast estimates for several variables, this time including several categorical ones, and am getting error messages. Thanks in advance for your help. Here is the code and the error message I get when I run proc mianalyze:

proc genmod data=mi_fcs;
class pid ss (ref="0") civil (ref="0") depression (ref="0")
alcohol (ref="0") ed (ref="0") mobility (ref="0") money (ref="0")
unsafe (ref="0") /param=ref;
model share=
ed
civil
alcohol
drugs
depression
ss
mobility
pimp
money
unsafe
viol
estigmasw
estigmahiv
astigmasw/Dist=poisson Link=log;
Repeated subject = pid / type=Ind;
by _imputation_;
estimate 'Incomplete secondary vs. any primary or none' ed 1 0 0 /exp;
estimate 'Complete secondary vs. any primary or none' ed 0 1 0 /exp;
estimate 'Incomplete or complete university or technical vs. any primary or none' ed 0 0 1/exp;
estimate 'Partner, cohab vs single' civil 0 1/exp;
estimate 'Partner, non-cohab vs single' civil 1 0/exp;
estimate 'Alcohol freq =<monthly vs never' alcohol 1 0 0 0/exp;
estimate 'Alcohol freq 2-4x/mo vs never' alcohol 0 1 0 0/exp;
estimate 'Alcohol freq 2-3x/wk vs never' alcohol 0 0 1 0/exp;
estimate 'Alcohol freq =>4x/wk vs never' alcohol 0 0 0 1/exp;
estimate 'Drug use <30 days: yes vs. no' drugs 1/exp;
estimate 'Depression: mild vs none/minimal' depression 1 0 0 0/exp;
estimate 'Depression: moderate vs none/minimal' depression 0 1 0 0/exp;
estimate 'Depression: moderately severe vs none/minimal' depression 0 0 1 0/exp;
estimate 'Depression: severe vs none/minimal' depression 0 0 0 1/exp;
estimate 'Social support: moderate vs low' ss 1 0/exp;
estimate 'Social support: high vs low' ss 0 1/exp;
estimate 'Mobility: nights spent outside Durban <6 mos.' mobility 1 /exp;
estimate 'Share earnings with pimp or other: yes vs. no' pimp 1/exp;
Estimate 'Enough money for needs: A little vs not at all' money 1 0 0 /exp;
Estimate 'Enough money for needs: Moderately vs not at all' money 0 1 0/exp;
Estimate 'Enough money for needs: Mostly or completely vs not at all' money 0 0 1/exp;
Estimate 'safe in daily life: Moderately vs Very much/extremely' unsafe 1 0 0 /exp;
Estimate 'safe in daily life: A little vs Very much/extremely' unsafe 0 1 0/exp;
Estimate 'safe in daily life: Not at all vs Very much/extremely' unsafe 0 0 1/exp;
estimate 'Physical and/or sexual violence ever: yes vs no' viol 1/exp;
estimate 'Enacted SW stigma level' estigmasw 1/exp;
estimate 'Enacted HIV stigma level' estigmaHIV 1/exp;
estimate 'Anticipated SW stigma level' astigmasw 1/exp;
ods output estimates=estimate_ds(where=(index(label,'Exp')=1));
title 'Sharing (Ever)correlates - robust poisson- MI';
run;
proc sort data=estimate_ds ;
by _imputation_;
run;
proc mianalyze data=estimate_ds THETA0=1 ;
by label;
modeleffects LBetaEstimate;
stderr stderr;
run;

ERROR: Data set WORK.ESTIMATE_DS is not sorted in ascending sequence. The current BY group has Label
= Exp(Incomplete secondary vs. any primary or none) and the next BY group has Label =
Exp(Complete secondary vs. any primary or none).