Scatter Plot Limits using STD

HSM9 — Mon, 04 Dec 2017 04:08:25 GMT

I am creating a scatter plot where I want upper and and lower limits that use the code below. The issue is that when I try to define the variables something goes wrong when putting the standard deviation in the statement. An error comes up saying that I don't have enough arguments. How do I fix this?

DATA WORK.Case_Control;
SET Epid.case_control_analysis;
Diff = BMI_GS - BMI_SR;
UpperLimit = MEAN(Diff) + 1.96*STD(diff);
LowerLimit = MEAN (Diff) - 1.96*STD(diff);
Bias = MEAN(diff);

proc means data = WORK.Case_Control mean std;
Var Diff;
run;

Proc SGplot data = WORK.Case_Control;

scatter X = BMI_GS Y = Diff;
label BMI_GS = "Gold-Standard BMI Measure";
label Diff = "Gold-Standard - Self-Report";
refline 0 / transparency = 0.1 lineattrs=(color=black pattern =1 thickness =3);
refline UpperLimit / transparency = 0.1 Label = ('Upper Limit of Agreement') lineattrs=(color=red pattern=2 thickness =3);
refline LowerLimit / transparency = 0.1 Label = ('Lower Limit of Agreement') lineattrs=(color=red pattern=2 thickness =3);
refline Bias / transparency = 0.1 Label = ('Bias') lineattrs=(color=red thickness =3);
run;

Re: Scatter Plot Limits using STD

PGStats — Mon, 04 Dec 2017 04:28:00 GMT

You should define dataset case_control as:

proc sql;
create table Case_Control as
select
    BMI_GS, BMI_SR,
    BMI_GS - BMI_SR as diff,
    mean(BMI_GS - BMI_SR) as bias,
    mean(BMI_GS - BMI_SR) - 1.96*std(BMI_GS - BMI_SR) as lowerLimit,
    mean(BMI_GS - BMI_SR) + 1.96*std(BMI_GS - BMI_SR) as upperLimit    
from Epid.case_control_analysis;
quit;

Re: Scatter Plot Limits using STD

HSM9 — Mon, 04 Dec 2017 04:41:58 GMT

Awesome, I finally got that to work.

topic Re: Scatter Plot Limits using STD in SAS Studio

Scatter Plot Limits using STD

Re: Scatter Plot Limits using STD

Re: Scatter Plot Limits using STD