topic Oddratio statement in in PROC logistic in Statistical Procedures

Oddratio statement in in PROC logistic

sammmy — Fri, 27 May 2016 09:11:10 GMT

if i have a model like this;

proc logistic data=saslib.sad_PLFO;

where PLFO in (0,1);

class sex race presents education wealth region / param=ref;

model PLFO (event='1') = age sex race presents education wealth region age*education wealth*region region*education;

run;

How do I seperately get the odds ratio for all the ten variables in the model using the oddratio statement in proc logistic. Since the variable region is invoved in two different interaction.

thanks

Re: Oddratio statement in in PROC logistic

arodriguez — Fri, 27 May 2016 12:39:22 GMT

Hi,

I'm not sure, but I think that is the exponential of the estimate. You could calculate it exporting the estimations or with the option expb in the model.

ods output ParameterEstimates=_PEst;
proc logistic data=sashelp.class;
	class sex;
	model sex(ref="F") = Age Weight Height / expb  ;
run;

Re: Oddratio statement in in PROC logistic

sammmy — Fri, 27 May 2016 14:49:30 GMT

Thank, I thought of that but the values I get are different from the values of the odds ratio estimate, I have checked that for the variables not in the interaction.

Re: Oddratio statement in in PROC logistic

Ksharp — Sat, 28 May 2016 06:27:35 GMT



ods output OddsRatios=OddsRatios;
proc logistic data=sashelp.class;
	class sex;
	model sex(ref="F") = Age Weight Height   ;
	oddsratio age;
run;

Re: Oddratio statement in in PROC logistic

sammmy — Sat, 28 May 2016 07:00:10 GMT

thank you so much, but that is quit easy. But from my example one variable is invoveld in two seperate interaction.

what if I want to get the odds ratio for educatio*region without wealth since region is also involved in interaction with wealth?

Re: Oddratio statement in in PROC logistic

JacobSimonsen — Sat, 28 May 2016 19:18:43 GMT

You can not separately get an odds ratio of the variables that are involved in some interactionsterms. But, you can easily get the oddsratios for a variable for each level of the other variable it interacts with: just use the "at" option in the odds ratio statement. Like in this example which calculate the oddsratio for the variable A at each level of B, and the oddsratio for B for at level of A.

data mydata;
  n=1000;
  do a=0 to 1;
    do b=0 to 1;
	  odds=(1.2**a)*(0.75**b)*(0.8**(a*b));
	  p=odds/(1+odds);
	  y=rand('binomial',p,n);
	  output;
	end;
  end;
run;
proc logistic data=mydata;
  class a(ref="0") b(ref="0")/param=glm ;
  model y/n=a b a*b;
  oddsratio a/at(b=all) diff=ref;
  oddsratio b/at(a=all) diff=ref;
run;