outputting frequencies into one dataset

beverlyobeng — Tue, 01 Mar 2016 21:40:04 GMT

I would please like help trying to export these frequencies into one big table, instead of 4 seperate tables. Is there a way to do this in SAS. Any help would be greatly appreciated.

proc freq data=M;
Tables (sex newrace livingage&year. risk;
run;

Re: outputting frequencies into one dataset

Reeza — Tue, 01 Mar 2016 22:38:16 GMT

If it's all one way freqs this the way I do it:

/*This code is an example of how to generate a table with 
Variable Name, Variable Value, Frequency, Percent, Cumulative Freq and Cum Pct
No macro's are required
Use Proc Freq to generate the list, list variables in a table statement if only specific variables are desired
Use ODS Table to capture the output and then format the output into a printable table.
*/

*Run frequency for tables;
ods table onewayfreqs=temp;
proc freq data=sashelp.class;
	table sex age;
run;

*Format output;
data want;
length variable $32. variable_value $50.;
set temp;
Variable=scan(table, 2);

Variable_Value=strip(trim(vvaluex(variable)));

keep variable variable_value frequency percent cum:;
label variable='Variable' 
	variable_value='Variable Value';
run;

*Display;
proc print data=want(obs=20) label;
run;

https://gist.github.com/statgeek/e0903d269d4a71316a4e

Re: outputting frequencies into one dataset

beverlyobeng — Wed, 02 Mar 2016 14:17:44 GMT

thank you this was extremely helpful

topic outputting frequencies into one dataset in Statistical Procedures

outputting frequencies into one dataset

Re: outputting frequencies into one dataset

Re: outputting frequencies into one dataset