CorrB using Proc Genmod

egaleano — Mon, 04 Sep 2017 15:14:32 GMT

Hello,

I would like parameters' names (or labels) to be shown in the Covariance (CovB) and Correlation (CorrB) matrix when I use the GENMOD procedure. In effect I only see prm1, prm2, etc... and if I use several covariates in the model I struggle to find out which parameter is correlated to another parameter.

Does anyone know how to achieve it?

Thank you

Re: CorrB using Proc Genmod

PGStats — Tue, 05 Sep 2017 04:32:01 GMT

Some post processing of the table data can yield a more informative correlation matrix. Starting with the logistic regression from the doc:

data drug;
   input drug$ x r n @@;
   datalines;
A  .1   1  10   A  .23  2  12   A  .67  1   9
B  .2   3  13   B  .3   4  15   B  .45  5  16   B  .78  5  13
C  .04  0  10   C  .15  0  11   C  .56  1  12   C  .7   2  12
D  .34  5  10   D  .6   5   9   D  .7   8  10
E  .2  12  20   E  .34 15  20   E  .56 13  15   E  .8  17  20
;

proc genmod data=drug;
   class drug;
   model r/n = x drug / dist = bin
                        link = logit
                        lrci corrb;
ods output parmInfo=pi corrb=cb;
run;

data pi2;
set pi;
length label $32;
label = catx("=", Effect, drug);
run;

proc sql;
select catx("=", parameter, quote(trim(label)))
into :labels separated by " "
from pi2;
quit;

data cb2;
set cb(rename=rowname=parameter); set pi2; by parameter notsorted;
label &labels.;
run;

title "Correlation between parameter estimates";
proc print data=cb2 label noobs; var label prm: ; run;

                      Correlation between parameter estimates

   label        Intercept          x     drug=A     drug=B     drug=C     drug=D

   Intercept      1.0000     -0.7550    -0.3098    -0.3787    -0.1956    -0.2279
   x             -0.7550      1.0000     0.0181    -0.0880    -0.1000    -0.1920
   drug=A        -0.3098      0.0181     1.0000     0.3050     0.1849     0.2533
   drug=B        -0.3787     -0.0880     0.3050     1.0000     0.2895     0.4030
   drug=C        -0.1956     -0.1000     0.1849     0.2895     1.0000     0.2543
   drug=D        -0.2279     -0.1920     0.2533     0.4030     0.2543     1.0000

Re: CorrB using Proc Genmod

egaleano — Tue, 05 Sep 2017 06:32:45 GMT

Thank you!

topic Re: CorrB using Proc Genmod in Statistical Procedures

CorrB using Proc Genmod

Re: CorrB using Proc Genmod

Re: CorrB using Proc Genmod