topic proc transreg output meaning in Statistical Procedures

proc transreg output meaning

jojozheng — Fri, 20 Jul 2018 22:17:46 GMT

Hello everyone,

I run the following code and output is below. What's the coefficient here means? And I also get a non-linear curve, so how can I get the equation or formula to output this curve? Thanks!

proc transreg data=WORK.NLNONONLINREGSTATS_0001 detail;
model identity(act_fedcd) = spline(Life_q/nknots=9);
output predicted coefficients out=work.predict;

run;

Re: proc transreg output meaning

PeterClemmensen — Mon, 23 Jul 2018 00:16:08 GMT

I don't follow your question. What coefficient?

You are fitting a non parametric model, so you can not get a parametric equation describing the fitted curve. But why do you want a formula for plotting purposes? You can use the outputted data to draw the curve? However, the procedure plots the curve on its own I assume since you are able to post the plot here?

Re: proc transreg output meaning

plf515 — Mon, 23 Jul 2018 12:24:51 GMT

Your output was too small to read. However, when you fit a spline, the formula for the curve is, naturally, very complicated. If you want a simple curve, don't fit a spline. You can get a formula, but it will not be intuitive at all.

Re: proc transreg output meaning

jojozheng — Mon, 23 Jul 2018 13:33:23 GMT

@PeterClemmensen I need to predict much more value based on this fitting curve. I think it's better for me to have the plotting formula to plot more points beyond the points I have now? cause I have 1 intercept and 1 coefficient in this output table (right bottom corner) which I thought they are using for plotting curve?

Re: proc transreg output meaning

plf515 — Mon, 23 Jul 2018 15:40:42 GMT

No. A spline curve has a very complex equation and it varies between knots of the spline
Peter

Re: proc transreg output meaning

Rick_SAS — Tue, 24 Jul 2018 12:59:34 GMT

I think the easiest approach is to do the spline fitting by using PROC GLMSELECT instead of TRANSREG. The GLMSELECT procedure supports the STORE statement, which stores the model in an item store. You can use the PLM procedure to score additional data (and graph the results), as discussed in the article "Techniques for scoring a regression model in SAS."

If you want to stick with PROC TRANSREG, you can use the "missing value trick" to score the model on a new set of data.

If you use PROC GLMSELECT, the code will look similar to the following:

/* Generate training and scoring data by randomly splitting the Sashelp.Cars data into two parts */
data Cars1 Cars2;
set sashelp.cars(where=(weight<6000));
if rand("Bernoulli", 0.6) then output Cars1;
else output Cars2;
run;

/* Create and store model with PROC GLMSELECT. Score with PROC PLM */

/* fit model on Cars1 data */
proc glmselect data=Cars1;
effect spl = spline(weight/knotmethod=equal(9));
model mpg_city = spl;
store out=SplineModel;
run;

/* score model on Cars2 */
proc plm restore=SplineModel;
   score data=Cars2 out=Pred;
   effectplot;
run;