topic Re: Transpose Data in Statistical Procedures

Transpose Data

ali_hash — Mon, 17 Aug 2015 00:07:34 GMT

Hi there,

I need to transpose this data without proc transpose. Here's the data I have:

	FALL_SEMESTER_RAW	FALL_SEMESTER_ADJ	SPRING_SEMESTER_RAW	SPRING_SEMESTER_ADJ
1	89	92.2	93	95.6
2	83	85.6	85	87.8
3	96	98.9	90	93.3
4	93	95.6	96	97.8
5	66	68.9	67	71.1

And I would like the data to look like this:

ID SEMESTER TYPE SCORE

1 FALL ADJ XX

1 FALL RAW XX

1 SPRING ADJ XX

1 SPRING RAW XX

...

This is what I tried but not working out too well. Any help is appreciated.

Re: Transpose Data

Ksharp — Mon, 17 Aug 2015 12:21:53 GMT

Code: Program

data have;
infile cards truncover expandtabs;
input FALL_SEMESTER_RAW FALL_SEMESTER_ADJ SPRING_SEMESTER_RAW SPRING_SEMESTER_ADJ;
cards;
89 92.2 93 95.6
83 85.6 85 87.8
96 98.9 90 93.3
93 95.6 96 97.8
66 68.9 67 71.1
;
run;
data want;
 set have;
 array x{*} _numeric_;
 ID=_n_;   
 do i=1 to dim(x);
  SEMESTER=scan(vname(x{i}),1,'_');
  TYPE=scan(vname(x{i}),-1,'_');
  SCORE=x{i};
  output;
 end;
keep ID   SEMESTER   TYPE   SCORE ;
run;

Re: Transpose Data

Rick_SAS — Mon, 17 Aug 2015 14:27:40 GMT

Why can't you use PROC TRANSPOSE?