topic Re: How to create a SAS data set that contains only the last record of each object ? in SAS Studio

How to create a SAS data set that contains only the last record of each object ?

Kitty28 — Sat, 03 Nov 2018 11:32:48 GMT

I would like to ask if there is an example raw data :

A	1
B	2
	3
C	4
	5

And now the goal is to output each Variable ( A,B,C) contains the last record, such as:

A	1
B	3
C	5

How can I compute the data steps to make the missing variable ( e.g. the empty space below "B" ) also followed by the previous "B" and treat them as the same observation? And also how to compare between Variables to make them output different variable names?

I have do some research that we can create the two variables for identify (A,B,C) by something call Var1 and Var2, then it can read the raw data record for Var1 and other variables from the same record. However, I feel confused with this method.

Is there any ways to achieve the above mentioned goal? Thank you for your help.

Re: How to create a SAS data set that contains only the last record of each object ?

Ksharp — Sat, 03 Nov 2018 11:47:42 GMT

data have;
infile cards expandtabs;
input  x $ y;
cards;
A	1
B	2
. 	3
C	4
. 	5
;
run;
data temp;
 set have;
 length xx $ 40;
 retain xx;
 if not missing(x) then xx=x;
drop x;
run;
data want;
 set temp;
 by xx notsorted;
 if last.xx;
run;

Re: How to create a SAS data set that contains only the last record of each object ?

Ksharp — Sat, 03 Nov 2018 11:49:27 GMT

data have;
infile cards expandtabs;
input  x $ y;
cards;
A	1
B	2
. 	3
C	4
. 	5
;
run;
data temp;
 set have;
 length xx $ 40;
 retain xx;
 if not missing(x) then xx=x;
drop x;
run;
data want;
 set temp;
 by xx notsorted;
 if last.xx;
run;

Re: How to create a SAS data set that contains only the last record of each object ?

VDD — Sat, 03 Nov 2018 12:09:15 GMT

data have;
infile cards expandtabs;
input var1 $ var2;
cards;
A	1
B	2
. 	3
C	4
.	5
;

data have2;
	 set have;
	 retain holder;
	 if not missing(var1) then holder=var1;
run;
data want(drop=holder);
	 set have2;
	 by holder notsorted;
	 if last.holder;
	 var1=holder;
run;

Re: How to create a SAS data set that contains only the last record of each object ?

Kitty28 — Sat, 03 Nov 2018 17:35:42 GMT

Sorry, I may need to say that the goal have to be achieved within ONE data set step..... This is the restriction for this question.

Thank you for your help .

Re: How to create a SAS data set that contains only the last record of each object ?

VDD — Sat, 03 Nov 2018 17:39:54 GMT

You should have noted those requirements. If you were the manager of a shop you would be calling someone back to work or having them redo their work because of poorly defined request.

Re: How to create a SAS data set that contains only the last record of each object ?

Ksharp — Sun, 04 Nov 2018 10:23:23 GMT

Why do you have to accomplish it via one data step ?

data have;
infile cards expandtabs;
input  x $ y;
cards;
A	1
B	2
. 	3
C	4
. 	5
;
run;
data want;
 length x $ 40;
 retain x;
 merge have(rename=(x=xx)) have(keep=x rename=(x=_x) firstobs=2) end=last;
 if not missing(xx) then x=xx;
 if not missing(_x) or last;
 drop xx _x;
run;

Re: How to create a SAS data set that contains only the last record of each object ?

Kitty28 — Sun, 04 Nov 2018 18:00:29 GMT

Thanks for your help. As I am doing some testing with my friends, so as to make some changes to it.
Anyway the question is well-solved !

Re: How to create a SAS data set that contains only the last record of each object ?

VDD — Sun, 04 Nov 2018 18:09:22 GMT

If your question has been solved then you and your classmates should mark the those answers as approved solutions for the answer that solved your original question. That would give credit to the individual that solved your question and it closes unanswered question in the SAS communities Q.