topic Re: SAS Aggregate data help in Statistical Procedures

SAS Aggregate data help

Natasha2018 — Wed, 21 Feb 2018 17:29:03 GMT

If I have only aggregate data available for the 3 different age categories how do I calculate the 95% confidence interval for each of the age categories in SAS. Thanks for all help in advance
Eg:
Age cat. Numerator Denominator Proportion
10-19. 10 13325356. 0.00000075
20-29. 13 1446666. 0.00000968
30+ 60. 1231555. 0.00004872

Re: SAS Aggregate data help

Reeza — Wed, 21 Feb 2018 17:33:00 GMT

You can try PROC FREQ and use the N as your weights, you may need to reformat your data a bit to get exactly what you need.

I think the first example is pretty close to your data structure.

You could also do the manual calculations in a data step assuming a binomial distribution.

Re: SAS Aggregate data help

PGStats — Wed, 21 Feb 2018 21:05:14 GMT

This way:

data have;
input Agecat $ Numerator Denominator;
datalines;
10-19. 10 13325356
20-29. 13 1446666
30+ 60 1231555 
;

proc genmod data=have;
class agecat;
model numerator/denominator = agecat / dist=binomial;
lsmeans agecat / ilink cl;
run;

Re: SAS Aggregate data help

PGStats — Wed, 21 Feb 2018 21:53:10 GMT

Or you might just as well do:

data have;
input Agecat $ Numerator Denominator;
datalines;
10-19. 10 13325356
20-29. 13 1446666
30+ 60 1231555 
;

data limits;
set have;
BinomialLowerN = quantile("binomial", 0.025, numerator/denominator, denominator);
BinomialUpperN = quantile("binomial", 0.975, numerator/denominator, denominator);
run;

Note: with such large denominators, using the Poisson distribution would yield the same intervals.

Re: SAS Aggregate data help

Natasha2018 — Thu, 22 Feb 2018 14:02:55 GMT

Thanks for your help
I tried doing this but it yielded confidence intervals for the numerator and not the proportion.

Re: SAS Aggregate data help

Reeza — Thu, 22 Feb 2018 18:44:58 GMT

Your ratios are close to 0 so that the confidence intervals are pretty much 0 to 0.

See this example:

data have;
input Agecat $ Type N ;
datalines;
10-19. 1 10 
10-19. 2 13325346 
20-29. 1 13 
20-29. 2 1446653
30+    1 60 
30+    2 1231495 
;

proc sort data=have;
by agecat;
run;


proc freq data=have;
by agecat;
table type / binomial ;
weight N;
run;

@Natasha2018 wrote:
Thanks for your help
I tried doing this but it yielded confidence intervals for the numerator and not the proportion.

Re: SAS Aggregate data help

PGStats — Thu, 22 Feb 2018 20:13:04 GMT

proc genmod gave you the limits for the proportion in the Least Squares Means table under the Lower Mean and Upper Mean headings.