topic Re: retain a value for common id in SAS Studio

retain a value for common id

AKHILA — Mon, 14 Jan 2019 07:30:24 GMT

i have a dataset like this.

I want to use the first value of weight for the respective subjects.someone pls help me.

input desired output

id weight id weight

1 58 1 58

1 . 1 58

2 62 2 62

2 . 2 62

3 57 3 57

3 . 3 57

Re: retain a value for common id

singhsahab — Mon, 14 Jan 2019 07:47:20 GMT

Hi Akhila,

i hope below code will help...

data have;
input id  weight;
cards;                          
1 58
1 .
1 . 
2 62
2 .
2 .
3 57
3 .
3 .
;
run;    

proc sort ; by id;
run;

data want;
set have;
by id;
retain i ;
if first.id then i=weight;
weight=i;
drop i;
run;

Thanks...

Re: retain a value for common id

AKHILA — Mon, 14 Jan 2019 08:24:45 GMT

it works. thank u so much

Re: retain a value for common id

PeterClemmensen — Mon, 14 Jan 2019 11:45:10 GMT

@AKHILA, please mark @singhsahabs answer as the solution to your problem.

Re: retain a value for common id

novinosrin — Mon, 14 Jan 2019 16:20:02 GMT

data have;
input id  weight;
cards;                          
1 58
1 .
1 . 
2 62
2 .
2 .
3 57
3 .
3 .
;
run;  

data want;
update have (obs=0) have;
by id;
output;
run;

Re: retain a value for common id

novinosrin — Mon, 14 Jan 2019 16:22:46 GMT


data have;
input id  weight;
cards;                          
1 58
1 .
1 . 
2 62
2 .
2 .
3 57
3 .
3 .
;
run;  
proc sql;
create table want(drop=w) as
select *,max(w) as weight
from have(rename=weight=w)
group by id;
quit;

Re: retain a value for common id

novinosrin — Mon, 14 Jan 2019 16:29:25 GMT

data have;
input id  weight;
cards;                          
1 58
1 .
1 . 
2 62
2 .
2 .
3 57
3 .
3 .
;
run;  
data want;
merge have(drop=weight) have(where=(weight > .));
by id;
run;

Re: retain a value for common id

novinosrin — Mon, 14 Jan 2019 16:50:10 GMT


data have;
input id  weight;
cards;                          
1 58
1 .
1 . 
2 62
2 .
2 .
3 57
3 .
3 .
;
run; 

data want;
if _n_=1 then do;
 dcl hash H (dataset:'have(where=(weight > .))') ;
   h.definekey  ("id") ;
   h.definedata ("weight") ;
   h.definedone () ;
end;
set have;
_iorc_=h.find();
run;