topic Output Parameters for Lognormal Distribution in Statistical Procedures

Output Parameters for Lognormal Distribution

kec02171 — Sun, 13 Jun 2021 20:14:55 GMT

I have a lognormal distribution and need to calculate an arithmetic mean and standard deviation. I can get these using the code below. The problem is that I need to also calculate confidence intervals using mean and stdev and I need to output these values to a dataset so I can do the calculation:

proc univariate data=have;

var x;

histogram x/dist=lognormal;

run;

How do I output this?: Bonus points if you can figure out how I can get confidence intervals for the mean and stdev below. 🙂

Re: Output Parameters for Lognormal Distribution

PaigeMiller — Sun, 13 Jun 2021 21:51:36 GMT

To output the values to a SAS data set, you can use ODS OUTPUT.

proc univariate data=have;
    ods output moments=moments;
    var x;
    histogram x/dist=lognormal;
run;

I don't know of a way to compute the confidence intervals.

Re: Output Parameters for Lognormal Distribution

Ksharp — Mon, 14 Jun 2021 10:33:56 GMT

Once you get parameter of lognormal distribution, you can use QUANTITLE() function to get CI .

Or try Bootstrap method.

Or Calling @Rick_SAS

Re: Output Parameters for Lognormal Distribution

Rick_SAS — Mon, 14 Jun 2021 11:01:40 GMT

By definition, if X ~ Lognormal(mu, sigma), then Y=log(X) is distributed as N(mu, sigma). So, compute Y, find the confidence interval for the mean, and then apply the EXP transform to map it back to the lognormal scale:

data have;
call streaminit(123);
do i = 1 to 1000;
   x = rand("Lognormal", 0.5, 1.3);
   output;
end;
run;

data Normal;
set Have;
logX = log(x);    /* logX ~ N(mu, sigma) */
run;

proc means data= Normal LCLM Mean UCLM;
var logX;
output out=MeansOut LCLM=lower UCLM=upper;
run;

data Want;
set MeansOut;
LCLM_LN = exp(lower);  /* transform the CI */
UCLM_LN = exp(upper);
run;

proc print data=Want; run;

Re: Output Parameters for Lognormal Distribution

kec02171 — Mon, 14 Jun 2021 20:10:00 GMT

Thanks all! This got me what I needed! To output the last table I used ods output parameterestimates=parest