topic Re: Goodman method (1965 year) confidence interval using SAS in Statistical Procedures

Goodman method (1965 year) confidence interval using SAS

AndreyMyslivets — Thu, 26 Jul 2018 15:23:18 GMT

Dear all!

Could you please help me with the following question:

I need to calculate the simultaneous confidence limits for multinomial proportions based on Goodman method (1965 year) like it id done here:

https://blogs.sas.com/content/iml/2017/02/15/confidence-intervals-multinomial-proportions.html

But I don't have SAS/IML, is it possible to done the calculation using base SAS without IML module?

Thanks in advance!

Best Regards,

Andrey

Re: Goodman method (1965 year) confidence interval using SAS

FreelanceReinh — Thu, 26 Jul 2018 17:09:10 GMT

Hello @AndreyMyslivets,

Yes, this is possible. Here's how (using Rick Wicklin's example data):

%let c=4;     /* number of categories */
%let a=0.05;  /* alpha */

data have;
input n1-n&c;
cards;
91 49 37 43
;

data GoodmanCI;
array n[&c];       /* counts */
array p[&c];       /* percentages */
array lcl[&c];     /* lower confidence limits */
array ucl[&c];     /* upper confidence limits */
set have;
nt=sum(of n[*]);   /* total n */
x=cinv(1-&a/&c,1); /* chi-square quantile, df=1, with Bonferroni adjustment */
do i=1 to &c;
  p[i]=n[i]/nt;
  lcl[i]=(x+2*n[i]-sqrt(x*(x+4*n[i]*(nt-n[i])/nt)))/(2*(nt+x));
  ucl[i]=(x+2*n[i]+sqrt(x*(x+4*n[i]*(nt-n[i])/nt)))/(2*(nt+x));
end;
drop i;
run;

I took the formulas from a 2016 post of mine where I estimated some coverage probabilities for this and other suggested confidence intervals for multinomial proportions.

Re: Goodman method (1965 year) confidence interval using SAS

StatDave — Thu, 26 Jul 2018 17:26:17 GMT

See examples 2 and 3 in this note using PROC CATMOD.

Re: Goodman method (1965 year) confidence interval using SAS

FreelanceReinh — Thu, 26 Jul 2018 19:41:17 GMT

@StatDave wrote:

See examples 2 and 3 in this note using PROC CATMOD.

According to another post in the 2016 thread I mentioned in my reply to @AndreyMyslivets, that Usage Note 32609 was not very helpful for computing simultaneous confidence intervals (EDIT: as far as non-IML techniques are concerned), unfortunately.

Re: Goodman method (1965 year) confidence interval using SAS

Ksharp — Fri, 27 Jul 2018 14:00:59 GMT

There is a macro in @Rick_SAS blog. maybe you can use it .

Re: Goodman method (1965 year) confidence interval using SAS

AndreyMyslivets — Sun, 29 Jul 2018 06:17:30 GMT

Dear @FreelanceReinh @StatDave @Ksharp

Many thanks for your help!