topic Re: Not able to download excel file from SAS VA7.5 front end by using stored process. in SAS Visual Analytics

Not able to download excel file from SAS VA7.5 front end by using stored process.

ShammiKalsi — Tue, 24 Nov 2020 15:20:20 GMT

Dear team,

I have created Stored process by using below sas code to export excel file. When i tried to call stored process in SAS VA7.5 it showing below error:

1. Code used for stored process is:

2. Error message screen shot is attached

ods _all_ close;

data _null_;
rc=stpsrv_header('Content-type','application/vnd.ms-excel');
rc=stpsrv_header('Content-disposition',"attachment; filename=Class.xlsx");
run;

%let WORKPATH=%sysfunc(pathname(work));

filename temp "&WORKPATH/temp.xlsx";

proc export data=sashelp.class
outfile=temp
dbms=xlsx
replace;
sheet='mysheet';
run; quit;

data _null_;
infile temp recfm=f lrecl=1;
file _webout recfm=n;
input;
put _infile_;
run;

Re: Not able to download excel file from SAS VA7.5 front end by using stored process.

Stu_SAS — Wed, 02 Dec 2020 18:01:51 GMT

Change your content type header to use application/vnd.openxmlformats-officedocument.spreadsheetml.sheet. Your current content header is for xls files.

data _null_;
    rc=stpsrv_header('Content-type','application/vnd.openxmlformats-officedocument.spreadsheetml.sheet');
    rc=stpsrv_header('Content-disposition',"attachment; filename=Class.xlsx");
run;

Additionally, try modifying your data _null_ statement to use the code as described in Usage Note 20784 - Tip for downloading an existing binary file when running the SAS® Stored Process Server:

 data _null_;
    length data $1;
    INFILE  in  recfm=n;
    file _webout  recfm=n mod;
    input data  $char1. @@;
    put data $char1. @@;
 run;