topic Re: Burr distribution CDF in Statistical Procedures

Burr distribution CDF

aaaaawe2 — Tue, 21 Jan 2020 17:23:10 GMT

Hi,

The Proc Severity procedure allows fitting of a 'Burr' distribution but the CDF function does not allow the 'Burr' distribution as an input. For instance I tried this code but does not work:

Cum_Pct_Burr = CDF("Burr", Y, theta,alpha,gamma);

Is there a way to generate a cdf for Burr distribution?

thanks,

Re: Burr distribution CDF

Reeza — Tue, 21 Jan 2020 18:00:30 GMT

You probably need to create your own using PROC FCMP. There's another question on here in the last week (in this forum) that shows how that can be done for a distribution.

Re: Burr distribution CDF

FreelanceReinh — Tue, 21 Jan 2020 22:18:10 GMT

Hi @aaaaawe2,

Yes, you can use PROC FCMP. And it's relatively easy in this case thanks to the closed-form expression of the Burr distribution's CDF (found in the PROC SEVERITY documentation😞

proc fcmp outlib=work.funcs.prob;
function cdf_burr(x,t,a,g);
  return(if x>0 then 1-(1+(x/t)**g)**-a else 0);
endsub;
run;

options cmplib=work.funcs;

For example, plot the CDF for seven parameter combinations (first six also shown in Wikipedia😞

%let n=7;
data burr(rename=(i=start));
array l[&n] _temporary_ (1 1 1 1 1 1   3);
array c[&n] _temporary_ (1 1 1 2 3 0.5 1);
array k[&n] _temporary_ (1 2 3 1 1 2   1);
do x=0 to 5 by 0.01;
  do i=1 to &n;
    F=cdf_burr(x,l[i],k[i],c[i]);
    output;
  end;
end;
F=.;
fmtname='legndf';
length label $40;
do i=1 to &n;
  label=cats('theta=',l[i],', alpha=', k[i],', gamma=', c[i]);
  output;
end;
run;

proc format cntlin=burr(firstobs=3508);
run;

ods graphics on / attrpriority=color;
title 'CDF of Burr distributions';

proc sgplot data=burr;
format start legndf.;
label start='Parameters';
yaxis label='CDF';
series x=x y=F / group=start;
keylegend / location=inside position=bottomright;
run;

title;

Result:

I haven't looked deeper into the related documentation "Defining a Severity Distribution Model with the FCMP Procedure" because I don't have a SAS/ETS license.

Re: Burr distribution CDF

Reeza — Tue, 21 Jan 2020 23:13:10 GMT

@FreelanceReinh SAS/ETS is included in onDemand for Academics if you're ever inclined to try it out.

Re: Burr distribution CDF

Rick_SAS — Thu, 29 Jan 2026 10:36:29 GMT

I am updating this old thread so that others who search for this information can find it. The following articles discuss using the Burr XII distribution in SAS: