Median survival time in Lifetest procedure

Frank_Furter — Mon, 02 Aug 2021 18:13:31 GMT

I would like to start by saying that I am not a SAS user myself.

I have recently received a statistical report based on a data analysis performed in SAS, that includes results from a Kaplan-Meier survival analysis performed using the Lifetest procedure. The analysis included a comparison of survival analysis results for different subsets of subjects. Even though the event of interest occurred in less than half of the subjects in each subset, the report author specified a median survival time and an accompanying 95% confidence interval. For some subsets only the lower bound of the 95% CI was specified but no median and no upper bound. Unfortunately, I have no access to the original SAS output.

Can this be correct? From what I have understood so far about Kaplan-Meier survival analysis, median survival can only be specified if the event of interest has occurred in at least 50% of the subjects that were initially at risk. Is my thinking incorrect?

KR, Frank

Re: Median survival time in Lifetest procedure

FreelanceReinh — Tue, 03 Aug 2021 12:45:50 GMT

Hallo @Frank_Furter and welcome to the SAS Support Communities!

Yes, these results can be correct. Censoring is the key. While the event of interest may occur in less than 50% of the subjects, the Kaplan-Meier survival estimate can drop below 50% due to censored observations and thus allow for a valid estimate of the median survival time. The corresponding 95% confidence interval can be complete, but a missing upper confidence limit (CL) can occur as well. It's also possible that only a lower CL is available while both the point estimate and the upper CL are missing. Please see the 2020 thread "Why did I get confidence intervals without a estimate?" for an explanation and a link to the formulas in the documentation. (The question there was about the 75% quantile, but the same arguments hold for the median.)

I've made up an example dataset HAVE with three subgroups (grp=1, 2, 3), all of which contain more censored observations (cens=1) than subjects with an event (cens=0). They exhibit three different situations with regard to the median survival estimate:

           Point   95% Confidence Interval
Group   Estimate      [Lower      Upper)

  1      55.0000     40.0000     65.0000
  2      40.0000     15.0000       .
  3        .          5.0000       .

data have;
grp=1;
do time=5 to 70 by 5;
  cens=(time<40 | time=70);
  output;
end;
grp=2;
do time=5 to 50 by 5;
  cens=(time ~in (15,30,40));
  output;
end;
grp=3;
do time=5 to 50 by 5;
  cens=(time ~in (5,10,20));
  output;
end;
run;

proc lifetest data=have plots=survival;
time time*cens(1);
strata grp;
run;

      Summary of the Number of Censored and Uncensored Values

                                                            Percent
Stratum             grp       Total  Failed    Censored    Censored

      1               1          14       6           8       57.14
      2               2          10       3           7       70.00
      3               3          10       3           7       70.00
-------------------------------------------------------------------
  Total                          34      12          22       64.71

Kaplan-Meier curves:

As you can see, it makes a difference whether the censored observations tend to occur early (as in group 1) or rather late (as in group 3). Group 2 is in between.

It should be noted that there was a bug (!) in SAS releases up to 9.4M6 (fixed in 9.4M7) which caused incorrect upper confidence limits for quantiles of the survival distribution in certain situations. This is described in Problem Note 64617. The example above is not affected by this bug, although produced with SAS 9.4M5.

topic Re: Median survival time in Lifetest procedure in Statistical Procedures

Median survival time in Lifetest procedure

Re: Median survival time in Lifetest procedure