topic Re: How to calculate relative risks after PROC MIANALYZE step in Statistical Procedures

How to calculate relative risks after PROC MIANALYZE step

Recep — Tue, 12 Jan 2021 23:18:49 GMT

Hello all,

I was wondering if anybody can help me calculating the relative risks of datasets produced by PROC MI and later combined by PROC MIANALYZE?

I know that PROC MIANALYZE does not have an option for producing this and the following link is a great example of how to calculate odds ratios in the data step after PROC MIANALYZE but I could not figure out the relative risks.

https://communities.sas.com/t5/Statistical-Procedures/calculation-of-odds-ratio-in-proc-mianalyse/td-p/507552

Best,

Recep

Re: How to calculate relative risks after PROC MIANALYZE step

Rick_SAS — Wed, 13 Jan 2021 12:15:59 GMT

You don't provide details, but if you want the relative risks as calculated by PROC LOGISTIC, you can take the averaged parameter estimates from PROC MIANALYZE and pass them to PROC LOGISTIC. For details and an example, see "How to score a logistic regression model that was not fit by PROC LOGISTIC."

Re: How to calculate relative risks after PROC MIANALYZE step

StatDave — Wed, 13 Jan 2021 19:01:52 GMT

This can be done using the NLEstimate macro as described, for non-imputed data, in this note. Using the FISH2 data used in the logistic regression example in the MIANALYZE documentation, and adding to it a binary variable, BIG, as big=(length>20);, the following fits the logistic model and then uses the NLEstimate macro to estimate the relative risk, Pr(big=1)/Pr(big=0). Note that the combined parameter estimates and covariance matrix are needed from MIANALYZE. Since the macro always tests that the estimated quantity equals zero, to test that the relative risk equals 1, 1 is subtracted from the definition of the relative risk in the the f= parameter of the macro.

proc mi data=Fish2 seed=1305417 out=outfish2;
   class Species big;
   monotone logistic(Species=big);
   var big Species;
run;
ods select none;
proc logistic data=outfish2 outest=out1 covout;
   class  big / param=glm;
   model Species= big / covb;
   by _Imputation_;
run;
ods select all;
proc mianalyze data=out1 tcov;
   modeleffects Intercept big0;
   ods output parameterestimates=pe tcov=cov;
run;
%nlest(inest=pe, incovb=cov, f=logistic(b_p1)/logistic(b_p1+b_p2)-1 )

Re: How to calculate relative risks after PROC MIANALYZE step

Recep — Tue, 19 Jan 2021 21:49:57 GMT

Thanks a lot for your response @StatDave! I'm having a bit of hard time understanding the relative risk calculation within the %nlest macro.
What is b_p1 and b_p2? When I replicate the code you provided above, neither "out1" nor "pe" dataset does not include those variables.

Re: How to calculate relative risks after PROC MIANALYZE step

StatDave — Tue, 19 Jan 2021 22:25:49 GMT

If you use the link I provided to the macro's documentation, you will see that the b_px values are the names the macro uses to refer to the model parameter estimates. So, the numerator expression, logistic(b_p1), computes the probability that big=1 by applying the inverse logit to the b_p1 parameter which is the intercept. Similarly for the denominator expression. The function, logistic(x), applies the inverse of the logit, 1/(1+exp(-x)).