topic Re: categorical variable in SAS Studio

categorical variable

sastuck — Wed, 25 Apr 2018 13:42:57 GMT

Hey!

I am trying to create a categorical variable for different industries using NAICS code. Naics.com identifies 20 different industries:

11	Agriculture, Forestry, Fishing and Hunting
21	Mining
22	Utilities
23	Construction
31-33	Manufacturing
42	Wholesale Trade
44-45	Retail Trade
48-49	Transportation and Warehousing
51	Information
52	Finance and Insurance
53	Real Estate Rental and Leasing
54	Professional, Scientific, and Technical Services
55	Management of Companies and Enterprises
56	Administrative and Support and Waste Management and Remediation Services
61	Educational Services
62	Health Care and Social Assistance
71	Arts, Entertainment, and Recreation
72	Accommodation and Food Services
81	Other Services (except Public Administration)
92	Public Administration

The data look just like the above codes--no extra zeros or anything.

Without looking too scrupulously at the codes themselves, is this the right idea?

*create categorical variable for industry;
data paper.ceo_firm3;
	set paper.ceo_firm2;
	if NAICS=11 then industry=outdoors;
	if NAICS=21 then industry=mining;
	if NAICS=22 then industry=utilities;
	if NAICS=23 then industry=construction;
	if NAICS=31 then industry=manufacturing;
	if NAICS=32 then industry=manufacturing;
	if NAICS=33 then industry=manufacturing;
	if NAICS=42 then industry=wholesale;
	if NAICS=44 then industry=retail;
	if NAICS=45 then industry=retail;
	if NAICS=48 then industry=transportation;
	if NAICS=49 then industry=transportation;
	if NAICS=51 then industry=information;
	if NAICS=52 then industry=finance;
	if NAICS=53 then industry=real_estate;
	if NAICS=54 then industry=professional; 
	if NAICS=55 then industry=management;
	if NAICS=56 then industry=waste;
	if NAICS=61 then industry=education;
	if NAICS=62 then industry=healthcare;
	if NAICS=71 then industry=arts;
	if NAICS=72 then industry=food;
	if NAICS=81 then industry=other;
	if NAICS=92 then industry=public_admin;
run;

Thanks for the feedback!

-SAStuck

Re: categorical variable

RW9 — Wed, 25 Apr 2018 13:59:08 GMT

No, your code is not syntactically correct. To correct your code:

*create categorical variable for industry;
data paper.ceo_firm3;
  set paper.ceo_firm2;
  if NAICS=11 then industry="outdoors";
  if NAICS=21 then industry="mining";

However that is a bit of a faff, and then what if you want to sort per code order. Another way of doing it is by formats:

Re: categorical variable

Reeza — Wed, 25 Apr 2018 14:47:19 GMT

Several websites (hint census) have this as a CSV file with the mapping’s down to the 4 & 6 digit NAICS. If you read in the CSV file and create a data set to pass to PROC FORMAT using CNTLIN you can avoid the manual typing out of all your codes.

Re: categorical variable

sastuck — Wed, 25 Apr 2018 15:15:04 GMT

Thanks for the heads up @Reeza! How would I merge the census's data into my data set without any additional information on the company though, like TICKER or CONAME?

Re: categorical variable

ballardw — Wed, 25 Apr 2018 15:36:01 GMT

@sastuck wrote:

Thanks for the heads up @Reeza! How would I merge the census's data into my data set without any additional information on the company though, like TICKER or CONAME?

Why would you need ticker or coname? You are asking about values of NAICS codes.

Here is how a custom format works:

proc format library=work;
value naics
11="outdoors"
21="mining"
22="utilities"
23="construction"
31="manufacturing"
32="manufacturing"
33="manufacturing"
42="wholesale"
;
run;

data junk;
   do x=11,21,22,23,33;
      output;
   end;
   format x naics.;
   label x ="Industry";
run;
proc print data=junk label;
var x;
run;

The source @Reeza mentioned would allow creating a pretty complete format.

Re: categorical variable

sastuck — Wed, 25 Apr 2018 17:36:53 GMT

i'm mentioning ticker and coname because in the end I want this data to be in my ceo_firm dataset. I'm not understanding how the code you shared would get the naics data into this new ceo_firm3 data set. Please enlighten me!

Re: categorical variable

ballardw — Wed, 25 Apr 2018 18:12:05 GMT

@sastuck wrote:

i'm mentioning ticker and coname because in the end I want this data to be in my ceo_firm dataset. I'm not understanding how the code you shared would get the naics data into this new ceo_firm3 data set. Please enlighten me!

The information is already in your data: the NAICS code value. The format just displays it in a more human understandable way. There is often no need to create an additional variable if all the information you need is contained in an existing variable.

If you do not already have the NAICS code in your ceo_firm data set then that should have been your question.

Re: categorical variable

sastuck — Wed, 25 Apr 2018 18:16:22 GMT

It is in the dataset. I just want to use it to create the categorical variables

Re: categorical variable

Reeza — Wed, 25 Apr 2018 19:21:32 GMT

Once you create a format you just need to apply it. You have two options:

1) Add a new variable, character, that contains the description.

2) Apply the format using PROC PRINT.

A generic example:

proc format;
value age_group
low - 13 = 'Pre-Teen'
13 - 15 = 'Teen'
16 - high = 'Adult';
run;

title 'Example of an applied format';
proc print data=sashelp.class;
format age age_group.;
run;


data class;
set sashelp.class;
age_category = put(age, age_group.);
label age_category = 'Age Category';
run;

title 'Example of creating a new variable with the format';
proc print data=class;
run;

@sastuck wrote:

It is in the dataset. I just want to use it to create the categorical variables